Wie, um ein Bild anzuzeigen, das in vbscript?

Möchte ich schreiben, einen code zum anzeigen und Bild-für alle 20 Minuten mit Vbscript. Ist es möglich, laden Sie die Bilder mithilfe von VBscript? Ich habe festgestellt, das LoadPicture() wäre eine option.

Das Bild sollte pop-up, sobald alle 20 Minuten in meinem desktop-Fenster.

Wie es zu benutzen? Bitte helfen Sie mir. Vielen Dank im Voraus.

Es gibt Tonnen von kostenlosen wallpaper-wechsler gibt. Irgendein besonderer Grund, warum Sie wollen, um die Umsetzung des x-TEN (und in VBScript zu starten)?
Eigentlich bin ich versucht, eine Anwendung zu erstellen, die erscheint, ein gif-Bild von einem blinkenden Auge alle 20 Minuten mit einer Meldung "Bitte blinken Sie Ihre Augen und sehen ein Objekt, das 20 Meter von Ihnen entfernt." Ich dachte, ich könnte es mit VBScript.
Haben Sie versucht, mithilfe der Windows-Aufgabenplanung ausführen der vbs ... kann man einplanen, nach jeder 20 Minuten, die ich glauben,
könntest du bitte gebt mir ein Beispiel?
Gebucht haben, eine mögliche Lösung zu Antworten. Lassen Sie mich wissen, wenn dieses für Sie arbeitet.
Verwandte: Brauchen Sie eine VBScript Öffnen Sie eine lokale Bild-Datei mithilfe der Anwendung Command prompt
vielen Dank für deine Hilfe 🙂

InformationsquelleAutor arunpandiyarajhen | 2013-12-04

image vbscript

Ok Arun. Hier ist, was ich Tat

Erstellen Sie eine VBS-Datei mit dem folgenden code

Set objExplorer = CreateObject("InternetExplorer.Application")
With objExplorer
    .Navigate "about:blank"
    .Visible = 1
    .Document.Title = "Show Image"
    .Toolbar=False
    .Statusbar=False
    .Top=400
    .Left=400
    .Height=200
    .Width=200
    .Document.Body.InnerHTML = "<img src='C:\Users\pankaj\Desktop\a.jpg'>"
End With

Gehen, um Fenster Task Scheduler und eine Aufgabe erstellen, die
- Erstellen Sie einen Trigger für 20 Minuten - Täglich wiederholt
- Aktion angeben, wie ein Programm Starten -> %systemroot%\system32\cscript.exe -> in
  Argumente geben die VBS-Datei die Lage

InformationsquelleAutor Pankaj Jaju

Können Sie versuchen, das vbscript :

LoadImage.vbs

Option Explicit
If AppPrevInstance() Then 
    MsgBox "There is an existing proceeding !" & VbCrLF & CommandLineLike(WScript.ScriptName),VbExclamation,"There is an existing proceeding !"    
    WScript.Quit   
Else
    Dim ws,fso,Srcimage,Temp,PathOutPutHTML,fhta
    Set ws = CreateObject("wscript.Shell")
    Set fso = CreateObject("Scripting.FileSystemObject")
    Temp = WS.ExpandEnvironmentStrings("%Temp%")
    PathOutPutHTML = Temp & "\image.hta"
    Set fhta = fso.OpenTextFile(PathOutPutHTML,2,True)
    Srcimage = "http://img.xooimage.com/files86/6/3/b/encode-decode-37ceb55.jpg"
    Do
        Call LoadImage(Srcimage)
        ws.run "mshta.exe " & PathOutPutHTML
        Call Pause(20)
    Loop
End If
'********************************************************************************************************
Sub LoadImage(Srcimage)
    fhta.WriteLine "<html>"
    fhta.WriteLine "    <hta:application id=""oHTA"" "
    fhta.WriteLine "        border=""none"" "
    fhta.WriteLine "        caption=""no"" "
    fhta.WriteLine "        contextmenu=""no"" "
    fhta.WriteLine "        innerborder=""no"" "
    fhta.WriteLine "        scroll=""no"" "
    fhta.WriteLine "        showintaskbar=""no"" "
    fhta.WriteLine "    />"
    fhta.WriteLine "    <script language=""VBScript"">"
    fhta.WriteLine "        Sub Window_OnLoad"
    fhta.WriteLine "            'Resize and position the window"
    fhta.WriteLine "            width = 760 : height = 580"
    fhta.WriteLine "            window.resizeTo width, height"
    fhta.WriteLine "            window.moveTo screen.availWidth\2 - width\2, screen.availHeight\2 - height\2"
    fhta.WriteLine "            'Automatically close the windows after 5 seconds"
    fhta.WriteLine "            idTimer = window.setTimeout(""vbscript:window.close"",10000)"
    fhta.WriteLine "        End Sub"
    fhta.WriteLine "    </script>"
    fhta.WriteLine "<body>"
    fhta.WriteLine "    <table border=0 width=""100%"" height=""100%"">"
    fhta.WriteLine "        <tr>"
    fhta.WriteLine "            <td align=""center"" valign=""middle"">"
    fhta.WriteLine "                <img src= "& Srcimage & ">"
    fhta.WriteLine "            </td>"
    fhta.WriteLine "        </tr>"
    fhta.WriteLine "    </table>"
    fhta.WriteLine "</body>"
    fhta.WriteLine "</html>"
End Sub
'**********************************************************************************************
Sub Pause(Min)
    Wscript.Sleep(Min*1000*60)
End Sub  
'**********************************************************************************************
Function AppPrevInstance()   
    With GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")   
        With .ExecQuery("SELECT * FROM Win32_Process WHERE CommandLine LIKE " & CommandLineLike(WScript.ScriptFullName) & _
            " AND CommandLine LIKE '%WScript%' OR CommandLine LIKE '%cscript%'")   
            AppPrevInstance = (.Count > 1)   
        End With   
    End With   
End Function   
'**************************************************************************
Function CommandLineLike(ProcessPath)   
    ProcessPath = Replace(ProcessPath, "\", "\\")   
    CommandLineLike = "'%" & ProcessPath & "%'"   
End Function
'**************************************************************************

InformationsquelleAutor Hackoo

Set objExplorer = CreateObject ("InternetExplorer.Application")
Do
Wscript.sleep 1200000
with objExplorer
.Navigate "about:blank"
.Document.Title = "title goes here"
.ToolBar = 0
.StatusBar = 0
.Left = (intHorizontal - 200) / 2
.Top = (intVertical - 400) / 2
.Width = 200
.Height = 400
.Visible = 1             

.Document.Body.Style.Cursor = "default"

.Document.Body.InnerHTML = "<img src='C:\Users\Administrator\Desktop\Virus\Image.jpg'>"
End With
Loop

Herzlich willkommen auf Stack Overflow! Bitte Bearbeiten Sie Ihre post, um mehr hinzuzufügen Erklärung darüber, was dein code macht und warum es das problem zu lösen. Eine Antwort, die meist nur code enthält (auch wenn es funktioniert) in der Regel nicht helfen, die OP zu verstehen, Ihr problem.

InformationsquelleAutor Daniel

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.