Write-text-Datei Anhängen (utf-8-codiert) in VB6

Ich habe das schreiben einer Textdatei in VB6. Ich muss es tun in Anhängen und in utf-8 codiert.

Habe ich versucht zwei Lösungen, eine mit "TextStream" und einer mit "ADODB.Stream".

Die erste:

    Set fsoFile = fso.OpenTextFile(FileIn(fi), ForAppending, True)
    fsoFile.WriteLine "<tag>kkkjòòkkkkjlòlk</tag>"
    fsoFile.Close

Funktioniert gut in Anhängen aber wie kann ich schreiben das es utf-8 codiert?

Den zweiten:

Dim ST As ADODB.Stream

Set ST = New ADODB.Stream
ST.Mode = adModeReadWrite
ST.Type = adTypeText
ST.Charset = "UTF-8"

ST.Open
ST.LoadFromFile FileIn(fi)
ST.Position = ST.Size
ST.WriteText "<tag>kkkjòòkkkkjlòlk</tag>"
ST.SaveToFile FileIn(fi)
ST.Close

Schreiben korrekt in utf-8, aber ich kann nicht schreiben, die Datei Anhängen, aber nur mit "adSaveCreateOverWrite".

Wie kann ich das tun? Gibt es einen anderen Weg?

Danke Ihnen sehr.

  • Mit Ihrem ADODB-Stream-Objekt, wenn die Datei, die Sie Anhängen, ist nicht zu groß, können Sie es öffnen, Lesen Sie den vorhandenen text in eine variable, dann schreiben Sie die variable, und der neue text wieder raus. Sie können auch öffnen Sie eine neue Datei jedes mal, schreiben Sie den vorhandenen text, um es dann den neuen text ein. Töten Sie die aktuelle Datei, und benennen Sie die neue Datei. Kompliziert, aber funktioniert schnell genug für kleinere Dateien, die der Benutzer nicht Links warten.
  • Leider arbeite ich mit großen text-Datei. Ich denke, dass es öffnen und Lesen Sie den vorhandenen text zu jeder Schleife wird eine schwere Arbeit für meine Anwendung.
InformationsquelleAutor epi82 | 2012-05-04
  1. 10

    Sie kombinieren könnte binäre I/O mit einem API-Aufruf, um die Konvertierung zu UTF-8:

    Option Explicit

Private Const CP_UTF8 As Long = 65001

Private Declare Function WideCharToMultiByte Lib "kernel32" ( _
    ByVal CodePage As Long, _
    ByVal dwFlags As Long, _
    ByVal lpWideCharStr As Long, _
    ByVal cchWideChar As Long, _
    ByVal lpMultiByteStr As Long, _
    ByVal cchMultiByte As Long, _
    ByVal lpDefaultChar As Long, _
    ByVal lpUsedDefaultChar As Long) As Long

Private Function OpenAppendUTF8(ByVal FileName As String) As Integer
    OpenAppendUTF8 = FreeFile(0)
    Open FileName For Binary Access Write As #OpenAppendUTF8
    Seek #OpenAppendUTF8, LOF(OpenAppendUTF8) + 1
End Function

Private Sub WriteUTF8( _
    ByVal FNum As Integer, _
    ByVal Text As String, _
    Optional ByVal NL As Boolean)

    Dim lngResult As Long
    Dim UTF8() As Byte

    If NL Then Text = Text & vbNewLine
    lngResult = WideCharToMultiByte(CP_UTF8, 0, StrPtr(Text), Len(Text), _
                                    0, 0, 0, 0)
    If lngResult > 0 Then
        ReDim UTF8(lngResult - 1)
        WideCharToMultiByte CP_UTF8, 0, StrPtr(Text), Len(Text), _
                            VarPtr(UTF8(0)), lngResult, 0, 0
        Put #FNum, , UTF8
    End If
End Sub

Private Sub Main()
    Dim F As Integer

    F = OpenAppendUTF8("test.txt")
    WriteUTF8 F, "Hello"
    WriteUTF8 F, ChrW$(&H2026&)
    WriteUTF8 F, "World", True
    Close #F
    MsgBox "Done"
End Sub
    • Fügen Sie einfach UTF-8-BOM, wenn LOF(OpenAppendUTF8) null ist.
    • Tatsächlich UTF-8-Dateien sind nie soll habe eine Stückliste, obwohl Sie Häufig sehen, wie Sie auf Windows-Dateien. en.wikipedia.org/wiki/UTF-8#Byte_order_mark Also ja, wenn Sie benötigen eine Stückliste hinzufügen, wie vorgeschlagen. Beachten Sie auch, dass UTF-8-Dateien sind oft erwartet, LF statt CRLF line-Trennzeichen, ein mehr zwicken könnte man machen.
    InformationsquelleAutor Bob77
  2. 1

    Ich bevorzuge, um es zu speichern ANSI, wie es standardmäßig tut. Öffnen Sie es mit notepad und überschreibt es die Auswahl von UTF8-Codierung. Ich fand es ist der Schnellste Weg von weit.
    Und ich mit einem anderen code Anhängen, zum Beispiel für eine Datenbank-Konvertierung:

    Dim fs As Object, a
Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.CreateTextFile(filename, True) 'example (myfile.xml, True)
a.writeline var1
a.writeline var2
a.Close
    • Funktioniert das? Ich dachte, dass wenn Sie schreiben, es zuerst mit ANSI-dann sind Sie begrenzen Ihre Zeichen gesetzt. Würde nicht es zu speichern in UTF8 nach ANSI Gerechten Ergebnis in einer UTF-version des ANSI-Zeichensatz? Also, wenn Ihr text war in russischer, würden Sie wirklich zur Aufrechterhaltung der richtigen Zeichen? Die CreateTextFile-kann speichern im Unicode-Format (UTF16) durch das hinzufügen einer weiteren "True", dann könnte man wahrscheinlich konvertieren Sie Sie in Wordpad oder etwas zu UTF8 ohne viel.
    InformationsquelleAutor Energy Kool
Schreibe einen Kommentar