Warum nicht diese FINDSTR Beispiel mit mehreren wörtlichen Suchbegriffen gefunden wird?

Ich kann nicht sagen, warum findstr kann fehlschlagen, mit mehreren literalen strings verwendet werden. Aber ich kann eine Methode zum umgehen der lästigen bug.

Gegeben, dass die buchstäbliche Suche nach Zeichenfolgen in einer Textdatei aufgelistet namens search_strings.txt...:

ffffaaa
faffaffddd

..., können Sie konvertieren Sie es in regulären Ausdrücken, indem Sie einen backslash vor jedes einzelne Zeichen:

@echo off
setlocal EnableExtensions DisableDelayedExpansion
> "regular_expressions.txt" (
    for /F usebackq^ delims^=^ eol^= %%S in ("search_strings.txt") do (
        set "REGEX=" & set "STRING=%%S"
        for /F delims^=^ eol^= %%T in ('
            cmd /U /V /C echo(!STRING!^| find /V ""
        ') do (
            set "ESCCHR=\%%T"
            if "%%T"="<" (set "ESCCHR=%%T") else if "%%T"=">" (set "ESCCHR=%%T")
            setlocal EnableDelayedExpansion
            for /F "delims=" %%U in ("REGEX=!REGEX!!ESCCHR!") do (
                endlocal & set "%%U"
            )
        )
        setlocal EnableDelayedExpansion
        echo(!REGEX!
        endlocal
    )
)
endlocal

Verwenden Sie dann die konvertierte Datei regular_expressions.txt...:

\f\f\f\f\a\a\a
\f\a\f\f\a\f\f\d\d\d

...zu tun, eine Suche nach regulären Ausdrücken, das scheint zu funktionieren, auch mit mehreren Suchbegriffen:

echo ffffaaa| findstr /R /G:"regular_expressions.txt"

Vorangehenden umgekehrten Schrägstriche einfach entkommen jedes Zeichen einschließlich derer, die eine bestimmte Bedeutung im regulären Ausdruck sucht.

Zeichen < und > ausgeschlossen sind, die mit Escapezeichen versehen, um Konflikte zu vermeiden, mit dem Wort Grenzen, die wurden ausgedrückt durch \< und \> wenn die am Anfang und am Ende einer such-Zeichenfolge.

Da reguläre Ausdrücke sind begrenzt auf 254 Zeichen für findstr letzten Versionen von Windows XP (im Gegensatz zu Zeichenketten, die sind beschränkt auf 511 Zeichen), die Länge der original-search-strings ist begrenzt auf 127 Zeichen, da jedes derartige Zeichen ausgedrückt, indem zwei Zeichen durch die Flucht.

Hier ist ein alternativer Ansatz, der entgeht nur die meta-Zeichen ., *, ^, $, [, ], \, ":

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "_META=.*^$[]\"^" & rem (including `"`)
> "regular_expressions.txt" (
    for /F usebackq^ delims^=^ eol^= %%S in ("search_strings.txt") do (
        set "REGEX=" & set "STRING=%%S"
        for /F delims^=^ eol^= %%T in ('
            cmd /U /V /C echo(!STRING!^| find /V ""
        ') do (
            set "CHR=%%T"
            setlocal EnableDelayedExpansion
            if not "!_META!"=="!_META:*%%T=!" set "CHR=\!CHR!"
            for /F "delims=" %%U in ("REGEX=!REGEX!!CHR!") do (
                endlocal & set "%%U"
            )
        )
        setlocal EnableDelayedExpansion
        echo(!REGEX!
        endlocal
    )
)
endlocal

Der Vorteil dieser Methode ist, dass die Länge des such-strings ist nicht mehr begrenzt auf 127 Zeichen aber zu 254 Zeichen minus 1 für jede vorkommende genannten meta-Zeichen, die Anwendung für findstr letzten Versionen von Windows XP.

Hier ist noch ein work-around, mit einem case-insensitive Suche mit findstr auf den ersten Platz, dann post-filtern Sie das Ergebnis, indem Sie groß-und Kleinschreibung Vergleiche:

echo ffffaaa|findstr /L /I "ffffaaa faffaffddd"|cmd /V /C set /P STR=""^&if @^^!STR^^!==@^^!STR:ffffaaa=ffffaaa^^! (echo(^^!STR^^!) else if @^^!STR^^!==@^^!STR:faffaffddd=faffaffddd^^! (echo(^^!STR^^!)

Den Doppel-Escape-Ausrufezeichen sorgen die variable STR erweitert, in dem explizit aufgerufen cmd Instanz auch im Falle verzögerte Erweiterung aktiviert ist, in der hosting - cmd Instanz.

Übrigens, wegen dem, was ich nenne ein design-Fehler, Suchanfragen mit literal-strings mit findstr nie zuverlässig funktioniert, sobald Sie umgekehrte Schrägstriche enthalten, denn solche können noch verzehrt werden, zu entkommen folgende meta-Zeichen, obwohl nicht notwendig, zum Beispiel für die Suche string \. tatsächlich entspricht .; wirklich passen \. buchstäblich, müssen Sie die Suchzeichenfolge \\.. Ich verstehe nicht, warum meta-Zeichen sind noch anerkannt, wenn dabei die wörtliche sucht, das ist nicht was ich Anruf-literal.