Wie eine Datei Lesen und schreiben in eine text-Datei?

Ich das öffnen will mis-Datei, kopieren Sie alle Daten und schreiben in eine text-Datei.

Meine mis-Datei.

Dateiname – 1.mis

M3;3395;44;0;1;;20090404;094144;8193;3;0;;;;
M3;3397;155;0;2;;20090404;105941;8193;3;0;;;;
M3;3396;160;0;1;;20090404;100825;8193;3;0;;;;
M3;3398;168;0;2;;20090404;110106;8193;3;0;;;;

usw...,

Oben sollten die Daten werden in einer text-Datei mit dem gleichen Dateinamen (1.txt).

Ich habe versucht, diesen code.

Dim sFileText As String
Dim iFileNo As Integer
iFileNo = FreeFile
Open "C:\Clients\Converter\Clockings.mis" For Input As #iFileNo
Do While Not EOF(iFileNo)
Input #iFileNo, sFileText
Loop
Close #iFileNo

Open "C:\Clients\Converter\2.txt" For Output As #iFileNo
Do While Not EOF(iFileNo)
Write #iFileNo, sFileText
Loop
Close #iFileNo

Nichts gespeichert ist 1.txt.

Gut, wenn Ihr mis-Datei speichert die Daten als text, können Sie einfach kopieren Sie die Datei auf 1.txt... 🙂
Es gibt nichts in 1.txt denn Sie schreiben zu 2.txt...

InformationsquelleAutor Gopal | 2009-09-10

file-io vb6

Es wesentlich einfacher mit dem scripting runtime installiert ist standardmäßig auf Windows

Gehen Sie einfach Projekt-Referenz und überprüfen Sie "Microsoft Scripting Runtime" und klicken Sie auf OK.

Dann können Sie diesen code verwenden, die ist viel besser als die Standard-Datei-Befehle

Dim FSO As FileSystemObject
Dim TS As TextStream
Dim TempS As String
Dim Final As String
Set FSO = New FileSystemObject
Set TS = FSO.OpenTextFile("C:\Clients\Converter\Clockings.mis", ForReading)
'Use this for reading everything in one shot
Final = TS.ReadAll
'OR use this if you need to process each line
Do Until TS.AtEndOfStream
    TempS = TS.ReadLine
    Final = Final & TempS & vbCrLf
Loop
TS.Close

Set TS = FSO.OpenTextFile("C:\Clients\Converter\2.txt", ForWriting, True)
    TS.Write Final
TS.Close
Set TS = Nothing
Set FSO = Nothing

Als für das, was ist falsch mit Ihrem original-code hier liest du jede Zeile der text-Datei.

Input #iFileNo, sFileText

Dann hier schreiben

Write #iFileNo, sFileText

sFileText ist eine string-variable also, was geschieht ist, dass jedes mal, wenn Sie Lesen, Sie ersetzen Sie einfach den Inhalt sFileText mit dem Inhalt der Zeile, die Sie gerade Lesen.

Also, wenn Sie gehen, um es schreiben, alles, was Sie schreiben, ist die Letzte Zeile, die Sie Lesen, das ist wahrscheinlich eine leere Zeile.

Dim sFileText As String
Dim sFinal as String
Dim iFileNo As Integer
iFileNo = FreeFile
Open "C:\Clients\Converter\Clockings.mis" For Input As #iFileNo
Do While Not EOF(iFileNo)
  Input #iFileNo, sFileText
sFinal = sFinal & sFileText & vbCRLF
Loop
Close #iFileNo

iFileNo = FreeFile 'Don't assume the last file number is free to use
Open "C:\Clients\Converter\2.txt" For Output As #iFileNo
Write #iFileNo, sFinal
Close #iFileNo

Hinweis: Sie brauchen nicht zu tun, eine Schleife zu schreiben. sFinal enthält den vollständigen text der Datei fertig geschrieben werden, in einem Schuss. Beachten Sie, dass input liest eine ZEILE in einer Zeit, so dass jede Zeile, die angehängt sFinal muss ein CR und LF angehängt an das Ende geschrieben werden ordnungsgemäß auf einem MS Windows-system. Andere Betriebssystem kann nur noch ein LF (Chr$(10)).

Wenn Sie brauchen, um die eingehenden Daten verarbeitet werden, dann müssen Sie etwas tun, wie diese.

Dim sFileText As String
Dim sFinal as String
Dim vTemp as Variant
Dim iFileNo As Integer
Dim C as Collection
Dim R as Collection
Dim I as Long
Set C = New Collection
Set R = New Collection

iFileNo = FreeFile
Open "C:\Clients\Converter\Clockings.mis" For Input As #iFileNo
Do While Not EOF(iFileNo)
  Input #iFileNo, sFileText
  C.Add sFileText
Loop
Close #iFileNo

For Each vTemp in C
     Process vTemp
Next sTemp

iFileNo = FreeFile
Open "C:\Clients\Converter\2.txt" For Output As #iFileNo
For Each vTemp in R
   Write #iFileNo, vTemp & vbCRLF
Next sTemp
Close #iFileNo

Einige Benutzer-Computer haben keine "FileSystemObject" (habe ich erlebt). Ich denke, dass übereifrige IT-Abteilungen manchmal trampeln auf die scripting runtime aus Angst vor Viren
Ja, das ist der Grund, warum sollten Sie auch als Teil Ihrer Installation. Der Administrator kann dann entscheiden, ob eine Ausnahme für die Anwendung. Oder machen Sie Ihre eigene version einwickeln der native Funktion oder wickeln Sie die .NET-äquivalent bis. Beide sind übertrieben, IMO.

InformationsquelleAutor RS Conley

Wenn Sie wollen, es zu tun, Zeile für Zeile:

Dim sFileText As String
Dim iInputFile As Integer, iOutputFile as integer

iInputFile = FreeFile
Open "C:\Clients\Converter\Clockings.mis" For Input As #iInputFile 
iOutputFile = FreeFile
Open "C:\Clients\Converter\2.txt" For Output As #iOutputFile 
Do While Not EOF(iInputFile)
   Line Input #iInputFile , sFileText
   ' sFileTextis a single line of the original file
   ' you can append anything to it before writing to the other file
   Print #iOutputFile, sFileText 
Loop
Close #iInputFile 
Close #iOutputFile

InformationsquelleAutor C-Pound Guru

2
```
FileCopy "1.mis", "1.txt"
```
- Filecopy funktioniert, Angenommen, ich möchte etwas hinzufügen, die in einer Ziel-Textdatei, Wie man code.
InformationsquelleAutor nothrow

    An example of reading a file:
Dim sFileText as String
Dim iFileNo as Integer
iFileNo = FreeFile
'open the file for reading
Open "C:\Test.txt" For Input As #iFileNo
'change this filename to an existing file! (or run the example below first)

'read the file until we reach the end
Do While Not EOF(iFileNo)
Input #iFileNo, sFileText
'show the text (you will probably want to replace this line as appropriate to your program!)
MsgBox sFileText
Loop

'close the file (if you dont do this, you wont be able to open it again!)
Close #iFileNo
(note: an alternative to Input # is Line Input # , which reads whole lines).


An example of writing a file:
Dim sFileText as String
Dim iFileNo as Integer
iFileNo = FreeFile
'open the file for writing
Open "C:\Test.txt" For Output As #iFileNo
'please note, if this file already exists it will be overwritten!

'write some example text to the file
Print #iFileNo, "first line of text"
Print #iFileNo, " second line of text"
Print #iFileNo, "" 'blank line
Print #iFileNo, "some more text!"

'close the file (if you dont do this, you wont be able to open it again!)
Close #iFileNo

Vom Hier

Sehen Sie, @Gopal: Über den Gleichen Daten angezeigt werden soll in eine text-Datei mit dem gleichen. Er/Sie muss ein FileCopy.
In einer Quellcode-Datei habe n die Anzahl der Linien, Wie man einen code?

InformationsquelleAutor Khodor

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.