Wenn die Bedingung in PL/SQL-Skript mit cursor und loop

Ich würde Sie gerne Fragen, wie Sie nach Hilfe oder Beratung in diesem speziellen Fall.

Ich habe die Tabelle "Teams". Die Tabelle enthält 3 Spalten - Problem, Responsible_team und More_Info (alle varchar2).

Habe ich eine PL/SQL-Skript mit cursor und eine Schleife für die Auswahl, wie viele teams als Problem Beschreibung, die Sie geben (einige zufällige Wort, das Sie denken, es könnte Ihnen helfen, das verantwortliche team). Das Teil funktioniert großartig für mich.

Aber ich weiß nicht, wie zu kompilieren, die IF-Bedingung drin. Wenn kein team fand nach eingegebenen Wort Beschreibung, würde ich gerne einige grundlegende Ausgabe dbms_output.put_line ("Verantwortliches team ist nicht gefunden').
Es gibt 2 Möglichkeiten, wie ich das Skript schrieb. Classic loop-und while-Schleife.
Ich wäre froh für jeden Rat.

1.Skript

set verify off
DECLARE
    v_issue teams.issue%type; --variable for issue column from teams table
    v_respteam teams.responsible_team%type; --variable for responsible_team column from teams table
    v_info teams.more_info%type; --variable for more_info column from teams table

--cursor declaration
    CURSOR c_respteam
    RETURN teams%ROWTYPE
    IS
        SELECT issue, responsible_team, more_info
        FROM teams
        WHERE lower(issue) like '%&Describe_Issue%';
BEGIN
    OPEN c_respteam;
    LOOP
      FETCH c_respteam into v_issue, v_respteam, v_info;
      EXIT when c_respteam%NOTFOUND;
      dbms_output.put_line('Responsible team is '|| v_respteam || ' --> ' || v_info);        
    END LOOP;
    CLOSE c_respteam;
end;
/

2.Skript

-- cursor with while loop
set verify off
DECLARE
    v_issue teams.issue%type; --variable for issue column from teams table
    v_respteam teams.responsible_team%type; --variable for responsible_team column from teams table
    v_info teams.more_info%type; --variable for more_info column from teams table

CURSOR c_respteam
RETURN teams%ROWTYPE IS
    SELECT issue, responsible_team, more_info
    FROM teams
    WHERE lower(issue) like '%&Describe_Issue%';

BEGIN
OPEN c_respteam;
FETCH c_respteam INTO v_issue, v_respteam, v_info;
WHILE c_respteam%FOUND
LOOP
dbms_output.put_line('Responsible team is '|| v_respteam || ' --> ' || v_info);
FETCH c_respteam INTO v_issue, v_respteam, v_info;
END LOOP;
CLOSE c_respteam;
END;
/

InformationsquelleAutor Michael Ondriska | 2015-07-17

Könnte man umschreiben zu:

declare
   l_found boolean :=false;

   cursor c_respteam is
      select issue
            ,responsible_team
            ,more_info
        from teams
       where lower(issue) like '%&Describe_Issue%';
begin
   for r in c_respteam
   loop
      l_found := true;
      dbms_output.put_line('Responsible team is ' || r.responsible_team || ' --> ' || r.more_info);
   end loop;

   if not l_found
   then
      dbms_output.put_line('No records found');
   end if;
end;
/

Ich danke Ihnen sehr. Ich dachte über Boolesche aber ich wusste nicht, wie zu kompilieren wie ich bin die Art von newbie.

InformationsquelleAutor Rene

1

Müssen Sie eine counter-variable [ETA: Oh, ich mag Rene booleschen variable Idee statt; entweder Weg, müssen Sie eine zusätzliche variable!] um herauszufinden, ob alle Zeilen zurückgegeben wurden, oder nicht. Ich bin mir nicht sicher, warum Sie eine explizite cursor, fetch, anstatt mit den cursor-for-Schleife? Cursor-for-Schleifen sind nicht nur leichter zu schreiben, zu Lesen und zu pflegen, aber Oracle habe einige hinter-den-kulissen-Optimierung in der Hilfe Leistung.

Natürlich abhängig davon, was Sie eigentlich tun mit den zurückgegebenen Daten durch den cursor (dbms_output.put_line etwas, das Sie sollten nie in Ihren Produktions-code), es ist fraglich,, die Sie benötigen würden, um eine Schleife durch einen cursor überhaupt.

Sowieso, mit dieser sagte, hier ist ein Beispiel, wie ich das handhaben würde, Ihre Anforderung zu prüfen, werden keine Zeilen zurückgegeben, die mit dem cursor:
```
declare
  cursor cur (p_val varchar2)
  is
    select dummy
    from   dual
    where  dummy like '%'||p_val||'%';

  v_counter integer := 0;
begin
  for rec in cur('Y')
  loop
    dbms_output.put_line('value of dummy = '||rec.dummy);
    v_counter := v_counter + 1;
  end loop;
  if v_counter = 0 then
    dbms_output.put_line('no rows returned');
  end if;
end;
/

no rows returned

declare
  cursor cur (p_val varchar2)
  is
    select dummy
    from   dual
    where  dummy like '%'||p_val||'%';

  v_counter integer := 0;
begin
  for rec in cur('X')
  loop
    dbms_output.put_line('value of dummy = '||rec.dummy);
    v_counter := v_counter + 1;
  end loop;
  if v_counter = 0 then
    dbms_output.put_line('no rows returned');
  end if;
end;
/

value of dummy = X
```
Ergänzen, was ich sagte, in meinem Kommentar, es klingt wie Sie brauchen nur eine einzelne sql-Anweisung, anstatt mit PL/SQL und unter Berufung auf dbms_output.

ZB., sagen, Sie haben die folgende Anweisung:
```
select lvl
from   (select 'X'||level lvl from dual connect by level <= 10)
where  lvl like '%&val%';
```
mit &val leer, erhalten Sie:
```
LVL                                      
-----------------------------------------
X1                                       
X2                                       
X3                                       
X4                                       
X5                                       
X6                                       
X7                                       
X8                                       
X9                                       
X10    
```
Mit &val = 2 erhalten Sie:
```
LVL                                      
-----------------------------------------
X2                                       
```
Mit &val = 100 erhalten Sie:
```
no rows selected.
```
- Wie ich bereits in Rene ' s Kommentar ich bin Neuling. Ich bin immer noch lernen. Dieses Skript ist nicht speziell für Produktion und Umwelt, aber für meine Bedürfnisse bei der Arbeit. Einfach gesagt, genau Teil meiner Arbeit ist verantwortlich für die Besitzer von tickets mit Problemen. Ich muss wissen, wer ist verantwortlich für das genaue Problem. Und ich spreche über eine Vielzahl von Themen und teams verantwortlich. Dies ist also nur für mich, da ich meine eigene Tabelle und das Skript ist eine schnellere Lösung, wie Sie zu finden, das team. Danke Boneist sowieso. Es ist sehr hilfreich.
- In diesem Fall hätte ich gedacht, dass eine einzelne select-Anweisung, die Ihren Bedürfnissen entsprechen würde, besser, eher, als pl/sql!
InformationsquelleAutor Boneist

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.