Wie zu Lesen, eine Excel-Datei(97-03) in Visual Basic 6.0

Kann mir jemand sagen, wie zu Lesen, eine Excel-Datei in visual basic 6.0 und importieren Sie alle Werte in eine listview oder ein datagridview verwenden wollen,eine einfache und effiziente Methode, dies zu erreichen. kann mir jemand helfen um dieses Problem zu lösen

  • ich weiß, sind diese alle veraltet ,aber brauche es für ein letztes mal
InformationsquelleAutor karthik | 2012-05-02
  1. 8

    Dies sollte den import von Daten aus einer Excel Datei in eine ListView:

        Dim ExcelObj As Object
    Dim ExcelBook As Object
    Dim ExcelSheet As Object
    Dim i As Integer

    Set ExcelObj = CreateObject("Excel.Application")
    Set ExcelSheet = CreateObject("Excel.Sheet")

    ExcelObj.WorkBooks.Open App.Path & "\ExcelFile.xls"

    Set ExcelBook = ExcelObj.WorkBooks(1)
    Set ExcelSheet = ExcelBook.WorkSheets(1)

    Dim l As ListItem
    lvwList.ListItems.Clear
    With ExcelSheet
    i = 1
    Do Until .cells(i, 1) & "" = ""
        Set l = lvwList.ListItems.Add(, , .cells(i, 1))
        l.SubItems(1) = .cells(i, 2)
        l.SubItems(2) = .cells(i, 3)
        l.SubItems(3) = .cells(i, 4)
        i = i + 1
    Loop

    End With

    ExcelObj.WorkBooks.Close

    Set ExcelSheet = Nothing
    Set ExcelBook = Nothing
    Set ExcelObj = Nothing
    • l.SubItems(1) = .cells(i, 2) auf dieser Linie bin ich immer der Fehler ungültige Eigenschaft
    • Versuchen Sie, hinzufügen von Spaltenüberschriften.
    • Danke, ich versucht, um einen Wert an die Spalte, die nicht vorhanden sind.
    • xaisoft,während das Lesen von excel-alle codes, die ich habe versucht, halten Sie die excel im Speicher und es Lesen,ist es möglich, das gleiche zu tun, ohne die Datei in den Speicher,wenn es albern klingt, bitte lassen Sie diese kommentieren
    • diese Zeile " Set ExcelSheet = CreateObject("Excel.Blatt"): "ist es relevant? die gleiche variable wird gesetzt 2 Zeilen afeter bevor Sie verwendet werden...
    InformationsquelleAutor Xaisoft
  2. 2

    Ich würde viel mehr wahrscheinlich verwenden Sie ein grid-Steuerelement von einer Art, anstatt ein ListView, aber...

    Da Sie ja nur bringen, ohne dass die Metadaten-Werte (Formatierung) Sie können mit einem Jet Excel IISAMs dies zu tun, und es funktioniert sogar auf Computern, auf denen Excel nicht installiert ist!

    Dim SheetName As String
Dim RS As ADODB.Recordset
Dim LI As ListItem
Dim I As Integer

'Look up 1st Worksheet (or just hardcode its Name).
'
'Notes:
'  o Can use Excel 8.0 or Excel 5.0 to read most Excel 7.0/97
'    Workbooks, but there is no IISAM specifically for Excel 7.0.
'  o Use HDR=Yes if your Worksheet has a header row.
With CreateObject("ADOX.Catalog")
    .ActiveConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source='" _
                      & App.Path & "\sample.xls';" _
                      & "Extended Properties='Excel 5.0;HDR=No'"
    SheetName = .Tables(0).Name
    Set RS = New ADODB.Recordset
    Set RS.ActiveConnection = .ActiveConnection
End With
'The "Table" name can be a range too, e.g. [Sheet1$A1C7]
With RS
    .Open "[" & SheetName & "]", _
          , _
          adOpenForwardOnly, _
          adLockReadOnly, _
          adCmdTable
    ListView.ListItems.Clear
    ListView.View = lvwReport
    For I = 0 To .Fields.Count - 1
        ListView.ColumnHeaders.Add , , .Fields(I).Name
    Next
    Do Until .EOF
        Set LI = ListView.ListItems.Add(, , CStr(.Fields(0).Value))
        For I = 1 To .Fields.Count - 1
            LI.SubItems(I) = CStr(.Fields(I).Value)
        Next
        .MoveNext
    Loop
    .Close
End With
    InformationsquelleAutor Bob77
Schreibe einen Kommentar