Wie Kann ich ein Dynamisches Array zu einem FileStream in Delphi?

Habe ich die folgenden Strukturen in Delphi 2009:

type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
  end;

var
  XRefList: array of IndiReportIndi;

wo XRefList ist ein dynamisches array.

Ich will sparen XRefList zu einem FileStream. Wie mache ich das UND umfassen alle IndiName und ReportIndiName Saiten, so dass Sie für alle abrufbar sein wenn ich wieder später laden aus, dass die FileStream?

  • Seit Dezember 2010 gibt es ein neues OpenSource-Einheit eine überlegung Wert, für die Serialisierung Datensätze oder dynamische arrays (mit viel mehr Funktionen als Serialisierung) für Delphi 5-XE2.
InformationsquelleAutor lkessler | 2010-12-07
  1. 6

    Verwenden: http://code.google.com/p/kblib/

    type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
  end;

  TXRefList = array of IndiReportIndi;

var
  XRefList: TXRefList;

    Speichern ganze XRefList zum streamen verwenden:

    TKBDynamic.WriteTo(lStream, XRefList, TypeInfo(TXRefList));

    Laden zurück:

    TKBDynamic.ReadFrom(lStream, XRefList, TypeInfo(TXRefList));
    • Sieht aus wie eine wirklich nette routine. Danke für den Hinweis it out.
    InformationsquelleAutor Krystian Bigaj
  2. 10
    type
  IndiReportIndi = record
    IndiName: string;
    NameNum: integer;
    ReportIndiName: string;
    procedure SaveToStream(Stream: TStream);
    procedure LoadFromStream(Stream: TStream);
  end;

type
  TXRefList = array of IndiReportIndi;

function LoadString(Stream: TStream): string;
var
  N: Integer;

begin
  Result:= '';
  Stream.ReadBuffer(N, SizeOf(Integer));
  if N > 0 then begin
    SetLength(Result, N);
//    Stream.ReadBuffer(Result[1], N * SizeOf(Char));
// fast version - see comment by A.Bouchez
    Stream.ReadBuffer(Pointer(Result)^, N * SizeOf(Char));
  end;
end;

procedure SaveString(Stream: TStream; const S: string);
var
  N: Integer;

begin
  N:= Length(S);
  Stream.WriteBuffer(N, SizeOf(Integer));
  if N > 0 then
//    Stream.WriteBuffer(S[1], N * SizeOf(Char));
// fast version - see comment by A.Bouchez
    Stream.WriteBuffer(Pointer(S)^, N * SizeOf(Char));
end;

procedure IndiReportIndi.LoadFromStream(Stream: TStream);
var
  S: string;

begin
  IndiName:= LoadString(Stream);
  Stream.ReadBuffer(NameNum, SizeOf(Integer));
  ReportIndiName:= LoadString(Stream);
end;

procedure IndiReportIndi.SaveToStream(Stream: TStream);
begin
  SaveString(Stream, IndiName);
  Stream.WriteBuffer(NameNum, SizeOf(Integer));
  SaveString(Stream, ReportIndiName);
end;

function LoadXRefList(Stream: TStream): TXRefList;
var
  N: Integer;
  I: Integer;

begin
  Stream.ReadBuffer(N, SizeOf(Integer));
  if N <= 0 then Result:= nil
  else begin
    SetLength(Result, N);
    for I:= 0 to N - 1 do
      Result[I].LoadFromStream(Stream);
  end;
end;

procedure SaveXRefList(Stream: TStream; const List: TXRefList);
var
  N: Integer;
  I: Integer;

begin
  N:= Length(List);
  Stream.WriteBuffer(N, SizeOf(Integer));
  for I:= 0 to N - 1 do
    List[I].SaveToStream(Stream);
end;
    • Sie könnte verwendet Zeiger(Ergebnis)^ statt Ergebnis[1] in LoadString und pointer(S)^ statt S[1] in SaveString, denn es spart einen Aufruf UniqueString(). LoadString könnte auch ein bisschen schneller, wenn kodiert mit Ergebnis := " in allen Fällen, dann SetLength(Result,N), wenn N>0: also es wird keine Neuzuordnung des Speichers (mit einem langsamen bewegen), aber einen string abzuschließen, der dann die neue Zuweisung (welche schneller ist).
    • Verwenden Sie einen TReader/TWriter zu vereinfachen, schreiben der standard-Datentypen. Anstelle von Strom.WriteBuffer(N, SizeOf(Integer)); Sie würde einfach schreiben, Schreiben.WriteInger(N) und N := Reader.ReadInteger;. Sie haben auch Unterstützung für strings und Varianten, und der code ist viel besser lesbar. Sie nur doppelter code Delphi bereits hat.
    • TReader/TWriter Umsetzung hängt von der Delphi-version und können sich ändern. Es ist unerwünscht, auf die Sie sich verlassen TReader/TWriter-Methoden zu implementieren, Ihre eigenen Daten-Serialisierung.
    • Die OP-Datensatz-Struktur wird sich ändern, wenn gut - und deinen code auch abhängig von der version von Delphi. Wenn die Datei verwendet werden soll über kompilierte Anwendung mit einer anderen version von Delphi, ein header mit der version Informationen sollten Hinzugefügt werden, damit die lese-Anwendung für die Verwendung der korrekten lese-Funktionen.
    InformationsquelleAutor kludg
  3. 5
    var
  S: TStream;
  W: TWriter;
  A: array of IndiReportIndi;
  E: IndiReportIndi;
  ...
begin
  S := nil;
  W := nil;
  try 
    S := TFileStream.Create(...);
    W := TWriter.Create(S);
    W.WriteInteger(Length(A));
    for E in A do
    begin
      W.WriteString(E.IndiName);
      W.WriteInteger(E.NameNum);
      W.WriteString(E.ReportIndiName);
    end;
  finally
    W.Free;
    S.Free
  end;
end;

    Zu Lesen, diese Daten, die Sie verwenden einem TReader und ReadInteger/ReadString.

    • Dank ldsandon. Schön und sauber und einfach. +1.
    InformationsquelleAutor
  4. 1

    Einfach TFileStreamEx zu speichern Variablen

    http://forum.chertenok.ru/viewtopic.php?t=4642

    Arbeit mit Ihnen aus 2005th Jahr, ohne irgendwelche Probleme...

    • Wusste nicht, über die EX-Funktion. Ich werde das prüfen.
    InformationsquelleAutor TuXAPuK
  5. 0

    Nur für die Antwort genau zu sein:

    Erwägen Sie einen Blick auf die TDynArray wrapper, die in der Lage ist zu serialisieren, jeder Datensatz in binärer, und auch zu/von dynamischen arrays.

    Gibt es eine Menge von TList-wie Methoden, einschließlich neuer Methoden (wie hashing oder binäre Suche).

    Sehr auf Geschwindigkeit optimiert und die Verwendung der Festplatte, funktioniert für Delphi 5-XE2 - und Open-Source.

    Siehe auch Wie zum speichern von dynamischen arrays in eine TList?

    InformationsquelleAutor Arnaud Bouchez
  6. 0

    Getestet Lösung:

    procedure TForm1.FormCreate(Sender: TObject);
VAR Stream: TFileStream;
    R: IndyRecordIndy;
begin
 Stream:= TFileStream.Create;
 TRY
   //put rec in stream
   Stream.WriteBuffer(R, SizeOf(R));

   //restore record from stram
   Stream.Position := 0;
   Stream.ReadBuffer(R, Stream.Size);
 FINALLY
  FreeAndNil(Stream);
 END;
end



;
    • Dies ist falsch! Speichern Sie die Zeiger auf die strings in der Datei. Das ist das nutzlose Daten, die das nächste mal, wenn Sie die Datei Lesen.
    InformationsquelleAutor WeGoToMars
Schreibe einen Kommentar