Wie bekomme ich eine andere Anwendung das Fenster-handle übergeben Delphi per Mausklick

Den Ansatz, dass Nutzer STATUS_ACCESS_DENIED, die in dem Kommentar ist wahrscheinlich der einfachste Weg, hier zu gehen. Ich würde empfehlen, mit Maus erfassen über Einhaken, weil es etwas einfacher zu implementieren.

Hier ist eine etwas ausführlichere Zusammenfassung von dem, was ist beteiligt:

Die erste Sache, die die Art ändern, wie das Auswahlverfahren funktioniert. Anstatt den Benutzer auf eine Schaltfläche klicken Sie auf Ihre app, um den Prozess zu starten, und klicken Sie dann auf das Ziel-Fenster, und klicken Sie schließlich erneut zu bestätigen; es ist viel einfacher zu implementieren, wenn Sie der Benutzer auf einen bestimmten Bereich Ihrer app, dann ziehen auf das Zielfenster und lassen Sie die Maustaste, während Sie über das Ziel hinaus. Dies ist, weil windows die Auffassung, dass ein Klick auf eine andere app zu gehören, die app, und Sie haben, um zusätzliche Arbeit zu tun, um Sie abzufangen. Doch es gibt einen einfachen Weg - genannte Maus-capture, um Informationen über eine drag/release wenn es beginnt wie ein Klick auf Ihrer eigenen app.

Dies ist auch der Ansatz, dass der Windows-SDK-tool Spy++ verwendet; also by doing es auf diese Weise, Sie sind auch im Einklang mit einem bekannten tool. (Pic von Spy++ hier - beachten Sie das Fadenkreuz Finder-Tool im dialog - das ist es, was Sie klicken und ziehen, um das Ziel. Würde empfehlen, das Windows SDK heruntergeladen und das Spiel mit diesem tool, wenn Sie nicht getan haben, bevor, es ist auch eine sehr nützliche Möglichkeit, zu sehen, wie andere Anwendungen sind gebaut, so groß, wie eine Windows-API-learning-tool.)

Schritte:

• Haben eine gewisse Kontrolle Ihrer app, die Reaktion auf mouse-down-events (WM_LBUTTONDOWN in Win32/C, OnMouseDown in delphi). Möchten Sie vielleicht ein Fadenkreuz-Symbol oder ähnliches hier, damit der Anwender weiß, wo Sie klicken.
• Wenn man eine Maus nach unten, verwenden SetCapture zu 'erfassen' die Maus. Dies bedeutet, dass die Kontrolle erhalten alle Maus-Nachrichten, während Sie die Maus bewegen, bis der Benutzer lässt den Knopf - auch wenn er sich bewegt, die außerhalb der Kontrolle.
• Legen Sie das Symbol aus wie ein Fadenkreuz, so dass der Benutzer weiß, sind Sie in der ziehen-Modus
• Wie der Benutzer die Maus bewegt, bekommen Sie die WM_MOUSEMOVE-Nachricht (OnMouseMove in Delphi), die die pointer-Koordinaten. Benötigen Sie zu konvertieren ClientToScreen diese Bildschirm-Koordinaten, dann WindowFromPoint zu finden, das Fenster an diesem Punkt. (Beachten Sie, dass diese Funde die innerste Fenster an diesem Punkt, Sie könnte verwenden ChildWindowFromPoint-ausgehend von der desktop-Fenster zu bekommen, die top-level-Fenster, wenn Sie wollen.) Es ist bis zu Ihnen, zu entscheiden, ob Sie zum aktualisieren der Benutzeroberfläche bei jeder Maus Bewegung durch das ziehen, oder nur wenn der Benutzer die Maustaste loslässt.
• Wenn der Benutzer die Maustaste loslässt, bekommst du eine WM_LBUTTONUP/OnMouseUp; in diesem Stadium, Dinge einpacken durch Aufruf von ReleaseCapture und setzen Sie den cursor wieder auf normal Form.

Beachten Sie, dass Sie mit der Maus verschieben, Veranstaltungen, sowohl während des ziehen, auch wenn der Benutzer gerade passiert, bewegen Sie den Mauszeiger über Ihre Steuern, vielleicht auf dem Weg zu einigen anderen Steuern. Der einfachste Weg, zu sagen, in diesen zwei Fällen abgesehen, ist die Verwendung einer Flagge in Ihrer Hand, die Sie festlegen, wenn Sie mit der Maus nach unten, und klar, wenn man die Maus nach oben, und verarbeiten nur die Maus bewegen-Ereignisse, wenn das flag gesetzt ist.

Oben beschrieben, den Prozess im Hinblick auf einfache Win32-APIs, die Sie nennen würden, die von C/C++; aber es sieht aus wie Delphi bietet direkte Unterstützung für die meisten oder alle von Ihnen.

edit: Möglich Delphi-Umsetzung:

type
  TForm1 = class(TForm)
    Label1: TLabel;
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
    procedure FormPaint(Sender: TObject);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    FCacheWnd: HWND;
    FCaptured: Boolean;
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const  // the first item, the place where the crosshair is
  ClickRect: TRect = (Left: 10; Top: 10; Right: 44; Bottom: 44);

procedure TForm1.FormPaint(Sender: TObject);
begin
  // draw the control and the crosshair if no capturing
  if GetCapture <> Handle then begin  
    DrawFrameControl(Canvas.Handle, ClickRect, 0, DFCS_BUTTONPUSH);
    DrawIcon(Canvas.Handle, ClickRect.Left, ClickRect.Top,
              Screen.Cursors[crCross]);
  end;
end;

procedure TForm1.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if (Button = mbLeft) and (Shift = [ssLeft])
      and PtInRect(ClickRect, Point(X, Y)) then begin
    // the second item, draw the control pressed,
    // set the flag and the capture. FCacheWnd is used not to get
    // window information for every mouse move - if the window under the
    // mouse is not changed.
    DrawFrameControl(Canvas.Handle, ClickRect, 0, DFCS_PUSHED);
    FCacheWnd := 0;
    FCaptured := True;
    SetCapture(Handle);
    Screen.Cursor := crCross; // the third item, set the cursor to crosshair.
  end;
end;

function GetWndFromClientPoint(ClientWnd: HWND; Pt: TPoint): HWND;
begin
  MapWindowPoints(ClientWnd, GetDesktopWindow, Pt, 1);
  Result := WindowFromPoint(Pt);
end;

function GetWndInfo(Wnd: HWND): string;
var
  ClassName: array [0..256] of Char;
begin
  Result := '';
  if IsWindow(Wnd) then begin
    GetClassName(Wnd, ClassName, 256);
    Result := Format('Window: %x [%s]', [Wnd, ClassName]);
    if (GetWindowLong(Wnd, GWL_STYLE) and WS_CHILD) = WS_CHILD then begin
      Wnd := GetAncestor(Wnd, GA_ROOT);
      GetClassName(Wnd, ClassName, 256);
      Result := Format(Result + sLineBreak + 'Top level: %x [%s]', [Wnd, ClassName]);
    end;
  end;
end;

procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  Wnd: HWND;
begin
  if FCaptured then begin
    // fourth item, convert coordinates and find the window under the cursor
    Wnd := GetWndFromClientPoint(Handle, Point(X, Y));
    if Wnd <> FCacheWnd then 
      Label1.Caption := GetWndInfo(Wnd);
    FCacheWnd := Wnd;
  end;
end;

procedure TForm1.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if FCaptured then begin
    // fifth item
    FCaptured := False;
    ReleaseCapture;
    InvalidateRect(Handle, @ClickRect, False); // invalidate pressed look
    Screen.Cursor := crDefault;
  end;
end;