Wie kann ich den Zugriff auf die ausgewählten Zeilen in Access?

Hier ist der code, es zu tun, aber es gibt einen Haken.

Private Sub Command1_Click()
     Dim i As Long
     Dim RS As Recordset
     Dim F As Form

     Set F = Me.sf.Form
     Set RS = F.RecordsetClone

     If F.SelHeight = 0 Then Exit Sub

     ' Move to the first selected record.
     RS.Move F.SelTop - 1

     For i = 1 To F.SelHeight
       MsgBox RS![myfield]
       RS.MoveNext
     Next i

End Sub

Hier ist der Haken:
Wenn der code Hinzugefügt, um eine Taste, sobald der Benutzer auf diese Schaltfläche klickt, wird die Auswahl verloren im Netz (selheight wird null sein). So müssen Sie erfassen diese Informationen, und speichern Sie es zu einem Modul Ebene-variable entweder mit einem timer oder sonstige Ereignisse, auf die form.

Hier ist ein Artikel, der beschreibt, wie die Arbeit rund um den catch-in einigen Details.

http://www.mvps.org/access/forms/frm0033.htm

Fang 2: Dies funktioniert nur mit zusammenhängenden Auswahl. Sie können nicht wählen Sie mehrere nicht aufeinander folgenden Zeilen im raster.

Update:

Gibt es vielleicht eine bessere Falle zu Falle, aber hier ist eine funktionierende Implementierung mithilfe des Formular.timerinterval-Eigenschaft, die ich getestet habe (zumindest in Access 2k3, aber 2k7 sollte gut funktionieren)

Dieser code wird in das UNTERFORMULAR, verwenden Sie die Eigenschaft, um die selheight-Wert in die master-form.

Public m_save_selheight As Integer

Public Property Get save_selheight() As Integer
    save_selheight = m_save_selheight
End Property

Private Sub Form_Open(Cancel As Integer)
    Me.TimerInterval = 500
End Sub

Private Sub Form_Timer()
    m_save_selheight = Me.selheight
End Sub

InformationsquelleAutor JohnFx

Habe ich versucht, etwas ähnliches vor, aber ich hatte nie Erfolg mit einer Methode erforderlich, dass die Benutzer mehrere Zeilen auswählen, im gleichen Stil wie ein Windows-Datei-Dialog (Strg, Shift, etc.).

Eine Methode, die ich verwendet habe, ist die Verwendung von zwei Listenfelder. Die Benutzer können doppelklicken Sie auf ein Element in dem linken Listenfeld aus, oder klicken Sie auf eine Schaltfläche, wenn ein Element ausgewählt ist, und es wird zu bewegen, um das Rechte Listenfeld.

Andere Möglichkeit ist die Verwendung einer lokalen Tabelle, der gefüllt ist mit deiner Quelle Daten sowie Boolesche Werte dargestellt, die als Checkboxen im Unterformular. Nachdem der Benutzer die Daten, die Sie wollen, indem Sie auf die Checkboxen der Benutzer eine Taste drückt (oder anderen Veranstaltungen), zu welcher Zeit Sie gehen direkt auf die zugrunde liegende Tabelle der Daten und der Abfrage nur die Zeilen, die geprüft wurden. Ich denke, diese option ist die beste, obwohl es erfordert ein wenig code, um richtig zu arbeiten.

Sogar in Access, ich finde manchmal ist es einfacher, zur Arbeit mit den Tabellen und Abfragen direkt, anstatt zu versuchen, verwenden Sie die integrierten tools in Access-Formulare. Manchmal ist die eingebaute tools nicht genau das tun, was Sie wollen.

InformationsquelleAutor Ben McCormack

Gibt es eine andere Lösung.

Den code unten zeigen die Anzahl der ausgewählten Zeilen zurückgegeben, sobald Sie die Maustaste loslassen.
Das speichern dieser Wert wird den trick tun.

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

        MsgBox Me.SelHeight

End Sub

InformationsquelleAutor user2777544

Warum nicht ein array oder recordset und dann jedes mal, wenn der Benutzer klickt auf eine Zeile (entweder zusammenhängend oder nicht, speichern Sie die Zeile oder eine id, die in das recordset. Dann, wenn Sie auf die Schaltfläche in der übergeordneten form, einfach Durchlaufen des Recordsets gespeichert wurde, zu tun, was Sie wollen. Nur vergessen Sie nicht, deaktivieren Sie das array oder recordset, nachdem auf die Schaltfläche geklickt wird.?

InformationsquelleAutor baldguy70

Den code von JohnFx gut funktioniert. Implementiert habe ich es ohne timer (MS-Access 2003):

1 - Legen Sie das Formular Taste Vorschau, um ja

2 - setzen Sie den code in eine Funktion

3 - legen Sie das Ereignis OnKeyUp und OnMouseUp, um die Funktion aufzurufen.

Option Compare Database
Option Explicit

Dim rowSelected() As String

Private Sub Form_Load()
'initialize array
ReDim rowSelected(0, 2)
End Sub

Private Sub Form_Current()
' if cursor place on a different record after a selection was made 
' the selection is no longer valid
If "" <> rowSelected(0, 2) Then
  If Me.Recordset.AbsolutePosition <> rowSelected(0, 2) Then
    rowSelected(0, 0) = ""
    rowSelected(0, 1) = ""
    rowSelected(0, 2) = ""
  End If
End If
End Sub

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
rowsSelected
If KeyCode = vbKeyDelete And Me.SelHeight > 0 Then
    removeRows
End If
End Sub

Private Sub Form_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
rowsSelected
End Sub

Sub rowsSelected()
Dim i As Long, rs As DAO.Recordset, selH As Long, selT As Long
selH = Me.SelHeight
selT = Me.SelTop - 1
If selH = 0 Then
    ReDim rowSelected(0, 2)
    Exit Sub
Else
    ReDim rowSelected(selH, 2)
    rowSelected(0, 0) = selT
    rowSelected(0, 1) = selH
    rowSelected(0, 2) = Me.Recordset.AbsolutePosition ' for repositioning 
    Set rs = Me.RecordsetClone
    rs.MoveFirst ' other key touched caused the pointer to shift
    rs.Move selT
    For i = 1 To selH
        rowSelected(i, 0) = rs!PositionNumber
        rowSelected(i, 1) = Nz(rs!CurrentMbr)
        rowSelected(i, 2) = Nz(rs!FutureMbr)
        rs.MoveNext
    Next
    Set rs = Nothing
    Debug.Print selH & " rows selected starting at " & selT 
End If
End Sub

Sub removeRows()
' remove rows in underlying table using collected criteria in rowSelected()
    Me.Requery
' reposition cursor
End Sub

Private Sub cmdRemRows_Click()
If Val(rowSelected(0, 1)) > 0 Then
    removeRows
Else
    MsgBox "To remove row(s) select one or more sequential records using the record selector on the left side."
End If
End Sub

InformationsquelleAutor Jean-Marc