XSLT: Änderung bestimmter Attribut-Werte

Ich bin ein XSLT-Neuling und habe eine einfache Aufgabe:

Angenommen ich habe folgende XML:

<Element1>
    <Element2 attr1="1"/>
</Element1>
<Element1 attr1="2"/>
<Element1>
    <Element2 attr1="2"/>
</Element1>

Will ich zur Umwandlung von XML in der gleichen XML-mit einer änderung: Alle Attribute mit der Bezeichnung "attr1" egal, wo Sie sind, umgewandelt werden, so dass zum Beispiel "1" wird "A" und "2" wird "X", ich. e. zu

<Element1>
    <Element2 attr1="A"/>
</Element1>
<Element1 attr1="X"/>
<Element1>
    <Element2 attr1="X"/>
</Element1>

Wie kann ich das erreichen?
Vielen Dank im Voraus!

InformationsquelleAutor Alexander | 2011-07-22

Können Sie festlegen, Zeichen zu ersetzen und austauschen von chars, dann verwenden Sie translate.
Sie können mit Hilfe dieser XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:variable name="in">12</xsl:variable>
    <xsl:variable name="out">AX</xsl:variable>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:attribute name="attr1">
            <xsl:value-of select="translate(., $in, $out)"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

Einen anderen Weg:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:choose>
            <xsl:when test=". = '1'">
                <xsl:attribute name="attr1">
                    <xsl:text>A</xsl:text>
                </xsl:attribute>
            </xsl:when>
            <xsl:when test=". = '2'">
                <xsl:attribute name="attr1">
                    <xsl:text>X</xsl:text>
                </xsl:attribute>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

<xsl:template match="@attr1"> passen alle Attribute attr1, dann mit xsl:choose Sie schafft entsprechenden Wert für dieses Attribut.

Um Platz für Laufzeit-Anpassung, ändern Sie den xsl:variable zu xsl:param.

InformationsquelleAutor Kirill Polishchuk

Ihnen nicht sagen, was passiert, wenn @attr=3 zum Beispiel gibt es also eine sonst-Klausel, um einfach kopieren Sie den Wert, wenn es nicht eines der ausgewählten.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="@attr1">
  <xsl:attribute name="attr1">
    <xsl:choose>
      <xsl:when test=". = 1">
        <xsl:text>A</xsl:text>
      </xsl:when>
      <xsl:when test=". = 2">
        <xsl:text>X</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="." />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:attribute>
</xsl:template>
</xsl:stylesheet>

Was ist, wenn die Werte benötigt werden, stammen von außerhalb? Also wie kann ein externes mapping-Datei verwendet werden, die "1" -> "A" and "2" -> "X" mapping?
dann könnte man die Einrichtung eines lookup über den Taste Funktion verweisen auf das externe Dokument.
Fragte ich this Frage mehr Klarheit zu gewinnen.

InformationsquelleAutor Bob Vale

Einen anderen Weg, mit document Funktion:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:l="local"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1">
        <xsl:attribute name="attr1">
            <xsl:value-of select="document('')//l:item[l:in = current()]/l:out"/>
        </xsl:attribute>
    </xsl:template>

    <xml xmlns="local">
        <item>
            <in>1</in>
            <out>A</out>
        </item>
        <item>
            <in>2</in>
            <out>X</out>
        </item>
    </xml>

</xsl:stylesheet>

Wäre es nicht effizienter, verwenden Sie einen Schlüssel-lookup gegen das Dokument?

InformationsquelleAutor Kirill Polishchuk

xslt-2-version folgenden arbeiten:

    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@attr1[.='1']">
        <xsl:attribute name="attr1">
            <xsl:value-of select="replace(.,'1','A')"/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="@attr1[.='2']">
        <xsl:attribute name="attr1">
            <xsl:value-of select="replace(.,'2','X')"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

InformationsquelleAutor jbowers

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.