Was ist der beste Weg, um den ersten Buchstaben jedes Wortes in einer Zeichenfolge in SQL Server groß zu schreiben

Was ist der beste Weg, um davon zu profitieren muss der erste Buchstabe jedes Wortes in einem string in SQL Server.

InformationsquelleAutor der Frage Magpie | 2008-09-10

  1. 64

    Vom http://www.sql-server-helper.com/functions/initcap.aspx

    CREATE FUNCTION [dbo].[InitCap] ( @InputString varchar(4000) ) 
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 1

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                         ELSE SUBSTRING(@InputString, @Index - 1, 1)
                    END

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    BEGIN
        IF @PrevChar != '''' OR UPPER(@Char) != 'S'
            SET @OutputString = STUFF(@OutputString, @Index, 1, UPPER(@Char))
    END

    SET @Index = @Index + 1
END

RETURN @OutputString

END
GO

    Gibt es eine einfachere/kleinere hier (aber funktioniert nicht, wenn eine Zeile nicht mit Leerzeichen, "Ungültige Länge parameter übergeben, um die RICHTIGE Funktion."):

    http://www.devx.com/tips/Tip/17608

    InformationsquelleAutor der Antwort Espo

  2. 1

    Andere Lösung ohne Verwendung der loop - pure-set-basierten Ansatz mit rekursiven CTE

    create function [dbo].InitCap (@value varchar(max))
returns varchar(max) as
begin

    declare
        @separator char(1) = ' ',
        @result varchar(max) = '';

    with r as (
        select value, cast(null as varchar(max)) [x], cast('' as varchar(max)) [char], 0 [no] from (select rtrim(cast(@value as varchar(max))) [value]) as j
        union all
        select right(value, len(value)-case charindex(@separator, value) when 0 then len(value) else charindex(@separator, value) end) [value]
        , left(r.[value], case charindex(@separator, r.value) when 0 then len(r.value) else abs(charindex(@separator, r.[value])-1) end ) [x]
        , left(r.[value], 1)
        , [no] + 1 [no]
        from r where value > '')

    select @result = @result +
    case
        when ascii([char]) between 97 and 122 
            then stuff(x, 1, 1, char(ascii([char])-32))
        else x
    end + @separator
    from r where x is not null;

    set @result = rtrim(@result);

    return @result;
end

    InformationsquelleAutor der Antwort Andrey Morozov

  3. 0

    Eine Variante von der, die ich habe mit seit einiger Zeit:

    CREATE FUNCTION [widget].[properCase](@string varchar(8000)) RETURNS varchar(8000) AS
BEGIN   
    SET @string = LOWER(@string)
    DECLARE @i INT
    SET @i = ASCII('a')
    WHILE @i <= ASCII('z')
    BEGIN
        SET @string = REPLACE( @string, ' ' + CHAR(@i), ' ' + CHAR(@i-32))
        SET @i = @i + 1
    END
    SET @string = CHAR(ASCII(LEFT(@string, 1))-32) + RIGHT(@string, LEN(@string)-1)
    RETURN @string
END

    Können Sie leicht ändern Sie verarbeiten Zeichen, nachdem andere Elemente als Räume, wenn Sie wollte.

    InformationsquelleAutor der Antwort Josef

  4. 0

    Hier ist die einfachste one-line-code. 

    select 
        LEFT(column, 1)+ lower(RIGHT(column, len(column)-1) )
     from [tablename]

    InformationsquelleAutor der Antwort Amrik

  5. 0

    Als eine Tabellenwert-Funktion:

    CREATE FUNCTION dbo.InitCap(@v AS VARCHAR(MAX))
RETURNS TABLE
AS
RETURN 
WITH a AS (
    SELECT (
        SELECT UPPER(LEFT(value, 1)) + LOWER(SUBSTRING(value, 2, LEN(value))) AS 'data()'
        FROM string_split(@v, ' ')
        FOR XML PATH (''), TYPE) ret)

SELECT CAST(a.ret AS varchar(MAX)) ret from a
GO

    Beachten Sie, dass string_split erfordert COMPATIBILITY_LEVEL 130.

    InformationsquelleAutor der Antwort Kristofer

  6. 0
    BEGIN
DECLARE @string varchar(100) = 'asdsadsd asdad asd'
DECLARE @ResultString varchar(200) = ''
DECLARE @index int = 1
DECLARE @flag bit = 0
DECLARE @temp varchar(2) = ''
WHILE (@Index <LEN(@string)+1)
BEGIN
    SET @temp = SUBSTRING(@string, @Index-1, 1)
    --select @temp
    IF @temp = ' ' OR @index = 1
        BEGIN
            SET @ResultString = @ResultString + UPPER(SUBSTRING(@string, @Index, 1))
        END
    ELSE
        BEGIN

            SET @ResultString = @ResultString + LOWER(SUBSTRING(@string, @Index, 1)) 
        END 

    SET @Index = @Index+ 1--increase the index
END
SELECT @ResultString

    ENDE

    InformationsquelleAutor der Antwort Vignesh Sonaiya

  7. -1

    Sollten Sie versuchen, diese stattdessen

    Select INITCAP(column_name) from table_name;

    Dies die Anfangsbuchstaben der genannten Attributen Einträge.

    InformationsquelleAutor der Antwort GOLDY AGARWAL

Schreibe einen Kommentar