Wie erstellen Sie eine Prozedur in einer oracle-sql-Skript und verwenden Sie es in das Skript?

Ich möchte erstellen Sie eine Skript für meine oracle DB, die Tropfen Tabellen. Wenn die Tabelle nicht existiert, wird das Skript nicht beenden fehlschlagen, drucken Sie einfach einen text ein: "nicht existiert".

Dem Skript ist die folgende:

BEGIN
    EXECUTE IMMEDIATE 'DROP TABLE mytable';
    DBMS_Output.Put_Line(' table dropped');
EXCEPTION WHEN OTHERS THEN
    IF SQLCODE = -942 THEN
        DBMS_Output.Put_Line(' table not exists');
    ELSE
        DBMS_Output.Put_Line(' Unknown exception while dropping table');
        RAISE;
    END IF;
END;

Will ich fallen eine Menge-Tabelle in ein Skript, und ich will nicht diese Zeilen schreiben, mehr als einmal.

Gibt es eine Möglichkeit, es zu schreiben, um eine Prozedur oder Funktion die bekommt einen parameter (den Namen der Tabelle), und rufen Sie diese Prozedur im Skript?

Vielleicht so etwas wie dieses:

drop_table_procedure('mytableA');
drop_table_procedure('mytableB');

Oder vielleicht ein Verfahren, das bekommt eine Undefinierte Größe der Liste (wie in java: String ... Tabellennamen):

drop_tables_procedure('mytableA','mytableB');

Bitte geben Sie mir einige Beispiele.
Danke!

  • Eine Prozedur erstellen, und übergeben Sie den Tabellenname als ein parameter. Und dann in einen anonymen block, führen alle Verfahren.
InformationsquelleAutor victorio | 2015-11-18
  1. 10

    Ja, können Sie erklären, eine "temporäre" - Verfahren in einem anonymen PL/SQL block:

    DECLARE 

  PROCEDURE drop_if_exists(p_tablename VARCHAR)
  IS
  BEGIN
      EXECUTE IMMEDIATE 'DROP TABLE '||p_tablename;
      DBMS_Output.Put_Line(' table dropped');
  EXCEPTION WHEN OTHERS THEN
      IF SQLCODE = -942 THEN
          DBMS_Output.Put_Line(' table not exists');
      ELSE
          DBMS_Output.Put_Line(' Unknown exception while dropping table');
          RAISE;
      END IF;
  END;

BEGIN
  drop_if_exists('TABLE_1');
  drop_if_exists('TABLE_2');
END;
/
    InformationsquelleAutor a_horse_with_no_name
  2. 1

    in execute immediate Sie benötigen, fügen Sie den Namen des Datenbank-Objekts.
    hier ist das Skript

    create table t1 (col1 int);
create table t2 (col1 int);

create procedure drop_my_table(av_name varchar2)
as
begin
    EXECUTE IMMEDIATE 'DROP TABLE '||av_name;
    DBMS_Output.Put_Line(' table dropped');
EXCEPTION WHEN OTHERS THEN
    IF SQLCODE = -942 THEN
        DBMS_Output.Put_Line(' table not exists');
    ELSE
        DBMS_Output.Put_Line(' Unknown exception while dropping table');
        RAISE;
    END IF;

end drop_my_table;

declare
  type array_t is varray(2) of varchar2(30);
  atbls array_t := array_t('t1', 't2');
begin
  for i in 1..atbls.count loop
       drop_my_table(atbls(i));
   end loop; 
end;
    InformationsquelleAutor are
  3. 1

    Können Sie unten auch 

    create or replace PROCEDURE drop_if_exists(p_tablename in VARCHAR)
      IS
    v_var1 number;
    begin 
    select 1 into v_var1 from user_tables where table_name=upper(p_tablename);
    if v_var1=1
    then 
    EXECUTE IMMEDIATE 'DROP TABLE '||p_tablename;
    DBMS_Output.Put_Line(' table dropped');
    else
    DBMS_Output.Put_Line(' table not exist');
    end if;
    exception 
    when others then
     DBMS_Output.Put_Line(' Unknown exception while dropping table');
            RAISE;
    end;

    Call-Verfahren

        begin 
    drop_if_exists('emp');
    end;
    /
    InformationsquelleAutor Tharunkumar Reddy
Schreibe einen Kommentar