Wie man CR/LF in einem TStringgrid Zelle?

Ich will eine Feste Zeile als header, aber die Texte sind ziemlich lang, also würde ich gerne erhöhen Sie die Zeilenhöhe und einfügen von CR/LF in der Zelle text.

Googeln zeigt dies als eine Lösung (und es ist das erste, was ich dachte, fo, bevor googeln), aber es unten nicht sehen, um zu arbeiten. Irgendwelche Ideen?

Grid.Cells[2,3] := 'This is a sample test' + #13#10 + 'This is the second line';

Was passiert, ist, dass die Zelle enthält This is a sample testThis is the second line

(Delphi 7, wenn es einen Unterschied macht)

[Kopfgeld] "Mein bad. Ich habe tatsächlich erhielt dieser die Antwort vor zwei Jahren ohne Prüfung und jetzt feststellen, dass die Antwort nicht funktioniert. Aplogies jedermann in die Irre geführt wurde. Dies ist ein FABOWAQ (Häufig gestellte, Häufig falsch beantworteten Frage). GINYF".

Ich davon aus, dass wir suchen, um zu verwenden OnDrawCell, aber Stell dir vor, wir müssten auch die Steigerung der Höhe der string-grid-Zeile, die enthält die Zelle.

Ich vergibt die Antwort entweder code oder eine FOSS-VCL-Komponente.

[Update] muss die Arbeit mit Delphi XE2 Starter edition

RowHeights[#] von TStringGrid würde nicht helfen? edit: AFAICS in den verlinkten code in die Antwort, RowHeights wird verwendet, um das Ausmaß.

InformationsquelleAutor Mawg | 2010-12-11

delphi delphi-xe2

TStringGrid verwendet Canvas.TextRect verwendet ExtTextOut, die wiederum nicht unterstützt Zeichnung von mehrzeiligen text.

Haben Sie zu ziehen, sich in einem OnDrawCell event-handler mit WinAPI ist DrawText routine. Siehe zum Beispiel diese Antwort, wie DrawText für mehrzeiligen text, und diese neue Antwort, wie zu implementieren benutzerdefinierte Zeichnung in OnDrawCell:

type
  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
      Rect: TRect; State: TGridDrawState);
  private
    procedure FillWithRandomText(AGrid: TStringGrid);
    procedure UpdateRowHeights(AGrid: TStringGrid);
  end;

procedure TForm1.FillWithRandomText(AGrid: TStringGrid);
const
  S = 'This is a sample'#13#10'text that contains'#13#10'multiple lines.';
var
  X: Integer;
  Y: Integer;
begin
  for X := AGrid.FixedCols to AGrid.ColCount - 1 do
    for Y := AGrid.FixedRows to AGrid.RowCount - 1 do
      AGrid.Cells[X, Y] := Copy(S, 1, 8 + Random(Length(S) - 8));
  UpdateRowHeights(AGrid);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FillWithRandomText(StringGrid1);
end;

procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
begin
  with TStringGrid(Sender) do
    if Pos(#13#10, Cells[ACol, ARow]) > 0 then
    begin
      Canvas.FillRect(Rect);
      Inc(Rect.Left, 2);
      Inc(Rect.Top, 2);
      DrawText(Canvas.Handle, PChar(Cells[ACol, ARow]), -1, Rect,
        DT_NOPREFIX or DT_WORDBREAK);
    end;
end;

procedure TForm1.UpdateRowHeights(AGrid: TStringGrid);
var
  Y: Integer;
  MaxHeight: Integer;
  X: Integer;
  R: TRect;
  TxtHeight: Integer;
begin
  for Y := AGrid.FixedRows to AGrid.RowCount - 1 do
  begin
    MaxHeight := AGrid.DefaultRowHeight - 4;
    for X := AGrid.FixedCols to AGrid.ColCount - 1 do
    begin
      R := Rect(0, 0, AGrid.ColWidths[X] - 4, 0);
      TxtHeight := DrawText(AGrid.Canvas.Handle, PChar(AGrid.Cells[X, Y]), -1,
        R, DT_WORDBREAK or DT_CALCRECT);
      if TxtHeight > MaxHeight then
        MaxHeight := TxtHeight;
    end;
    AGrid.RowHeights[Y] := MaxHeight + 4;
  end;
end;

Wie man CR/LF in einem TStringgrid Zelle?

Gibt es auch andere StringGrid Komponenten können in der Zeichnung mit mehrzeiligem text. Zum Beispiel, diese eine, die ich selbst geschrieben habe (download-Quellen: NLDStringGrid + NLDSparseList), eventuell mit diesem Ergebnis:

Wie man CR/LF in einem TStringgrid Zelle?

var
  R: TRect;
begin
  NLDStringGrid1.Columns.Add;
  NLDStringGrid1.Columns.Add;
  NLDStringGrid1.Cells[1, 1] := 'Sample test'#13#10'Second line';
  NLDStringGrid1.Columns[1].MultiLine := True;
  NLDStringGrid1.AutoRowHeights := True;
  SetRect(R, 2, 2, 3, 3);
  NLDStringGrid1.MergeCells(TGridRect(R), True, True);
  NLDStringGrid1.ColWidths[2] := 40;
  NLDStringGrid1.Cells[2, 2] := 'Sample test'#13#10'Second line';
end;

+1 @NGLN ich D/L, und versuchen Sie es jetzt. Irgendwelche Einschränkungen bei der Nutzung?
Kompilieren fehlschlägt - nicht finden können, DesignEditors.dcu - wahrscheinlich, weil ich bin mit XE2 Starter edition ?
Möglicherweise, aber das weiß ich nicht. Hast du konvertieren Sie die Paket-Datei zu XE2? Hinweis: die requires DesignIde Linie! Versuchen Sie Laufzeit sonst.
Der code oben (nicht dein Paket), funktioniert Prima - außer ... wenn alle Einträge in einer Zeile sind leer, die Reihe zeigt, wie ein pixel hoch. Kann es sein, die Standard Zeile Höhe? Versuchen Sie, diese - in FillWithRandomText() fallen die loops und zuordnen einer einzelnen Zelle (sagen Cells[3,3]). Ich denke, du bekommst das Kopfgeld auf diesen einen, aber es wäre schön, wenn Sie könnte zwicken, leere Zeile Sache.
Ich änderte UpdateRowHeights() aus MaxHeight := 0; zu MaxHeight := AGrid.DefaultRowHeight; und leere Zeilen jetzt Aussehen vernünftig.

InformationsquelleAutor NGLN

Den TStringGrid ist ein Standard-renderer keine Unterstützung für mehrere Linien. Durch die Einstellung des TStringGrid im OwnerDraw-Modus (aufrufen von OnDrawCell-Ereignis) wiedergegeben werden können, wird jede Zelle von Ihrem eigenen Geschmack.

Haben Sie einen Blick auf diese ein Beispiel, das half einem vorherigen Benutzer.

Verlinkte Referenz code eingefügt:

procedure DrawSGCell(Sender : TObject; C, R : integer; Rect : TRect;
          Style : TFontStyles; Wrap : boolean; Just : TAlignment;
          CanEdit : boolean);
  { draws formatted contents in string grid cell at col C, row R;
    Style is a set of fsBold, fsItalic, fsUnderline and fsStrikeOut;
    Wrap invokes word wrap for the cell's text; Just is taLeftJustify,
    taRightJustify or taCenter; if CanEdit false, cell will be given 
    the background color of fixed cells; call this routine from 
    grid's DrawCell event }
var
  S        : string;
  DrawRect : TRect;
begin
  with (Sender as tStringGrid), Canvas do begin
    { erase earlier contents from default drawing }
    if (R >= FixedRows) and (C >= FixedCols) and CanEdit then
      Brush.Color:= Color
    else
      Brush.Color:= FixedColor;
    FillRect(Rect);
    { get cell contents }
    S:= Cells[C, R];
    if length(S) > 0 then begin
      case Just of
        taLeftJustify  : S:= ' ' + S;
        taRightJustify : S:= S + ' ';
        end;
      { set font style }
      Font.Style:= Style;
      { copy of cell rectangle for text sizing }
      DrawRect:= Rect;
      if Wrap then begin
        { get size of text rectangle in DrawRect, with word wrap }
        DrawText(Handle, PChar(S), length(S), DrawRect,
          dt_calcrect or dt_wordbreak or dt_center);
        if (DrawRect.Bottom - DrawRect.Top) > RowHeights[R] then begin
          { cell word-wraps; increase row height }
          RowHeights[R]:= DrawRect.Bottom - DrawRect.Top;
          SetGridHeight(Sender as tStringGrid);
          end
        else begin
          { cell doesn't word-wrap }
          DrawRect.Right:= Rect.Right;
          FillRect(DrawRect);
          case Just of
            taLeftJustify  : DrawText(Handle, PChar(S), length(S), DrawRect,
                               dt_wordbreak or dt_left);
            taCenter       : DrawText(Handle, PChar(S), length(S), DrawRect,
                               dt_wordbreak or dt_center);
            taRightJustify : DrawText(Handle, PChar(S), length(S), DrawRect,
                               dt_wordbreak or dt_right);
            end;
          end
        end
      else
        { no word wrap }
        case Just of
          taLeftJustify  : DrawText(Handle, PChar(S), length(S), DrawRect,
                             dt_singleline or dt_vcenter or dt_left);
          taCenter       : DrawText(Handle, PChar(S), length(S), DrawRect,
                             dt_singleline or dt_vcenter or dt_center);
          taRightJustify : DrawText(Handle, PChar(S), length(S), DrawRect,
                             dt_singleline or dt_vcenter or dt_right);
          end;
      { restore no font styles }
      Font.Style:= [];
      end;
    end;
end;

Ich denke, das wird gut funktionieren für Sie...

+1, Das sieht gut aus. Ich werde es mal ausprobieren & erhalten Sie zurück. Dank
Das code-sets RowHeights[] innerhalb der DrawCell routine. Uglhh...
es ist ein Beispiel (in vielen Punkten), wie sollten Sie nicht in den code schreiben (außer dass es tut, was NGLN darauf hingewiesen). Mein Vorschlag, benutze es nicht...
Aber, wenn es funktioniert und niemand sonst kann die post eine Lösung ...
Ich lese gerade den code, ich sehe nicht, wo es faßt mehrere Zeilen der Begegnung mit #13#10
Der erste Aufruf DrawText (mit DT_CALCRECT-flag) ermittelt das Rechteck erforderlich zu ziehen, der text, die berücksichtigt, mehrere Zeilen.
+1 für replyimng, aber wir reden am Kreuz Schweinswale. Ist, die Umhüllung, wenn eine Zeile zu lang wird? Wenn es Raum für 12 chars, und ich pass 'ein'#13 'B'#13 '- C' - erhalte ich drei Zeilen? Ich möchte in der Lage sein zu sagen, wo genau die Zeilenumbrüche kommen. Vielen Dank für deine Hilfe @SertacAkyuz
Ja, das wird Berechnung der Rechteck für 3 Zeilen. Außerdem, wenn die Zeilen über den rechten Rand, es wird gewickelt (wegen der DT_WORDBREAK flag), so dass Sie können am Ende mit mehr Zeilen.
das sieht aus wie guter code (und extrem flexibel), aber es hat einen compile-Fehler - was ist SetGridHeight ?
kein Kommentar?
Der code ist aus einem forum im Jahr 2003. LU RD hat eingefügt, der code hier, ich habe nur die Verknüpfung zu dem original-Beitrag. Jedoch, ich bin kein Delphi-Programmierer (ich verwende C++ Builder) und die gleiche VCL Bibliothek, die als Delphi-Benutzer verwenden. Es könnte sein, dass die TStringGrid-Komponente wurde geändert, seit 2003 (nicht das erste mal, dass Sie sich bewegen und so). Meine Vermutung ist, dass SetGridHeight() aufgerufen wurde, um zu zwingen die Zelle selbst aktualisieren, daher fallen in diese routine wieder, aber dieses mal die Zellenhöhe passt der ganze text und gezogen werden. (weiter im nächsten Kommentar)
(...weiter aus brevious Kommentar), Wenn der code funktioniert, ohne die SetGridHeight() es macht den job in der zugrunde liegenden VCL. Ich bin damit einverstanden, dass dies kein guter Ort ist, zum einstellen der Zellenhöhe, es sollte getan werden, zur gleichen Zeit, die Sie einen neuen Wert zuweisen, um das raster. Manchmal werden Sie vielleicht nicht wollen, dass die Zelle ändern in der Größe. Jedoch, konnte Sie ein cap-Wert, um die Berechnung der Höhe nur zulassen, dass es zu einer maximalen Höhe.
und danke

InformationsquelleAutor Max Kielland

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.