Wie kann ich bei einem Arbeitsgruppen-computer zu einer Domäne Remote

Szenario: ich bin mit Computer a in einer Domäne mit Administrator-Anmeldeinformationen. Remote ComputerB (mit admin-Anmeldeinformationen bekannt) ist in einer Arbeitsgruppe. ComputerB Anforderungen für den Beitritt zu einer bestimmten Domäne (Anders als Computer a) in eine angegebene ORGANISATIONSEINHEIT die meine aktiv Computer a Anmeldeinformationen haben, das Rechte zu tun. Ich kann Nicht mit einem externen Programm wie NETDOM und würde lieber VBScript verwenden.

Jede Hilfe ist sehr willkommen!

InformationsquelleAutor VoidnessMD | 2012-08-11
  1. 0

    Versuchen, diese, ich angepasst, ein Stück Skript von http://www.tek-tips.com/viewthread.cfm?qid=1240726

    strComputer = "ComputerB"
strPassword = "mypassword"
strDomain   = "mydomain"
strUser     = "myusername"

Set objComputer = GetObject("winmgmts:{impersonationLevel=Impersonate}!\\" & _
    strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
        strComputer & "'")

ReturnValue = objComputer.JoinDomainOrWorkGroup(strDomain, strPassword, strDomain & "\" & strUser, "ou=My_Computer_OU,DC=mycorp,dc=com, _
        JOIN_DOMAIN + ACCT_CREATE)

If ReturnValue = 0 Then
    MsgBox "Computer added to domain under old name without error. proceeding to change computer name. "
Else
    MsgBox "Computer not added to domain successfully. Return value: " & ReturnValue
End If
    • Danke für die Antwort aber endete es herauszufinden auf eigene Faust.
    • dann nehmen Sie eine von den Antworten bitte, da sonst die Leute, die wollen, zu helfen, die Eröffnung dieser Frage
    • Ich versuchte ursprünglich, aber aus irgendeinem Grund machte es mich erst 3 Stunden vor, ich könnte tatsächlich prüfen. Und da ich nicht über 3 Stunden zu sitzen, habe ich natürlich vergessen. Geprüft werden soll jetzt.
    InformationsquelleAutor peter
  2. 0

    Ich war tatsächlich in der Lage zu lösen, diese auf meinem eigenen. Hier ist der code für zukünftige Programmierer:

    Const JOIN_DOMAIN             = 1
Const ACCT_CREATE             = 2
Const ACCT_DELETE             = 4
Const WIN9X_UPGRADE           = 16
Const DOMAIN_JOIN_IF_JOINED   = 32
Const JOIN_UNSECURE           = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET        = 256
Const INSTALL_INVOCATION      = 262144

Const WbemAuthenticationLevelPktPrivacy = 6

SystemName = "ComputerB"
strNamespace = "root\cimv2"
ComputerBLogin= "Login"
ComputerBPass = "Password"
ComputerALogin = "Login"
ComputerAPass = "Password"
DomainName = "domain.com"
OU = "OU=desiredou,DC=domain,DC=com"

Set objWbemLocator = CreateObject("WbemScripting.SWbemLocator")

Set objWMIService = objwbemLocator.ConnectServer(SystemName, strNamespace, ComputerBLogin, ComputerBPass)

objWMIService.Security_.authenticationLevel = WbemAuthenticationLevelPktPrivacy

Set colComputers = objWMIService.ExecQuery _
    ("Select * From Win32_ComputerSystem")
For Each objComputer in colComputers
    ReturnValue = objComputer.JoinDomainOrWorkGroup(DomainName, ComputerAPass, ComputerALogin, OU, JOIN_DOMAIN + ACCT_CREATE)
Next

If Err.Number <> 0 Then
    Set WshShell = CreateObject("WScript.Shell")
    message = WshShell.Popup ("Unable to join " & SystemName & " to the domain! Please join manually.",, "Error", 0 + 16)
Else
    Set WshShell = CreateObject("WScript.Shell")
    message = WshShell.Popup ("Domain joining was successful!",, "Success!", 0 + 64)
End If

Err.Clear
    InformationsquelleAutor VoidnessMD
Schreibe einen Kommentar