Wie machst du eine Verschachtelte if-else-Anweisung im Prolog?

Wenn ich diese Funktion haben:

min(List1, List2, Output) :-
   length(List1, N),
   length(List2, M),
   (   N < M ->
       Output = 'true'
   ;   Output = 'false'
   ).

aber was ist, wenn ich wollte auch überprüfen, ob N == M? Vielleicht so:

min(List1, List2, Output) :-
   length(List1, N),
   length(List2, M),
   (   N < M ->
       Output = 'true'
   ;   (  N = M ->
          Output = 'equal'
       ;  Output = 'other'
       )
   ).

Scheint nicht zu funktionieren.

  • Was genau scheint nicht zu funktionieren? Sie bekommen Antworten, die Sie nicht erwarten, oder hat es nicht kompilieren?
InformationsquelleAutor Bramble | 2010-11-16
  1. 4

    Ihre Verschachtelung der Implikation (->) sieht richtig hier. Beachten Sie, dass in Ihrer definition N und M werden ganze zahlen (vorausgesetzt, die Aufrufe length/2 beide erfolgreich), so kann verglichen werden mit == statt der Vereinigung (=). In der Tat, man könnte sogar arithmetische gleich in SWI-PROLOG, nämlich =:=:

    min(List1, List2, Output) :-
    length(List1, N),
    length(List2, M),
    (N < M ->
        Output = 'true'
    ;   (N =:= M ->
            Output = 'equal'
        ;   Output = 'other'
        )
    ).

    Testen:

    1 ?- min([a],[b],O).
O = equal.

2 ?- min([a,c],[b],O).
O = other.

3 ?- min([a,c],[b,d],O).
O = equal.

4 ?- min([a,c],[b,d,e],O).
O = true.
    • (=:=)/2 ist ein ISO-Prädikat.
    InformationsquelleAutor sharky
  2. 5

    In verschachtelten if-then-else, es ist üblich, weglassen redundanter Klammern, nachgeben:

    min(List1, List2, Output) :-
    length(List1, N),
    length(List2, M),
    (   N < M -> Output = true
    ;   N =:= M -> Output = equal
    ;   Output = other
    ).

    In Prolog ist es gute Praxis zu verwenden pattern-matching, wenn möglich, denn dies führt zu mehr Allgemeinen, deklarativer und lesbarere Programme als mit if-then-else. Für diesen speziellen Fall von Bedingungen, überprüfen Sie heraus die compare/3 Bibliothek Prädikat. compare/3 können Sie verdinglichen das Verhältnis der beiden Längen in einem atom, und Sie können das atom zu beschreiben, die drei Bedingungen mit pattern-matching:

    lists_output(List1, List2, Output) :-
        length(List1, L1),
        length(List2, L2),
        compare(Order, L1, L2),
        order_output(Order, Output).

order_output(<, true).
order_output(=, equal).
order_output(>, other).

    Probe Abfragen und Ergebnisse:

    ?- lists_output([_,_], [_,_,_], Output).
Output = true.

?- lists_output([_,_,_], [_,_,_], Output).
Output = equal.

?- lists_output([_,_,_,_], [_,_,_], Output).
Output = other.
    • Ganz nett, ich mag diesen Stil, es ist ordentlicher. Ich Frage mich, ob die Rangfolge der Regeln für ->, ; usw. üblich sind unter anderen PROLOG-Implementierungen, so dass diese nicht SWI-PROLOG-spezifisch ist (wahrscheinlich der Fall)?
    • Ich habe noch kein ISO-standard bereit, aber ich habe gesehen, diesen Stil vor und @mat ' s code funktioniert einwandfrei in SICStus 3.12.
    • Das Beispiel verwendet nur ISO-definierten Operatoren. Siehe iso-prolog, wie Sie den standard für 30 USD!
    InformationsquelleAutor mat
Schreibe einen Kommentar