Wie kann ich Lesen Sie die 64-bit-Registrierungsschlüssel von einem 32-bit-Prozess?

Dein code ist unnötig Komplex, vor allem, weil Sie sind nicht unter Ausnutzung der eingebauten TRegistry Klasse, die Schilde, die Sie von der Komplexität der low-level-registry-API. Betrachten Sie beispielsweise den folgenden code:

type
  TRegistryView = (rvDefault, rvRegistry64, rvRegistry32);

function RegistryViewAccessFlag(View: TRegistryView): LongWord;
begin
  case View of
  rvDefault:
    Result := 0;
  rvRegistry64:
    Result := KEY_WOW64_64KEY;
  rvRegistry32:
    Result := KEY_WOW64_32KEY;
  end;
end;

function ReadRegStr(const Root: HKEY; const Key, Name: string;
  const View: TRegistryView=rvDefault): string;
var
  Registry: TRegistry;
begin
  Registry := TRegistry.Create(KEY_READ or RegistryViewAccessFlag(View));
  try
    Registry.RootKey := Root;
    if not Registry.OpenKey(Key) then
      raise ERegistryException.CreateFmt('Key not found: %s', [Key]);
    if not Registry.ValueExists(Name) then
      raise ERegistryException.CreateFmt('Name not found: %s\%s', [Key, Name]);
    Result := Registry.ReadString(Name);//will raise exception in case of failure
  finally
    Registry.Free;
  end;
end;

Die Funktion ReadRegStr wird den string-Wert mit dem Namen Name aus dem Schlüssel Key relativ zum root-key Root. Wenn ein Fehler Auftritt, beispielsweise wenn der Schlüssel oder name nicht vorhanden ist, oder wenn der Wert vom falschen Typ, dann wird eine Ausnahme ausgelöst.

Den View parameter ist eine enumeration, die macht es einfach für Sie, um Zugriff auf native 32-bit-oder 64-bit-Aussicht auf die registry. Beachten Sie, dass die Muttersprache heißt Muttersprache, um den Prozess, der ausgeführt wird. So wird es die 32-bit-Ansicht für 32-bit-Prozess-und 64-bit-Ansicht für ein 64-bit-Prozess. Diese Aufzählung spiegelt die äquivalente definition in .net.

In meiner Verwendung dieses Registrierungsschlüssels ich ging einen Schritt weiter. Wenn der Wert nicht existieren, ich Sie erstellt habe: nicht in HKEY_LOCAL_MACHINE, würde eine Erhöhung erforderlich, aber in HKEY_CURRENT_USER. Wer sehen den eingeführten Schlüssel es ist unwahrscheinlich, um zu realisieren, dass es ein dummy.

function GetComputerGUID: String;
var
  Reg: TRegistry;
  oGuid: TGUID;
  sGuid: String;
begin
  Result := '';
  // Attempt to retrieve the real key
  Reg := TRegistry.Create(KEY_READ OR KEY_WOW64_64KEY);
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKeyReadOnly('SOFTWARE\Microsoft\Cryptography') and Reg.ValueExists('MachineGuid') then
      Result := Reg.ReadString('MachineGuid');
    Reg.CloseKey;
  finally
    Reg.Free;
  end;
  // If retrieval fails, look for the surrogate
  if Result = '' then begin
    Reg := TRegistry.Create;
    try
      Reg.RootKey := HKEY_CURRENT_USER;
      if Reg.OpenKey('SOFTWARE\Microsoft\Cryptography', True) then begin
        if Reg.ValueExists('MachineGuid') then
          Result := Reg.ReadString('MachineGuid')
        else begin
          // If the surrogate doesn't exist, create it
          if CreateGUID(oGUID) = 0 then begin
            sGuid := Lowercase(GUIDToString(oGUID));
            Reg.WriteString('MachineGuid', Copy(sGuid, 2, Length(sGUID) - 2));
            Result := Reg.ReadString('MachineGuid');
          end;
        end;
      end;
      Reg.CloseKey;
    finally
      Reg.Free;
    end;
  end;
  if Result = '' then
    raise Exception.Create('Unable to access registry value in GetComputerGUID');
end;

Das ist ein guter Punkt von @Remy Lebeau - TeamB obwohl, ich sollte mod den obigen code entsprechend.