Versuchen, ein Skript für eine unbeaufsichtigte deinstallation mit VBScript

Ich bin versucht zu schreiben ein Skript zum deinstallieren von Anwendungen. Ich habe das Skript zu arbeiten, aber jedes Programm wirft eine Eingabeaufforderung, wenn Sie ausgeführt wird.

Ich weiß, dass die Anwendungen unterstützen das "/S" - parameter so ein silent-deinstallation durchgeführt werden kann. Ich kann die deinstallation /s " - Befehl von einer Eingabeaufforderung aus, und es funktioniert gut. Keine Aufforderungen enthält, wird es einfach deinstalliert.

Mein problem ist das aufrufen der parameter /S in einem Skript. Egal, wie ich versuche, ich bekomme immer syntax Fehler. Ich weiß, das ist nur mir und meinem nicht-Verständnis von Anführungszeichen und Klammern, aber ich bin irgendwie müde zu versuchen, um es zu arbeiten. Das problem wird noch verschärft durch die Tatsache, dass alle Pfade mit Leerzeichen in Ihnen, die eine weitere dang Zitate.
Ich hoffe, jemand kann mir zeigen was ich falsch mache.

Also, ich weiß wirklich nicht, was mache ich mit VBS Sachen, so würde ich es begrüßen, wenn Ihr alle übersehen, wie hässlich das Skript ist. 🙂

Ich habe auch eine Frage über die "wahren" parameter. Mein Verständnis ist, dass dies bedeutet, dass der aktuelle Vorgang abgeschlossen sein sollte, bevor Sie sich auf die nächste operation. Aber die deinstallation zu laufen scheinen alle zur gleichen Zeit. Bin ich Verständnis für die "wahren" parameter korrekt?

Den Befehl für eine automatische deinstallation ist:

C:\Program Files\Juniper Networks\Network Connect 7.1.9\uninstall.exe /S

Hier ist mein Skript, ohne das "/S' - parameter.

'Uninstall Juniper Networks Network Connect 7.1.9

Wscript.Echo "Uninstalling 'Juniper Networks Network Connect 7.1.9'"

Dim objShell
Set objShell = WScript.CreateObject( "WScript.Shell" )
objShell.Run ("""C:\Program Files\Juniper Networks\Network Connect 7.1.9\uninstall.exe"""), 1, True
Set objShell = nothing
InformationsquelleAutor user3583386 | 2014-05-09
  1. 0

    Hier ist mein selbst-explainig Lösung:

    ' VB Script Document
'http://stackoverflow.com/questions/23569022/trying-to-script-a-silent-uninstall-with-vbscript
option explicit
Dim strResult
strResult = Wscript.ScriptName _
    & vbTab & "Uninstalling 'Juniper Networks Network Connect 7.1.9'"
Dim strCommand, intWindowStyle, bWaitOnReturn, intRetCode
' strCommand 
'   String value indicating the command line you want to run. 
'   You must include any parameters you want to pass to the executable file.
strCommand = """C:\Program Files\Juniper Networks\Network Connect 7.1.9\uninstall.exe"" /S"
'for test only strCommand = """C:\Program Files\Mozilla Firefox\firefox.exe"" -safe-mode"

' intWindowStyle
'   Optional. Integer value indicating the appearance of the program's window. 
'   Note that not all programs make use of this information.
intWindowStyle = 1
' bWaitOnReturn
'   Optional. Boolean value indicating whether the script should wait 
'   for the program to finish executing before continuing 
'   to the next statement in your script. 
'   If set to true, script execution halts until the program finishes, 
'   and Run returns any error code returned by the program. 
'   If set to false (the default), the Run method returns 0 immediately 
'   after starting the program (not to be interpreted as an error code).
bWaitOnReturn = True
strResult = strResult & vbNewLine & strCommand _
  & vbNewLine & CStr( intWindowStyle) _
  & vbNewLine & CStr( bWaitOnReturn)
Wscript.Echo strResult
Dim objShell
Set objShell = WScript.CreateObject( "WScript.Shell" )
' intRetCode
' The Run method returns an integer
intRetCode = objShell.Run( strCommand, intWindowStyle, bWaitOnReturn)
Set objShell = nothing

Wscript.Echo strResult & vbNewLine & "result=" & CStr( intRetCode)
Wscript.Quit
    • Wow!!! Ich danke Ihnen so sehr. Ich hasse es aufzugeben, auf ein problem, und seit ich dies geschrieben, habe ich das uninstall-switch zu arbeiten (es war ein Zitat-Platzierung, was, wie ich vermutete), aber dieser code wird helfen, stellen Sie sicher, dass die Deinstallationen laufen nicht alle über einander. Vielen Dank für diese. Ich werde spielen, um mit ihm und sehen, ob ich es machen kann arbeiten für meine situation. Nochmals vielen Dank, John
    • Sie können auch drücken Sie diese deinstallieren, um andere Computer mit PSEXEC
    InformationsquelleAutor JosefZ
Schreibe einen Kommentar