Verwendung regulärer Ausdrücke (Regex) in Microsoft Excel sowohl in Zellen als auch in Schleifen

Reguläre Ausdrücke verwendet Pattern-Matching.

Zur Verwendung in Excel gehen Sie folgendermaßen vor :

Schritt 1: Hinzufügen VBA-Verweis auf "Microsoft VBScript Regular Expressions 5.5"

• Wählen Sie "Entwickler" - Reiter (Ich habe nicht diese Registerkarte, was kann ich tun?)
• Wählen Sie "Visual Basic" - Symbol 'Code' ribbon Abschnitt
• In "Microsoft Visual Basic for Applications" - Fenster, wählen Sie "Extras" aus dem oberen Menü.
• Wählen Sie "Referenzen"
• Aktivieren Sie das Kontrollkästchen neben "Microsoft VBScript Regular Expressions 5.5" in Ihrer Arbeitsmappe.
• Klicken Sie auf "OK"

Schritt 2: Definieren Sie Ihre Muster

Grundlegende Definitionen:

- Bereich.

• E. g. a-z entspricht einem Kleinbuchstaben von a bis z
• E. g. 0-5 steht für eine beliebige Anzahl von 0 bis 5

[] Entsprechen genau einem der Objekte, die sich innerhalb dieser Klammern.

• E. g. [a] entspricht dem Buchstaben a
• E. g. [abc] entspricht einem einzelnen Buchstaben, das kann a, b oder c
• E. g. [a-z] entspricht einem beliebigen einzelnen Kleinbuchstaben des Alphabets.

() Gruppen die verschiedene Spiele für die Rückkehr Zwecke. Siehe Beispiele unten.

{} Multiplikator für die wiederholte Kopien des Musters definiert werden, bevor es.

• E. g. [a]{2} entspricht zwei aufeinander folgenden kleinen Buchstaben ein: aa
• E. g. [a]{1,3} entspricht mindestens einem und bis zu drei Kleinbuchstaben aaaaaa

+ Match mindestens eines oder mehrere der Muster definiert werden, bevor es.

• E. g. a+ passen aufeinander folgenden a ' s aaaaaaund so weiter

? Übereinstimmung mit null oder einem der Muster definiert werden, bevor es.

• E. g. Muster kann oder kann nicht vorhanden sein, können aber nur erreicht werden eine Zeit.
• E. g. [a-z]? entspricht, leer-string oder beliebige Kleinbuchstaben.

* Übereinstimmung mit null oder mehr von dem Muster, bevor Sie es.
- E. g. Wildcard für Muster, die möglicherweise oder möglicherweise nicht vorhanden.
- E. g. [a-z]* passt leere Zeichenfolge oder die Zeichenfolge von Kleinbuchstaben.

. Entspricht einem beliebigen Zeichen außer newline \n

• E. g. a. Entspricht einem zwei-Zeichen-Zeichenkette beginnend mit a und endend mit nichts außer \n

| ODER Betreiber

• E. g. a|b bedeutet entweder a oder b abgestimmt werden können.
• E. g. red|white|orange entspricht genau einer der Farben.

^ Not-operator

• E. g. [^0-9] Zeichen können nicht enthalten eine Reihe
• E. g. [^aA] Zeichen können nicht in Kleinbuchstaben angegeben werden a oder oberen Fall A

\ Entweicht besonderen Charakter, folgt (überschreibt oben beschriebenen Verhalten)

• E. g. \.\\\(\?\$\^

---

Verankerung Muster:

^ Match auftreten zu Beginn der Zeichenfolge

• E. g. ^a Erste Zeichen muss jedoch ein Buchstabe a
• E. g. ^[0-9] Erste Zeichen muss eine Zahl sein.

$ Übereinstimmung auftreten muss am Ende der Zeichenfolge

• E. g. a$ Letzte Zeichen muss Buchstabe a

---

Vorrang-Tabelle:

Order  Name                Representation
1      Parentheses         ( )
2      Multipliers         ? + * {m,n} {m, n}?
3      Sequence & Anchors  abc ^ $
4      Alternation         |

---

Vordefinierte Zeichen Abkürzungen:

abr    same as       meaning
\d     [0-9]         Any single digit
\D     [^0-9]        Any single character that's not a digit
\w     [a-zA-Z0-9_]  Any word character
\W     [^a-zA-Z0-9_] Any non-word character
\s     [ \r\t\n\f]   Any space character
\S     [^ \r\t\n\f]  Any non-space character
\n     [\n]          New line

---

Beispiel 1: Ausführen als makro

Den folgenden Beispiel-makro sieht den Wert in Zelle A1 zu sehen, wenn die ersten 1 oder 2 Zeichen sind Ziffern. Wenn dem so ist, werden Sie entfernt und der rest der Zeichenfolge wird angezeigt. Wenn nicht, dann eine box erscheint, die Sie informiert, dass keine übereinstimmung gefunden wird. Zelle A1 Werte 12abc zurück abc Wert der 1abc zurück abc Wert der abc123 wird wieder "Nicht Abgestimmt", weil die Ziffern wurden nicht am Anfang der Zeichenfolge.

Private Sub simpleRegex()
    Dim strPattern As String: strPattern = "^[0-9]{1,2}"
    Dim strReplace As String: strReplace = ""
    Dim regEx As New RegExp
    Dim strInput As String
    Dim Myrange As Range

    Set Myrange = ActiveSheet.Range("A1")

    If strPattern <> "" Then
        strInput = Myrange.Value

        With regEx
            .Global = True
            .MultiLine = True
            .IgnoreCase = False
            .Pattern = strPattern
        End With

        If regEx.Test(strInput) Then
            MsgBox (regEx.Replace(strInput, strReplace))
        Else
            MsgBox ("Not matched")
        End If
    End If
End Sub

---

Beispiel 2: die Ausführung mit einem in-cell-Funktion

Dieses Beispiel ist gleich wie Beispiel 1, jedoch wird das setup ausgeführt werden als ein in-cell-Funktion. Um zu verwenden, ändern Sie den code zu diesem:

Function simpleCellRegex(Myrange As Range) As String
    Dim regEx As New RegExp
    Dim strPattern As String
    Dim strInput As String
    Dim strReplace As String
    Dim strOutput As String


    strPattern = "^[0-9]{1,3}"

    If strPattern <> "" Then
        strInput = Myrange.Value
        strReplace = ""

        With regEx
            .Global = True
            .MultiLine = True
            .IgnoreCase = False
            .Pattern = strPattern
        End With

        If regEx.test(strInput) Then
            simpleCellRegex = regEx.Replace(strInput, strReplace)
        Else
            simpleCellRegex = "Not matched"
        End If
    End If
End Function

Platz Ihren Streicher ("12abc") in Zelle A1. Geben Sie diese Formel =simpleCellRegex(A1) in Zelle B1 und das Ergebnis wird "abc".

---

Beispiel 3: Schleife Durch Auswahl

Dieses Beispiel ist gleich wie Beispiel 1, aber durchläuft einen Bereich von Zellen.

Private Sub simpleRegex()
    Dim strPattern As String: strPattern = "^[0-9]{1,2}"
    Dim strReplace As String: strReplace = ""
    Dim regEx As New RegExp
    Dim strInput As String
    Dim Myrange As Range

    Set Myrange = ActiveSheet.Range("A1:A5")

    For Each cell In Myrange
        If strPattern <> "" Then
            strInput = cell.Value

            With regEx
                .Global = True
                .MultiLine = True
                .IgnoreCase = False
                .Pattern = strPattern
            End With

            If regEx.Test(strInput) Then
                MsgBox (regEx.Replace(strInput, strReplace))
            Else
                MsgBox ("Not matched")
            End If
        End If
    Next
End Sub

---

Beispiel 4: Spaltung neben verschiedenen mustern

In diesem Beispiel durchläuft eine Reihe (A1A2 & A3) und sucht nach einer Zeichenfolge, beginnend mit drei Ziffern, gefolgt von einem einzelnen Buchstaben und dann 4 Ziffern. Die Ausgabe teilt abgesehen das Muster passt in den angrenzenden Zellen mithilfe der (). $1 stellt die ersten Muster abgestimmt innerhalb der ersten Reihe von ().

Private Sub splitUpRegexPattern()
    Dim regEx As New RegExp
    Dim strPattern As String
    Dim strInput As String
    Dim Myrange As Range

    Set Myrange = ActiveSheet.Range("A1:A3")

    For Each C In Myrange
        strPattern = "(^[0-9]{3})([a-zA-Z])([0-9]{4})"

        If strPattern <> "" Then
            strInput = C.Value

            With regEx
                .Global = True
                .MultiLine = True
                .IgnoreCase = False
                .Pattern = strPattern
            End With

            If regEx.test(strInput) Then
                C.Offset(0, 1) = regEx.Replace(strInput, "$1")
                C.Offset(0, 2) = regEx.Replace(strInput, "$2")
                C.Offset(0, 3) = regEx.Replace(strInput, "$3")
            Else
                C.Offset(0, 1) = "(Not matched)"
            End If
        End If
    Next
End Sub

Ergebnisse:

---

Weitere Muster Beispiele

String   Regex Pattern                  Explanation
a1aaa    [a-zA-Z][0-9][a-zA-Z]{3}       Single alpha, single digit, three alpha characters
a1aaa    [a-zA-Z]?[0-9][a-zA-Z]{3}      May or may not have preceeding alpha character
a1aaa    [a-zA-Z][0-9][a-zA-Z]{0,3}     Single alpha, single digit, 0 to 3 alpha characters
a1aaa    [a-zA-Z][0-9][a-zA-Z]*         Single alpha, single digit, followed by any number of alpha characters

</i8>    \<\/[a-zA-Z][0-9]\>            Exact non-word character except any single alpha followed by any single digit

InformationsquelleAutor der Antwort Portland Runner

Erweiterung auf patszim's Antwort für diejenigen in Eile.

1. Geöffneten Excel-Arbeitsmappe.
2. Alt+F11 VBA/Makros Fenster.
3. Hinzufügen Referenz auf regex unter Tools dann Referenzen
   
   
4. und Auswahl Microsoft VBScript Regular Expression 5.5
   
   
5. Legen Sie ein neues Modul (code muss sich in der Modul-sonst funktioniert es nicht).
   
   
6. In das neu eingefügte Modul
   
   

7. fügen Sie den folgenden code:

   Function RegxFunc(strInput As String, regexPattern As String) As String
       Dim regEx As New RegExp
       With regEx
           .Global = True
           .MultiLine = True
           .IgnoreCase = False
           .pattern = regexPattern
       End With
   
       If regEx.Test(strInput) Then
           Set matches = regEx.Execute(strInput)
           RegxFunc = matches(0).Value
       Else
           RegxFunc = "not matched"
       End If
   End Function

8. Den regex-Muster ist in einer der Zellen und absolute Referenzierung verwendet wird.
   
   Funktion gebunden werden, um die Arbeitsmappe, die Ihr erstellt.
   
   Wenn es eine Notwendigkeit für Sie zu sein verwendet in anderen Arbeitsmappen, speichern Sie die Funktion in Persönlichen.XLSB

InformationsquelleAutor der Antwort SAm

Hier ist ein regex_subst() Funktion. Beispiele:

=regex_subst("watermellon", "[aeiou]", "")
---> wtrmlln
=regex_subst("watermellon", "[^aeiou]", "")
---> aeeo

Ist hier der vereinfachte code (einfacher für mich jedenfalls). Ich konnte nicht herausfinden, wie man eine passende Ausgabe-pattern mit dem oben zu arbeiten, wie meine Beispiele:

Function regex_subst( _
     strInput As String _
   , matchPattern As String _
   , Optional ByVal replacePattern As String = "" _
) As Variant
    Dim inputRegexObj As New VBScript_RegExp_55.RegExp

    With inputRegexObj
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
        .Pattern = matchPattern
    End With

    regex_subst = inputRegexObj.Replace(strInput, replacePattern)
End Function

InformationsquelleAutor der Antwort jgreve