Wie machst du Identitätswechsel .NET?

"Identitätswechsel".NETTO Platz bedeutet in der Regel das ausführen von code unter einer bestimmten Benutzer-account. Es ist ein etwas separates Konzept als erste Zugriff auf das Benutzerkonto mit einem Benutzernamen und Passwort, obwohl diese beiden Ideen-pair-Mädchen, zusammen Häufig. Ich werde beschreiben, wie Sie beide, und dann erklären, wie mein SimpleImpersonation - Bibliothek, die verwendet Sie intern.

Identitätswechsel

Den APIs für den Identitätswechsel sind in .NET über die System.Security.Principal namespace:

• Neueren code (.NETTO-4.6+, .NET Core, etc.) sollte in der Regel verwenden WindowsIdentity.RunImpersonated, die akzeptiert, dass ein handle auf das Symbol des Benutzerkontos, und klicken Sie dann entweder eine Action oder Func<T> für den code auszuführen.

  WindowsIdentity.RunImpersonated(tokenHandle, () =>
  {
      //do whatever you want as this user.
  });

  oder

  var result = WindowsIdentity.RunImpersonated(tokenHandle, () =>
  {
      //do whatever you want as this user.
      return result;
  });

• Älteren code verwendet die WindowsIdentity.Impersonate Methode zum abrufen einer WindowsImpersonationContext Objekt. Dieses Objekt implementiert IDisposable, allgemein so genannt werden sollte, von einem using block.

  using (WindowsImpersonationContext context = WindowsIdentity.Impersonate(tokenHandle))
  {
      //do whatever you want as this user.
  }

  Während dieser API immer noch existiert .NET Framework, es sollte im Allgemeinen vermieden werden, und ist nicht verfügbar .NET-Core-oder .NET Standard.

Zugriff auf das Benutzerkonto

Die API für die Nutzung einen Benutzernamen und ein Passwort, um Zugriff auf einen Benutzer-account in Windows ist LogonUser - was ist eine native Win32-API. Es gibt zurzeit keine built-in .NET-API für den Aufruf, so muss man in dem resort, P/Invoke.

[DllImport("advapi32.dll", SetLastError = true, CharSet = CharSet.Unicode)]
internal static extern bool LogonUser(String lpszUsername, String lpszDomain, String lpszPassword, int dwLogonType, int dwLogonProvider, out IntPtr phToken);

Dies ist der basic-call-definition, aber es gibt viel mehr zu berücksichtigen, um tatsächlich nutzen es in der Produktion:

• Abrufen eines handles mit den "sicheren" Zugriff Muster.
• Schließen des native Griffe entsprechend
• Code access security (CAS) Vertrauen (in .NET Framework nur)
• Vorbei SecureString wenn Sie sammeln können, die einen sicher über Tastatureingaben.

Die Menge an code zu schreiben, um zu veranschaulichen, all das jenseits dessen ist, was sollte in einer StackOverflow-Antwort, IMHO.

Eine Kombinierte und Einfacher Ansatz

Statt schreiben alle das Sie sich, betrachten Sie mit meinem SimpleImpersonation Bibliothek, die kombiniert Sie die Identitätswechsel-und Benutzer Zugang zu einer einzigen API. Es funktioniert gut, sowohl moderne und ältere Codebasis, mit der gleichen einfachen API:

var credentials = new UserCredentials(domain, username, password);
Impersonation.RunAsUser(credentials, logonType, () =>
{
    //do whatever you want as this user.
}); 

oder

var credentials = new UserCredentials(domain, username, password);
var result = Impersonation.RunAsUser(credentials, logonType, () =>
{
    //do whatever you want as this user.
    return something;
});

Beachten Sie, dass es ist sehr ähnlich zu der WindowsIdentity.RunImpersonated API, ist aber nicht erforderlich, dass Sie wissen nichts über token verarbeitet.

Dies ist die API in der version 3.0.0. Siehe die Projekt-readme für mehr details. Beachten Sie auch, dass eine frühere version der Bibliothek verwendet eine API, mit der IDisposable Muster, ähnlich WindowsIdentity.Impersonate. Die neuere version ist viel sicherer, und beide sind immer noch intern verwendet.

InformationsquelleAutor Matt Johnson

Hier ist meine vb.net Hafen von Matt Johnson ' s Antwort. Ich fügte hinzu, ein enum für die Typen Anmeldung. LOGON32_LOGON_INTERACTIVE war der erste enum-Wert, der arbeitete für sql server. Mein connection string war einfach vertraut. Kein Benutzername /Kennwort in der Verbindungszeichenfolge.

  <PermissionSet(SecurityAction.Demand, Name:="FullTrust")> _
  Public Class Impersonation
    Implements IDisposable

    Public Enum LogonTypes
      ''' <summary>
      ''' This logon type is intended for users who will be interactively using the computer, such as a user being logged on  
      ''' by a terminal server, remote shell, or similar process.
      ''' This logon type has the additional expense of caching logon information for disconnected operations; 
      ''' therefore, it is inappropriate for some client/server applications,
      ''' such as a mail server.
      ''' </summary>
      LOGON32_LOGON_INTERACTIVE = 2

      ''' <summary>
      ''' This logon type is intended for high performance servers to authenticate plaintext passwords.
      ''' The LogonUser function does not cache credentials for this logon type.
      ''' </summary>
      LOGON32_LOGON_NETWORK = 3

      ''' <summary>
      ''' This logon type is intended for batch servers, where processes may be executing on behalf of a user without 
      ''' their direct intervention. This type is also for higher performance servers that process many plaintext
      ''' authentication attempts at a time, such as mail or Web servers. 
      ''' The LogonUser function does not cache credentials for this logon type.
      ''' </summary>
      LOGON32_LOGON_BATCH = 4

      ''' <summary>
      ''' Indicates a service-type logon. The account provided must have the service privilege enabled. 
      ''' </summary>
      LOGON32_LOGON_SERVICE = 5

      ''' <summary>
      ''' This logon type is for GINA DLLs that log on users who will be interactively using the computer. 
      ''' This logon type can generate a unique audit record that shows when the workstation was unlocked. 
      ''' </summary>
      LOGON32_LOGON_UNLOCK = 7

      ''' <summary>
      ''' This logon type preserves the name and password in the authentication package, which allows the server to make 
      ''' connections to other network servers while impersonating the client. A server can accept plaintext credentials 
      ''' from a client, call LogonUser, verify that the user can access the system across the network, and still 
      ''' communicate with other servers.
      ''' NOTE: Windows NT:  This value is not supported. 
      ''' </summary>
      LOGON32_LOGON_NETWORK_CLEARTEXT = 8

      ''' <summary>
      ''' This logon type allows the caller to clone its current token and specify new credentials for outbound connections.
      ''' The new logon session has the same local identifier but uses different credentials for other network connections. 
      ''' NOTE: This logon type is supported only by the LOGON32_PROVIDER_WINNT50 logon provider.
      ''' NOTE: Windows NT:  This value is not supported. 
      ''' </summary>
      LOGON32_LOGON_NEW_CREDENTIALS = 9
    End Enum

    <DllImport("advapi32.dll", SetLastError:=True, CharSet:=CharSet.Unicode)> _
    Private Shared Function LogonUser(lpszUsername As [String], lpszDomain As [String], lpszPassword As [String], dwLogonType As Integer, dwLogonProvider As Integer, ByRef phToken As SafeTokenHandle) As Boolean
    End Function

    Public Sub New(Domain As String, UserName As String, Password As String, Optional LogonType As LogonTypes = LogonTypes.LOGON32_LOGON_INTERACTIVE)
      Dim ok = LogonUser(UserName, Domain, Password, LogonType, 0, _SafeTokenHandle)
      If Not ok Then
        Dim errorCode = Marshal.GetLastWin32Error()
        Throw New ApplicationException(String.Format("Could not impersonate the elevated user.  LogonUser returned error code {0}.", errorCode))
      End If

      WindowsImpersonationContext = WindowsIdentity.Impersonate(_SafeTokenHandle.DangerousGetHandle())
    End Sub

    Private ReadOnly _SafeTokenHandle As New SafeTokenHandle
    Private ReadOnly WindowsImpersonationContext As WindowsImpersonationContext

    Public Sub Dispose() Implements System.IDisposable.Dispose
      Me.WindowsImpersonationContext.Dispose()
      Me._SafeTokenHandle.Dispose()
    End Sub

    Public NotInheritable Class SafeTokenHandle
      Inherits SafeHandleZeroOrMinusOneIsInvalid

      <DllImport("kernel32.dll")> _
      <ReliabilityContract(Consistency.WillNotCorruptState, Cer.Success)> _
      <SuppressUnmanagedCodeSecurity()> _
      Private Shared Function CloseHandle(handle As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
      End Function

      Public Sub New()
        MyBase.New(True)
      End Sub

      Protected Overrides Function ReleaseHandle() As Boolean
        Return CloseHandle(handle)
      End Function
    End Class

  End Class

Müssen Sie mit einem Using - Anweisung enthalten einige code ausführen imitiert.

InformationsquelleAutor toddmo

Ich bin mir bewusst, dass ich schon spät für die party, aber ich denke, dass die Bibliothek von Phillip Allan-Harding, es ist das beste für diesen Fall und ähnliche.

Brauchen Sie nur ein kleines Stück code wie diesen:

private const string LOGIN = "mamy";
private const string DOMAIN = "mongo";
private const string PASSWORD = "HelloMongo2017";

private void DBConnection()
{
    using (Impersonator user = new Impersonator(LOGIN, DOMAIN, PASSWORD, LogonType.LOGON32_LOGON_NEW_CREDENTIALS, LogonProvider.LOGON32_PROVIDER_WINNT50))
    {
    }
}

Hinzufügen und seine Klasse:

.NET (C#) Identitätswechsel mit Netzwerk-Anmeldeinformationen

Meinem Beispiel kann verwendet werden, wenn Sie die imitierten Anmeldung an Netzwerk-Anmeldeinformationen, aber es hat mehr Optionen.

InformationsquelleAutor Federico Navarrete