VBA-Verbindung von Excel 2010 SQL Server 2008

ich bin Recht neu in SQL und VBA, also bitte verzeihen Sie jede audacity den folgenden code enthalten können. Ich arbeite mit code geschrieben in Excel-VBA. Schließlich werden die Daten aus der user form in excel eingetragen werden in eine SQL-Datenbank habe ich erstellt mit SQL Server 2008. Gerade jetzt, ich versuche nur, um öffnen Sie die Verbindung zur SQL-Datenbank, und geben Sie hart codierte Werte in die db. Leider wurde dies viel mehr eine Herausforderung, als ich erwartet hatte. Ich habe versucht, das Spiel mit der Verbindungszeichenfolge ein paar verschiedene Möglichkeiten, aber kein Glück hatten. Wenn das Formular ausgeführt wird, bekomme ich keine Fehler und ich kann die Daten sehen, die Hinzugefügt wurde, in die entsprechende excel-Arbeitsblatt (aber keine änderungen an der SQL-DB). Ich kann sehen, dass die db auf SQL Server Management Studio, und fügen Sie die Zeilen aus, aber ich bin nicht in der Lage, um eine Zeile hinzuzufügen, um die db über diesen code. Die db ist geschützt, die ausschließlich von windows-Authentifizierung. Jegliche Hilfe würde sehr geschätzt werden.

Sub ConnectSqlServer()
'********SPC DATABASE CONNECTION**********************
'write slurry information to database
'spc_date, mix_type, slurry_lot_num, mixer_num, shift, oper

Dim conn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim sConnString As String

'Create connection string
sConnString = "Provider=sqloledb; Server=SERV; Database=db; Trusted_Connection=True;"

'Create the Connection and Recordset objects
Set oConn = New ADODB.Connection
Set rs = New ADODB.Recordset

'Open connection and execute
conn.Open sConnString
Set rs = conn.Execute("INSERT INTO TBL (col1, col2) VALUES ('val', 'val');")

'Clean up
If CBool(conn.State And adStateOpen) Then conn.Close
Set conn = Nothing
Set rs = Nothing

End Sub

Welche Art von Fehlermeldung bekommst du? Beachten Sie, dass eine insert wird nicht ein recordset zurückgeben.
Ich bekomme keine Fehlermeldungen, aber wenn ich das SQL Server Management Studio und in der Tabelle anzeigen, ich kann sehen, dass die Werte, die ich habe versucht, fügen Sie der Tabelle wurden nicht Hinzugefügt

InformationsquelleAutor DeliaOD | 2014-03-11

1

Beim einfügen von Daten, die Sie nicht brauchen, ein recordset-Objekt, da eine INSERT Erklärung nicht ein recordset zurückgeben. Stattdessen versuchen Sie es mit einem command-Objekt statt. Das command-Objekt gibt Ihnen mehr Kontrolle über wie Sie Ihre SQL-Anweisung an den server übergeben wird, und es gibt Ihnen auch ein Weg, um zu testen, ob alle Datensätze eingefügt wurden.

Ich würde auch empfehlen die Einstellung Option Explicit an der Spitze jedes Moduls, da es Sie daran zu hindern, Fehler zu machen, mit Variablen (zum Beispiel, Sie haben beide conn und oConn im code, was ich nicht denke, das Sie bestimmt.

Hier sind meine änderungen an Ihrem code. Es ist ungetestet, aber ich denke ich habe es Recht. Wenn es ohne Fehler ausgeführt wird, und recordsAffected gibt 1 zurück, aber es ist immer noch nichts auf dem server, dann haben wir ein wenig mehr Graben.
```
Sub ConnectSqlServer()
'********SPC DATABASE CONNECTION**********************
'write slurry information to database
'spc_date, mix_type, slurry_lot_num, mixer_num, shift, oper

Dim conn As New ADODB.Connection
Dim cmd As New ADODB.Command
Dim sConnString As String
Dim recordsAffected as Long

'Create connection string
sConnString = "Provider=sqloledb; Server=SERV; Database=db; Trusted_Connection=True;"

'Open connection and execute
conn.Open sConnString
With cmd
  .ActiveConnection = conn
  .CommandType = adCmdText
  .CommandText = "INSERT INTO TBL (col1, col2) VALUES ('val', 'val');"
  .Execute recordsAffected 'Includes a return parameter to capture the number of records affected
End With

Debug.Print recordsAffected 'Check whether any records were inserted

'Clean up
If CBool(conn.State And adStateOpen) Then conn.Close
Set cmd = Nothing
Set conn = Nothing

End Sub
```
- Danke für die Antwort Jeff. Ich habe versucht, mit diesem, statt von meinem ursprünglichen code und das gleiche passierte - ich bekam keine Fehler, aber keine Zeilen zur Datenbank Hinzugefügt wurden. Mein code ist alles in Microsoft Visual Basic für Applikationen - wissen Sie, wo recordsAffected würde ausgedruckt werden? (sorry für die langsame Reaktion - wurde die Website unter Wartung für ein wenig)
- In der Visual Basic-Editor, drücken Sie Strg+G, um das Direktfenster zu öffnen. Das ist, wo Debug.Drucken spuckt seine Ergebnisse. Sie werden wahrscheinlich haben, um es wieder laufen, etwas zu sehen. Lassen Sie mich wissen, was auftaucht.
- Gotcha..nochmals vielen Dank. Es lief wieder und es wurde nichts ausgedruckt in das Direktfenster
- Sind Sie positiv, wird der code tatsächlich ausgeführt? Da würde ich sehr viel erwartet habe, deinen ursprünglichen code einen Fehler zurück. Versuchen Sie Folgendes: platzieren Sie den cursor irgendwo in den frühen code, vielleicht auf conn.Open sConnString, und drücken Sie F9, um erstellen Sie einen Haltepunkt, dann die Dinge laufen wieder. Sollte Ihr code Ausführung anhalten und gelb markiert; Sie können dann durch die Prozedur Schritt für Schritt durch drücken der Taste F8. Dies kann Ihnen zeigen, was falsch läuft, aber ich Frage mich, ob der Haltepunkt wird auch der hit bei allen.
- Fortschritte! Auf den ersten, Sie waren korrekt, wird der breakpoint nicht erreicht. Ich habe den Sub und End Sub und in mit dem code, fügt die Daten in die excel-Arbeitsblatt. Sobald ich dies getan habe, es den Haltepunkt. Nach dem drücken der F8 war in der Lage zu laufen, meine sConnString="...." Linie, aber an der conn.Öffnen sConnString bin ich immer ein "invalid connection string attribute" Fehler
- Ja, ich erwarte, dass dies ist der Fehler, den Sie haben würden, erhalten in den ersten Platz. Für die Unterstützung beim Bau Ihrer Verbindungszeichenfolge, versuchen Sie folgenden link: connectionstrings.com/sql-server
- Für sqloledb, ich denke, Sie wollen 'Datenquelle' und 'Initial Catalog", nicht "Server" und "Datenbank" in der Verbindungszeichenfolge.
- Ich änderte "Trusted_Connection=True;" auf "Integrated Security=SSPI;" und er entledigte sich die Fehler und die Zeile Hinzugefügt. Ich danke Ihnen SO sehr für Ihre Hilfe!
InformationsquelleAutor Jeff Rosenberg

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.