Wie bekomme ich die data des URLRequest-von der Kompletten Event-handler für ein URLLoader-in AS3

Habe ich eine Warteschlange von Nachrichten, die ich möchte senden auf eine URL, und ich möchte zum entfernen von Nachrichten aus dieser Warteschlange erst nachdem ich sicher bin, dass Sie erfolgreich gesendet wurden. Um dies zu tun muss ich wissen, in der COMPLETE Ereignis für die URLLoader genau, welche Daten gesendet wurde, so, dass ich entfernen können, die richtige Nachricht aus der Warteschlange.

Das ist, wenn ich so etwas haben.

var urlRequest:URLRequest = new URLRequest(targetUrl);  
var urlLoader:URLLoader = new URLLoader();  
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;  
urlRequest.data = "test";  

urlRequest.method = URLRequestMethod.POST;  
urlLoader.addEventListener(Event.COMPLETE, handleComplete);  
urlLoader.load(urlRequest);

Dann meine handleComplete-Funktion ist wie folgt:

public function handleComplete(e:Event):void{  

   //How do I trace the urlRequest.data for this event, whats below does not work.  
   //Because the target of the event is the URLLoader, not the URLRequest.  

   trace(e.target.data);  
}
Schicken Sie diese an ein php-Skript? denn dann weiß ich die Antwort.
Wäre es zu einem server-side script, wäre es wahrscheinlich pearl, aber php würde auch funktionieren.
trace(urlLoader.Daten);
auch rufen "targetUrl" in einen browser, und stellen Sie sicher, es ist nicht wieder ein Fehler
trace(urlLoader.Daten); funktioniert nicht, urlLoader.Daten wird nur verfolgt als "undefined", wenn ich versuche es. Die "targetURL" - funktioniert, und die Nachrichten, die ich sende sind geloggt auf meinem server mit einem php-Skript. Ich weiß nur nicht, wie überprüfen Sie die client-Seite in mein AS3-code, der Sie empfangen wurden.

InformationsquelleAutor Alex | 2011-03-17

  1. 1

    Ihre Frage zu beantworten, wie man die URLRequest - Objekt können Sie einfach erstellen Sie Ihre eigenen benutzerdefinierten URLLoader Klasse, die speichert die URLRequest Objekt. Das folgende ist ein Beispiel dafür:

    CustomURLLoader.als:

    package
{
    import flash.net.URLLoader;
    import flash.net.URLRequest;

    public class CustomURLLoader extends URLLoader
    {
        private var _urlRequest:URLRequest;

        public function get urlRequest():URLRequest
        {
            return _urlRequest;

        }//end function

        public function CustomURLLoader(urlRequest:URLRequest)
        {
            super(urlRequest);
            _urlRequest = urlRequest;

        }//end function

    }//end class

}//end package

    Main.als(Dokument-Klasse):

    package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;

    public class Main extends Sprite
    {
        public function Main()
        {
            if(stage) init()
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }//end function

        public function init(e:Event = null):void
        {
            var urlRequest:URLRequest = new URLRequest("file.php");
            urlRequest.data = "test"; 
            urlRequest.method = URLRequestMethod.POST;  
            var customURLLoader:CustomURLLoader = new CustomURLLoader(urlRequest);
            customURLLoader.addEventListener(Event.COMPLETE, onCustomURLLoaderComplete);

        }//end function

        private function onCustomURLLoaderComplete(e:Event):void
        {
            var customURLLoader:CustomURLLoader = e.target as CustomURLLoader;
            trace(customURLLoader.urlRequest.data); //output: test

        }//end function

    }//end class

}//end package
    Genial, das macht absolut Sinn und scheint, wie es funktionieren sollte. Ich werde versuchen Sie es zuerst, was morgen ist :). Danke!
    Ich hoffe es hilft, und wenn es das tut, sollten Sie dies akzeptieren, da die Antwort für diese Frage.
    Habe es ausprobiert und es funktionierte wie ein Charme 🙂 Danke, habe ich als Antwort.

    InformationsquelleAutor Taurayi

Schreibe einen Kommentar