Wie um zu überprüfen, ob port offen ist auf einem remote-server mit batch-Datei und ohne Drittanbieter-software?

Upsettingly, wird Windows nicht bieten einfache Werkzeuge, um zu überprüfen, ob port offen ist auf einem remote-server.

Ist eine option, telnet, aber es kann nicht sein, scripted, wie es zugeht, wenn die Ausgabe umgeleitet oder gefangen genommen werden. Once upon a time es war ein MSWinsock.Winsock.1 COM-Objekt installiert auf Windows-Maschinen, die verwendet werden könnten, in einem Skript, aber nicht mehr. PortQry und PsPing sind wunderbare Werkzeuge, aber Sie haben noch, um Sie herunterzuladen (obwohl es von Microsoft bereitgestellt).

Also der einfachste Weg ist es, verlassen Sie sich auf PowerShell.

Hier ist der code für eine einfache .bat - Skript, intern verwenden Sie Powershell, um den job zu erledigen :

@echo off

::Must be without quotes. If you intend to use command line arguments use %~1
set "host=google.com"
set /a port=443

for /f %%a in ('powershell "$t = New-Object Net.Sockets.TcpClient;try{$t.Connect("""%host%""", %port%)}catch{};$t.Connected"') do set "open=%%a"
:: or simply
:: powershell "$t = New-Object Net.Sockets.TcpClient;try{$t.Connect("""%host%""", %port%)}catch{};$t.Connected"
echo Open: %open%

Einige Maschinen haben .NET framework ohne PowerShell installiert ist, also in diesem Fall C# - code eingebettet werden kann in ein batch-Skript mit msbuild:

<!-- :
    @echo off
    :: checks if a port on a remote server is open
    :: returns errorlevel 1 if it's closed
        setlocal
        for %%h in (/h /help -help -h "") do (
            if /I "%~1" equ "%%~h" (
                goto :printHelp
            )
        )

        if "%~2" equ ""  goto :printHelp

        set "HOST=%~1"
        set /a PORT=%~2

        ::::::  Starting C# code :::::::
        :: searching for msbuild location
        for /r "%SystemRoot%\Microsoft.NET\Framework\" %%# in ("*msbuild.exe") do  set "msb=%%#"

        if not defined  msb (
           echo No .NET framework installed
           endlocal & exit /b 10
        )

        rem ::::::::::  calling msbuid :::::::::
        call %msb% /nologo /noconsolelogger  "%~dpsfnx0"
        rem ::::::::::::::::::::::::::::::::::::
        endlocal & exit /b %errorlevel%

        :printHelp
        echo Checks if port is open on a remote server
        echo(
        echo Usage:
        echo    %~nx0 host port
        echo(
        echo If the port is not accessible an errorlevel 1 is set
        endlocal & exit /b 0

--> 

<Project ToolsVersion="$(MSBuildToolsVersion)" xmlns="http://schemas.microsoft.com/developer/msbuild/2003">
  <Target Name="_"><_/></Target>
  <UsingTask TaskName="_" TaskFactory="CodeTaskFactory" AssemblyFile="$(MSBuildToolsPath)\Microsoft.Build.Tasks.v$(MSBuildToolsVersion).dll" > 

    <Task>
      <Using Namespace="System" />
      <Using Namespace="System.Net.Sockets" />

      <Code Type="Method" Language="cs"><![CDATA[

      public override bool Execute(){
            String host=Environment.GetEnvironmentVariable("HOST").ToLower();
            int port=Int32.Parse(Environment.GetEnvironmentVariable("PORT"));

            Console.WriteLine("Checking host {0} and port {1}",host,port);
            using(TcpClient client = new TcpClient()) {
            try {
                client.Connect(host, port);
            } catch(Exception) {
                Console.WriteLine("Closed");
                return false;
            }
            client.Close();
            Console.WriteLine("Open");
            return true;
        }       
      }
        ]]>
      </Code>
    </Task>
  </UsingTask>
</Project>

Als für die Maschinen ohne .NET framework kenne ich keine native Methode, um zu überprüfen remote-ports.

Diese Befehle können verwendet werden in der Powershell:

New-Object System.Net.Sockets.TcpClient("123.12.12.123", 22)
New-Object System.Net.Sockets.UdpClient("123.12.12.123", 22)