Wie implementieren von Drag & Drop von outlook, mail oder thunderbird, um ein delphi-form?

Erste von allen, wenn Sie finden eine fertige Bibliothek, die sich aus der box (wie die vorgeschlagen von ldsandon) zu verwenden, da dies alles von hand ist schmerzhaft und frustrierend. Die Dokumentation ist stellenweise unvollständig und könnte Fehler enthalten: Sie werden am Ende Dinge tun, durch trial and error und Google wird Sie nicht retten, weil nicht viele Leute Tauchen Sie ein in die tiefen der Ole-drag-und-drop, und die meisten von denen, die tun, wird wahrscheinlich verwenden Sie fertige code.

, Wie dies in reinem Pascal

Theoretisch die API, die verwendet wird, um Ihre Anwendung zu verarbeiten OLE Tropfen ist sehr einfach. Alles, was Sie tun müssen, ist eine Umsetzung der IDropTarget Schnittstelle, die tut, was Sie brauchen, und rufen RegisterDragDrop Bereitstellung der Griff für Ihre Anwendung ist, Fenster und des interface.

Hier ist, wie meine Implementierung sieht so aus:

  TDropTargetImp = class(TInterfacedObject, IDropTarget)
  public
    function DragEnter(const dataObj: IDataObject; grfKeyState: Longint; pt: TPoint; var dwEffect: Longint): HResult; stdcall;
    function DragOver(grfKeyState: Longint; pt: TPoint; var dwEffect: Longint): HResult; stdcall;
    function DragLeave: HResult; stdcall;
    function Drop(const dataObj: IDataObject; grfKeyState: Longint; pt: TPoint; var dwEffect: Longint): HResult; stdcall;
  end;

Die Umsetzung der DragEnter, DragOver und DragLeave trivial ist, considerring ich mache das für ein experiment: ich werde nur akzeptieren alles:

function TDropTargetImp.DragEnter(const dataObj: IDataObject; grfKeyState: Integer; pt: TPoint; var dwEffect: Integer): HResult;
begin
  dwEffect := DROPEFFECT_COPY;
  Result := S_OK;
end;

function TDropTargetImp.DragLeave: HResult;
begin
  Result := S_OK;
end;

function TDropTargetImp.DragOver(grfKeyState: Integer; pt: TPoint; var dwEffect: Integer): HResult;
begin
  dwEffect := DROPEFFECT_COPY;
  Result := S_OK;
end;

Die eigentliche Arbeit geschieht in TDropTargetImp.Drop.

function TDropTargetImp.Drop(const dataObj: IDataObject; grfKeyState: Integer; pt: TPoint; var dwEffect: Integer): HResult;
var iEnum: IEnumFORMATETC;
    DidRead:LongInt;
    F: TFormatEtc;
    STG:STGMEDIUM;
    Response:Integer;

    Stream:IStream;

    Storage: IStorage;
    EnumStg: IEnumStatStg;
    ST_TAG: STATSTG;

    FileStream: TFileStream;
    Buff:array[0..1023] of Byte;
begin
  if dataObj.EnumFormatEtc(DATADIR_GET, iEnum) = S_OK then
  begin

    {
    while (iEnum.Next(1, F, @DidRead) = S_OK) and (DidRead > 0) do
    begin
      GetClipboardFormatName(F.cfFormat, FormatName, SizeOf(FormatName));
      ShowMessage(FormatName + ' : ' + IntToHex(F.cfFormat,4) + '; lindex=' + IntToStr(F.lindex));
    end;
    }

    ZeroMemory(@F, SizeOf(F));
    F.cfFormat := $C105; // CF_FILECONTENTS
    F.ptd := nil;
    F.dwAspect := DVASPECT_CONTENT;
    F.lindex := 0{ -1}; // Documentation says -1, practice says "0"
    F.tymed := TYMED_ISTORAGE;

    Response := dataObj.GetData(F, STG);
    if Response = S_OK then
      begin
        case STG.tymed of
          TYMED_ISTORAGE:
            begin
              Storage := IStorage(STG.stg);
              if Storage.EnumElements(0, nil, 0, EnumStg) = S_OK then
              begin
                while (EnumStg.Next(1, ST_TAG, @DidRead) = S_OK) and (DidRead > 0) do
                begin
                  if ST_TAG.cbSize > 0 then
                  begin
                  Response := Storage.OpenStream(ST_TAG.pwcsName, nil, STGM_READ or STGM_SHARE_EXCLUSIVE, 0, Stream);
                  if Response = S_OK then
                    begin
                      // Dump the stored stream to a file
                      FileStream := TFileStream.Create('C:\Temp\' + ST_TAG.pwcsName + '.bin', fmCreate);
                      try
                        while (Stream.Read(@Buff, SizeOf(Buff), @DidRead) = S_OK) and (DidRead > 0) do
                          FileStream.Write(Buff, DidRead);
                      finally FileStream.Free;
                      end;
                    end
                  else
                    case Response of
                      STG_E_ACCESSDENIED: ShowMessage('STG_E_ACCESSDENIED');
                      STG_E_FILENOTFOUND: ShowMessage('STG_E_FILENOTFOUND');
                      STG_E_INSUFFICIENTMEMORY: ShowMessage('STG_E_INSUFFICIENTMEMORY');
                      STG_E_INVALIDFLAG: ShowMessage('STG_E_INVALIDFLAG');
                      STG_E_INVALIDNAME: ShowMessage('STG_E_INVALIDNAME');
                      STG_E_INVALIDPOINTER: ShowMessage('STG_E_INVALIDPOINTER');
                      STG_E_INVALIDPARAMETER: ShowMessage('STG_E_INVALIDPARAMETER');
                      STG_E_REVERTED: ShowMessage('STG_E_REVERTED');
                      STG_E_TOOMANYOPENFILES: ShowMessage('STG_E_TOOMANYOPENFILES');
                      else
                        ShowMessage('Err: #' + IntToHex(Response, 4));
                    end;
                  end;
                end;
              end;
            end
          else
            ShowMessage('TYMED?');
        end;
      end
    else
      case Response of
        DV_E_LINDEX: ShowMessage('DV_E_LINDEX');
        DV_E_FORMATETC: ShowMessage('DV_E_FORMATETC');
        DV_E_TYMED: ShowMessage('DV_E_TYMED');
        DV_E_DVASPECT: ShowMessage('DV_E_DVASPECT');
        OLE_E_NOTRUNNING: ShowMessage('OLE_E_NOTRUNNING');
        STG_E_MEDIUMFULL: ShowMessage('STG_E_MEDIUMFULL');
        E_UNEXPECTED: ShowMessage('E_UNEXPECTED');
        E_INVALIDARG: ShowMessage('E_INVALIDARG');
        E_OUTOFMEMORY: ShowMessage('E_OUTOFMEMORY');
        else
         ShowMessage('Err = ' + IntToStr(Response));
      end;

  end;
  Result := S_OK;
end;

Dieser code nimmt die "Drop", sieht für einige CF_FILECONTENTS, öffnet es sich wie TYMED_ISTORAGE, fällt jedem einzelnen stream in diesem Speicher, um eine Datei in C:\Temp\<stream_name>.bin; ich habe versucht, diese mit Delphi 2010 und Outlook 2007, es funktioniert alles richtig: Öffnen Sie die gespeicherten Dateien (viele von Ihnen!) Ich kann alles finden, von der E-Mail-Nachricht, in unerwarteter Weise. Ich bin sicher, es gibt Dokumentation, dass irgendwo genau erklärt, was jede dieser Dateien enthalten soll, aber ich weiß nicht wirklich, zu akzeptieren drag-and-Drop Dateien von Outlook so ich schaue nicht zu weit. Wieder, ldsandon ist link sieht vielversprechend aus.

Diese codes sieht ziemlich kurz, aber das ist nicht die Quelle der Schwierigkeiten. Die Dokumentation für diese war wirklich fehlen; ich traf Straßensperren an jeder Ecke, angefangen mit diesem:

F.lindex := 0{ -1}; // Documentation says -1, practice says "0"

Msdn-Dokumentation klar sagt, dass die einzige gültige Wert für das "lindex" - 1: ratet mal, was, -1 funktioniert nicht, 0 nicht!

Dann gibt es diese kurzen code:

Response := Storage.OpenStream(ST_TAG.pwcsName, nil, STGM_READ or STGM_SHARE_EXCLUSIVE, 0, Stream);

besonders die zwei consts:

STGM_READ or STGM_SHARE_EXCLUSIVE

immer, dass die Kombination war eine Sache von trial-and-error. Ich weiß nicht, wie Versuch und Irrtum: das Ist die optimale Kombination von flags für das, was ich will? Wird, dass die Arbeit auf jeder Plattform? Ich weiß nicht...

Dann gibt es die Angelegenheit von machen Sie Kopf oder Schwanz des tatsächlichen Inhalts empfangen von Outlook. Zum Beispiel den BETREFF der E-Mail gefunden wurde, in diesem stream: __substg1.0_800A001F. Der Körper der Nachricht gefunden wurde, die in diesem stream: __substg1.0_1000001F. Für eine einfache E-Mail-Nachricht, die ich bekam 59-streams von nicht-null-Größe.