Windows-batch-Skript zu Parsen von CSV-Datei und Ausgabe einer text-Datei

Wichtiges update - ich glaube nicht, dass Windows-batch ist eine gute option für Ihre Bedürfnisse, weil eine einzige FOR /F nicht analysieren kann mehr als 31 Token. Siehe unten den Nachtrag unten für eine Erklärung.

Es ist jedoch möglich, das zu tun, was Sie wollen mit batch. Dieser hässliche code erhalten Sie Zugang zu allen 64-Token.

for /f "usebackq tokens=1-29* delims=," %%A in ("%filename%") do (
  for /f "tokens=1-26* delims=," %%a in ("%%^") do (
    for /f "tokens=1-9 delims=," %%1 in ("%%{") do (
      rem Tokens 1-26 are in variables %%A - %%Z
      rem Token  27 is in %%[
      rem Token  28 is in %%\
      rem Token  29 is in %%]
      rem Tokens 30-55 are in %%a - %%z
      rem Tokens 56-64 are in %%1 - %%9
    )
  )
)

Anhang bietet wichtige Informationen, wie die oben genannten arbeiten.

Wenn Sie nur brauchen ein paar der Token verteilen sich unter anderem der 64 auf der Linie, dann die Lösung ist geringfügig einfacher, dass Sie vielleicht in der Lage zu vermeiden, mit verrückten Charakteren, wie FÜR Variablen. Aber es ist trotzdem eine sorgfältige Buchführung zu erfolgen.

Beispielsweise im folgenden erhalten Sie Zugang zu Token 5, 27, 46 und 64

for /f "usebackq tokens=5,27,30* delims=," %%A in ("%filename%") do (
  for /f "tokens=16,30* delims=," %%E in ("%%D") do (
    for /f "tokens=4 delims=," %%H in ("%%G") do (
      rem Token  5 is in %%A
      rem Token 27 is in %%B
      rem Token 46 is in %%E
      rem Token 64 is in %%H
    )
  )
)

April 2016 Update - Basierend auf Untersuchungen von DosTips Benutzer Aacini, penpen, und aGerman habe, entwickelte ich eine relativ einfache Methode, um gleichzeitigen Zugriff auf Tausende von Token verwenden FÜR /F. Die Arbeit ist Teil des diese DosTips thread. Der eigentliche code kann gefunden werden in diesen 3 posts:

• Arbeiten mit einer festen Anzahl von Spalten
• Arbeiten mit unterschiedlichen Anzahl von Spalten
• Dynamisch auswählen, welche Token zu erweitern, innerhalb der DO-Klausel

Ursprüngliche Antwort
FÜR die Variablen sind begrenzt auf ein einzelnes Zeichen, so Ihr %%BL-Strategie nicht funktionieren kann. Die Variablen sind case-Sensitiv. Laut Microsoft, Sie sind beschränkt auf die Erfassung 26 Token innerhalb einer FOR-Anweisung, aber es ist möglich, mehr zu bekommen, wenn Sie mehr als nur alpha. Seine Schmerzen, denn Sie müssen eine ASCII-Tabelle, um herauszufinden, welche Zeichen gehen, wo. FÜR lässt nicht nur jedes Zeichen, jedoch, und die maximale Anzahl der Token, die ein einzelner FÜR /F zuweisen können, ist 31 +1. Jeder Versuch, zu analysieren und zuordnen von mehr als 31 wird ruhig ausfallen, als Sie entdeckt habe.

Zum Glück, ich glaube nicht, dass Sie brauchen, dass viele Token. Sie geben einfach an, welche Token Sie wollen mit dem TOKEN-option.

for /f "usebackq tokens=7,12,15,18 delims=," %%A in ("%filename%") do echo %%A,%%B,%%C,%%D

geben Sie Ihren 7., 12., 15 und 18 Token.

Nachtrag

April 2016 Update vor Ein paar Wochen erfuhr ich, dass die folgenden Regeln (geschrieben vor 6 Jahren) sind code-Seite abhängig. Die Daten unten wurden überprüft, für Codepages 437 und 850. Mehr wichtiger ist, die FÜR die variable Sequenz von erweiterten ASCII-Zeichen 128-254 nicht mit der byte-code-Wert und variiert enorm von der code-Seite. Es stellt sich heraus, die FOR /F-variable-mapping basiert auf der zugrunde liegenden UTF-(16?) code zeigen. Also die erweiterte ASCII-Zeichen sind von begrenztem nutzen, wenn Sie Sie mit FÜR /F. Siehe den thread unter http://www.dostips.com/forum/viewtopic.php?f=3&t=7703 für weitere Informationen.

Ich einige tests durchgeführt und kann Folgendes berichten (Aktualisierung in Reaktion auf jeb ' s Kommentar):

Meisten Zeichen können verwendet werden wie eine variable, einschließlich der erweiterten ASCII-128-254. Aber einige Zeichen können nicht verwendet werden, um eine variable definieren, in der der erste Teil einer FOR-Anweisung, kann aber verwendet werden, in der DO-Klausel. Ein paar kann nicht verwendet werden, für die entweder. Einige haben keine Einschränkungen, erfordern aber eine spezielle syntax.

Folgende ist eine Zusammenfassung von Zeichen, die Beschränkungen oder erfordern eine Besondere syntax. Beachten Sie, dass text innerhalb der Spitzen Klammern wie <space> repräsentiert ein einzelnes Zeichen.

Dec  Hex   Character   Define     Access
  0  0x00  <nul>       No         No
 09  0x09  <tab>       No         %%^<tab>  or  "%%<tab>"
 10  0x0A  <LF>        No         %%^<CR><LF><CR><LF>  or  %%^<LF><LF>
 11  0x0B  <VT>        No         %%<VT>
 12  0x0C  <FF>        No         %%<FF>
 13  0x0D  <CR>        No         No
 26  0x1A  <SUB>       %%%VAR%    %%%VAR% (%VAR% must be defined as <SUB>)
 32  0x20  <space>     No         %%^<space>  or  "%%<space>"
 34  0x22  "           %%^"       %%"  or  %%^"
 36  0x24  $           %%$        %%$ works, but %%~$ does not
 37  0x25  %           %%%%       %%~%%
 38  0x26  &           %%^&       %%^&  or  "%%&"
 41  0x29  )           %%^)       %%^)  or  "%%)"
 44  0x2C  ,           No         %%^,  or  "%%,"
 59  0x3B  ;           No         %%^;  or  "%%;"
 60  0x3C  <           %%^<       %%^<  or  "%%<"
 61  0x3D  =           No         %%^=  or  "%%="
 62  0x3E  >           %%^>       %%^>  or  "%%>"
 94  0x5E  ^           %%^^       %%^^  or  "%%^"
124  0x7C  |           %%^|       %%^|  or  "%%|"
126  0x7E  ~           %%~        %%~~ (%%~ may crash CMD.EXE if at end of line)
255  0xFF  <NB space>  No         No

Sonderzeichen wie ^ < > | & muss entweder escaped oder quotiert. Zum Beispiel, die folgenden Werke:

for /f %%^< in ("OK") do echo "%%<" %%^<

Einige Zeichen können nicht verwendet werden, definieren Sie eine variable. Zum Beispiel, die folgende gibt einen syntax-Fehler:

for /f %%^= in ("No can do") do echo anything

Aber %%= wird implizit definiert, indem die TOKEN-option, und den Wert zugegriffen und in der DO-Klausel, etwa so:

for /f "tokens=1-3" %%^< in ("A B C") do echo %%^< %%^= %%^>

Den % ist seltsam - Sie definieren eine variable mit %%%%. Aber Der Wert kann nicht zugegriffen werden, es sei denn, Sie verwenden die ~ modifier. Dies bedeutet, dass die umschließenden Anführungszeichen können nicht beibehalten werden.

for /f "usebackq tokens=1,2" %%%% in ('"A"') do echo %%%% %%~%%

Den oben genannten Erträge %% A

Den ~ ist ein potenziell gefährlicher FÜR die variable. Wenn Sie, versuchen Zugriff auf die variable mit %%~ am Ende einer Zeile, können Sie bekommen zu unvorhersehbaren Ergebnissen und möglicherweise sogar Abstürzen CMD.EXE! Der einzige zuverlässige Weg, um Zugriff ohne Einschränkungen ist die Verwendung %%~~, die natürlich entfernt alle umschließenden Anführungszeichen.

for /f %%~ in ("A") do echo This can crash because its the end of line: %%~

for /f %%~ in ("A") do echo But this (%%~) should be safe

for /f %%~ in ("A") do echo This works even at end of line: %%~~

Den <SUB> (0x1A) Charakter ist etwas besonderes, weil <SUB> Literale eingebettet innerhalb des batch-Skripts ausgelesen werden, werden Zeilenvorschubzeichen (<LF>). Um <SUB> als FÜR die variable, der Wert muss irgendwie gespeichert innerhalb einer environment-variable ist, und dann %%%VAR% funktioniert für beide-definition und Zugang.

Wie gesagt, eine einzige FÜR /F Parsen und zuordnen maximal 31 tokens. Zum Beispiel:

@echo off
setlocal enableDelayedExpansion
set "str="
for /l %%n in (1 1 35) do set "str=!str! %%n"
for /f "tokens=1-31" %%A in ("!str!") do echo A=%%A _=%%_

Den oben genannten Erträge A=1 _=31 Hinweis - Token 2-30 gut funktionieren, ich wollte nur ein kleines Beispiel

Jeden Versuch, zu analysieren und weisen Sie mehr als 31 Zeichen im hintergrund fehl, ohne ERRORLEVEL.

@echo off
setlocal enableDelayedExpansion
set "str="
for /l %%n in (1 1 35) do set "str=!str! %%n"
for /f "tokens=1-32" %%A in ("!str!") do echo this example fails entirely

Können Sie analysieren und die Zuweisung von bis zu 31 Token zuweisen und den Rest für ein anderes token wie folgt:

@echo off
setlocal enableDelayedExpansion
set "str="
for /l %%0 in (1 1 35) do set "str=!str! %%n"
for /f "tokens=1-31*" %%@ in ("!str!") do echo @=%%A  ^^=%%^^  _=%%_

Den oben genannten Erträge @=1 ^=31 _=32 33 34 35

Und jetzt die wirklich schlechte Nachricht. Eine einzelne FOR /F kann nie analysieren mehr als 31 Token, wie ich erfuhr, als ich sah Anzahl der Token-limit in einem FOR-Befehl in einem Windows-batch-Skript

@echo off
setlocal enableDelayedExpansion
set "str="
for /l %%n in (1 1 35) do set "str=!str! %%n"
for /f "tokens=1,31,32" %%A in ("!str!") do echo A=%%A  B=%%B  C=%%C

Den sehr unglücklichen Ausgang ist A=1 B=31 C=%C

InformationsquelleAutor dbenham

% % @ % % ` (Hier nicht dokumentiert) als start-Variablen max, die Sie bekommen können ist 71:

@echo off
for /f "tokens=1-31* delims=," %%@ in ("%filename%") do (
    echo:
    echo  1=%%@
    echo  2=%%A
    echo  3=%%B
    echo  4=%%C
    echo  5=%%D
    echo  6=%%E
    echo  7=%%F
    echo  8=%%G
    echo  9=%%H
    echo 10=%%I
    echo 11=%%J
    echo 12=%%K
    echo 13=%%L
    echo 14=%%M
    echo 15=%%N
    echo 16=%%O
    echo 17=%%P
    echo 18=%%Q
    echo 19=%%R
    echo 20=%%S
    echo 21=%%T
    echo 22=%%U
    echo 23=%%V
    echo 24=%%W
    echo 25=%%X
    echo 26=%%Y
    echo 27=%%Z
    echo 28=%%[
    echo 29=%%\
    echo 30=%%]
    echo 31=%%^^
    for /F "tokens=1-30* delims=," %%` in ("%%_") do (
        echo 32=%%`
        echo 33=%%a
        echo 34=%%b
        echo 35=%%c
        echo 36=%%d
        echo 37=%%e
        echo 38=%%f
        echo 39=%%g
        echo 40=%%h
        echo 41=%%i
        echo 42=%%j
        echo 43=%%k
        echo 44=%%l
        echo 45=%%m
        echo 46=%%n
        echo 47=%%o
        echo 48=%%p
        echo 49=%%q
        echo 50=%%r
        echo 51=%%s
        echo 52=%%t
        echo 53=%%u
        echo 54=%%v
        echo 55=%%w
        echo 56=%%x
        echo 57=%%y
        echo 58=%%z
        echo 59=%%{
        echo 60=%%^|
        echo 61=%%}
        for /F "tokens=1-9* delims=," %%0 in ("%%~") do (
            echo 62=%%0
            echo 63=%%1
            echo 64=%%2
            echo 65=%%3
            echo 66=%%4
            echo 67=%%5
            echo 68=%%6
            echo 69=%%7
            echo 70=%%8
            echo 71=%%9
        )
    )
)

InformationsquelleAutor Andy Smith