Wie können Sie konvertieren von HEX in BIN, ein Zeichen in einer Zeit, in EXCEL 2010

Ich versuche einen Weg zu finden, um einen string von HEX-Werte zu konvertieren und Sie zu BIN. Ich brauche zum konvertieren 1 HEX-Zeichen in einer Zeit:

Beispiel: HEX = 0CEC
BIN = 0000 1100 1110 1100

Ich brauche, um dies zu tun in Excel. Jede Hilfe wäre toll.

Dank,
Larry

InformationsquelleAutor Larry | 2012-03-16
  1. 8

    In einem Modul

    Public Function HEX2BIN(strHex As String) As String
    Dim c As Long, i As Long, b As String * 4, j As Long
    For c = 1 To Len(strHex)
        b = "0000"
        j = 0
        i = Val("&H" & Mid$(strHex, c, 1))
        While i > 0
            Mid$(b, 4 - j, 1) = i Mod 2
            i = i \ 2
            j = j + 1
        Wend
        HEX2BIN = HEX2BIN & b & " "
    Next
    HEX2BIN = RTrim$(HEX2BIN)
End Function

    Für 

    =HEX2BIN("0CEC")
   0000 1100 1110 1100
    • Danke.. auch ich war falsch, HEX2BIN arbeiten kann, anscheinend. Vielen Dank für die Hilfe
    • Eigentlich ist die VBA-Funktion hat wunderbar funktioniert, vielen Dank Alex
    InformationsquelleAutor Alex K.
  2. 2

    Ja, ich hatte dies vor kurzem. Ich bin spät, um das Spiel, sondern anderen Menschen zu tun haben, diese von Zeit zu Zeit, also lasse ich den code, wo jeder es finden kann:

    Option Explicit

Public Function HexToBinary(strHex As String, Optional PadLeftZeroes As Long = 5, Optional Prefix As String = "oX") As String
Application.Volatile False

' Convert a hexadecimal string into a binary
' As this is for Excel, the binary is returned as string: there's a risk that it will be treated as a number and reformatted

' Code by Nigel Heffernan, June 2013. Http://Excellerando.Blogspot.co.uk  THIS CODE IS IN THE PUBLIC DOMAIN

' Sample Usage:
'
'   =HexToBinary("8E")
'   oX0010001110
'
'   =HexToBinary("7")
'   oX001111
'
'   =HexToBinary("&HD")
'   oX01101


Dim lngHex As Long
Dim lngExp As Long
Dim lngPad As Long
Dim strOut As String
Dim strRev As String


If Left(strHex, 2) = "&H" Then
    lngHex = CLng(strHex)
Else
    lngHex = CLng("&H" & strHex)
End If

lngExp = 1
Do Until lngExp > lngHex
    ' loop, bitwise comparisons with successive powers of 2
    ' Where bitwise comparison is true, append "1", otherwise append 0
    strRev = strRev & CStr(CBool(lngHex And lngExp) * -1)
lngExp = lngExp * 2
Loop


' As we've done this in ascending powers of 2, the results are in reverse order:
If strRev = "" Then
    HexToBinary = "0"
Else
    HexToBinary = VBA.Strings.StrReverse(strRev)
End If

' The result is padded by leading zeroes: this is the expected formatting when displaying binary data
If PadLeftZeroes > 0 Then
    lngPad = PadLeftZeroes * ((Len(HexToBinary) \ PadLeftZeroes) + 1)
    HexToBinary = Right(String(lngPad, "0") & HexToBinary, lngPad)
End If

HexToBinary = Prefix & HexToBinary

End Function
    InformationsquelleAutor Nigel Heffernan
  3. 1

    Können Sie HEX2BIN(Anzahl, [Orte]).

    Den HEX2BIN Funktion syntax hat die folgenden Argumente:

    • Anzahl Erforderlich. Der hexadezimale Zahl, die Sie konvertieren möchten. Das argument Zahl darf aus höchstens 10 Zeichen. Die am meisten signifikante bit von Zahl ist das Vorzeichen-bit (40-bit von rechts). Die übrigen 9 bits Größe bit. Negative zahlen vertreten sind, mit zwei-Komplement-notation.
    • Orte Optional. Die Anzahl der Zeichen zu verwenden. Wenn stellen weggelassen wird, HEX2BIN verwendet die minimale Anzahl von Zeichen erforderlich. Orte ist nützlich für die Polsterung der Rückgabewert mit führenden 0EN (Nullen) aufgefüllt werden.
    • BTW: "installieren und laden das Analyse-Funktionen-add-in"
    • HEX2BIN wird nicht für diese Arbeit. Der HEX-Wert ist zu lang für EXCEL ausgeführt durch HEX2BIN
    • warum?
    • sorry, das war für ältere Excel-version 🙂
    InformationsquelleAutor KevinDTimm
  4. 0

    Ich würde eine einfache Formel wie folgt:

    =HEX2BIN(MID(S23,1,2))&HEX2BIN(MID(S23,3,2))&HEX2BIN(MID(S23,5,2))&HEX2BIN(MID(S23,7,2)&HEX2BIN(MID(S23,9,2)&HEX2BIN(MID(S23,11,2)&HEX2BIN(MID(S23,13,2))

    Zelle S23 = BFBEB991, Ergebnis = 10111111101111101011100110010001

    Dieser es ihm erlauben würde, so zu sein wie lange Sie brauchen. Fügen Sie einfach so viele Wiederholungen, wie Sie benötigen, Erhöhung der start-position von 2 (zB 1, 3, 5, 7, 9, 11, 13, 15, ....). Beachten Sie, dass die fehlenden Zeichen werden ignoriert.

    InformationsquelleAutor SteveAt
  5. 0

    Für mich, es gibt diese (sorry, in VBA, hat aber den Vorteil, dass Sie nicht Fragen, Sie die Länge der Zeichenfolge zu konvertieren). Vorsichtig legte ich einen Kommentar im unteren Teil, für die können Sie fügen Sie ein Leerzeichen zwischen jedem Abschnitt von 4 bits. Einige wollen nicht den Platz und einige werden es brauchen:

    Length = Len(string_to_analyse)
For i = 1 To Length
    Value_test_hexa = Left(Right(string_to_analyse, Length - (i - 1)), 1)
'get the asci value of each hexa character (actually can work as a decimal to binary as well)
    Value_test = Asc(Value_test_hexa)

    If Value_test > 47 And Value_test < 58 Then
        Value_test = Value_test - 48
    End If

' Convert A to F letters to numbers from 10 to 15
    If Value_test > 64 And Value_test < 71 Then
        Value_test = Value_test - 55
    End If

'identify the values of the 4 bits for each character (need to round down)
    a = WorksheetFunction.RoundDown(Value_test /8, 0)
    b = WorksheetFunction.RoundDown((Value_test - a * 8) /4, 0)
    c = WorksheetFunction.RoundDown((Value_test - a * 8 - b * 4) /2, 0)
    d = (Value_test - a * 8 - b * 4 - c * 2)

    Value_converted = Value_converted & a & b & c & d ' can eventually add & " " in order to put a space every 4 bits
Next i

    Getestet OK, so dass Sie gehen können mit ihm.

    InformationsquelleAutor GPER
Schreibe einen Kommentar