Wie archivieren Sie jeden Ordner in einem Verzeichnis einzeln mit WinRAR?

Hier ist eine batch-Datei für mehr Allgemeine Verwendung dieser gemeinsamen Aufgabe werden, denn der Ordner mit den Unterordnern zu archivieren, können angegeben werden, die als ersten parameter die beim ausführen der batch-Datei.

@echo off
setlocal
set "BackupFolder=C:\Backup"

rem Folder to archive can be optionally specified as parameter.
if "%~1" == "" (
    set "FolderToArchive=C:\projects"
) else (
    set "FolderToArchive=%~1"
)

rem Check existence of the folder to archive.
if not exist "%FolderToArchive%\*" (
    echo.
    echo Error: Folder %FolderToArchive% does not exist.
    echo.
    endlocal
    pause
    goto :EOF
)

rem Check existence of backup folder and create this folder
rem if not already existing with verification on success.
if not exist "%BackupFolder%\*" (
    md "%BackupFolder%"
    if errorlevel 1 (
        echo.
        echo Error: Folder %BackupFolder% could not be created.
        echo.
        endlocal
        pause
        goto :EOF
    )
)

rem Archive each subfolder in specified or default folder to archive
rem as separate archive with name of folder as archive file name and
rem with current date and an automatically incremented number with at
rem least 2 digits appended to the archive file name to be able to
rem create multiple archives on different days and even on same day.

rem Parent directory path of each subfolder is removed from archive.
rem The name of the subfolder itself is added to each archive. This
rem can be changed by replacing "%%D" with "%%D\" or "%%D\*". Then
rem the files and subfolders of the compressed folder would be added
rem to archive without the name of the compfessed folder.

rem Best compression is used on creating a solid archive with 4 MB
rem dictionary size. All messages are suppressed except error messages.
rem The last modification time of the created archive file is set to
rem date and time of newest file inside the archive.

set "RarError=0"

for /D %%D in ("%FolderToArchive%\*") do (
    echo Archiving %%D ...
    "%ProgramFiles%\WinRAR\Rar.exe" a -ag_YYYY-MM-DD_NN -cfg- -ep1 -idq -m5 -md4m -r -s -tl -y "%BackupFolder%\%%~nD.rar" "%%D"
    if errorlevel 1 set "RarError=1"
)

rem Wait for a key press if an error occurred on creating an archive file.
if "%RarError%" == "1" (
    echo.
    pause
)
endlocal

Details über die verwendeten Schalter auf Rar Befehlszeile öffnen der text-Datei Rar.txt im program files Ordner von WinRAR das ist das Handbuch für die Konsolen-version Rar.exe und Lesen Sie die Erklärungen für diese Schalter.

Hinweis: Befehl eine (zu Archiv hinzufügen) wird in der batch-code oben statt m (bewegen zu archivieren).

Handbuch für den Einsatz WinRAR.exe aus einer batch-Datei finden Sie in der Hilfe von WinRAR auf der Registerkarte Inhalt unter Punkt Command-line-Modus.

Gibt es einige Unterschiede, auf die Liste der switches zwischen Konsole und GUI-version von WinRAR. Zum Beispiel WinRAR.exe unterstützt auch die Erstellung von ZIP-Archiven, die Rar.exe nicht unterstützt. Daher WinRAR.exe unterstützt der switch -af<type> die Konsolen-version nicht. Oder der Schalter -idq (quiet-Modus) der Konsolen-version ist der Schalter -ibck (ausführen im hintergrund) für die GUI-version.

Für das Verständnis der verwendeten Befehle und wie Sie funktionieren, öffnen Sie eine Eingabeaufforderung-Fenster, führen Sie dort die folgenden Befehle ein, und Lesen Sie ganz alle Hilfe-Seiten angezeigt, die für jeden Befehl sehr sorgfältig.

• echo /?
• endlocal /?
• for /?
• if /?
• md /?
• pause /?
• rem /?
• set /?
• setlocal /?

Hinweis: Solch eine Archivierung kann auch mit WinRAR, indem Sie in WinRAR den Ordnern zu archivieren, klicken Sie auf Hinzufügen Symbol in der Werkzeugleiste, einfügen C:\Backup\ auf Archiv name und aktivieren die option Setzen Sie jede Datei auf separaten Archiv auf der Registerkarte Dateien. Die anderen Optionen eingesetzt in die obige batch-Datei definiert, die über Schalter kann gefunden werden auf den Registerkarten Allgemeinen, Backup und Zeit.