XSLT - finden-position (), wenn innerhalb einer geschachtelten for-each

Ich bin mit XSLT zur transformation auf einige ziemlich komplexe XML. Um zu erreichen, die Ausgabe, die ich brauche, habe ich zum erstellen einer verschachtelten for-Schleife so etwas wie die folgenden:

Quell-XML -

<root>
  <element1>
    <child>
      <aaa></aaa>
      <bbb></bbb>
    </child>
  </element1>
  <element2/>
  <element3/>
  <element3/>
  <element3/>
</root>

XSLT

<xsl:for-each select="element3">
  <!-- Do some stuff -->

  <xsl:for-each select="../element1/child/*">
    <!-- Do some more stuff -->
  </xsl:for-each>
</xsl:for-each>

Problem

Was ich versuche zu tun ist, während in meinem geschachtelte Schleife (auf ../element1/child/*) - ich würde gern herausfinden:

Die position des Elements, ich bin derzeit auf der looping - wenn ich zum Beispiel wurde der Fokus derzeit auf <bbb> dann diese position (glaube ich) wäre '1'
Die position der übergeordneten Schleife (auf element3) - also, wenn, zum Beispiel, war ich auf die Dritte Instanz des <element3> und dann die Schleife durch ../element1/child/* und konzentrierte sich auf <aaa> - die beiden Werte würde ich nach wäre '2' und '0'.

Im Idealfall würde ich mag in der Lage sein, um die Zuordnung dieser Werte zu einer Variablen. Ich habe versucht, mit der position() notation wie unten, aber das scheint nicht zu funktionieren.

<xsl:for-each select="../element1/child/*">
  <xsl:variable name="postion_current_loop" select="position()"/>
  <xsl:variable name="postion_parent_loop" select="??????"/>
  <!-- Do some more stuff -->
</xsl:for-each>

Wenn jemand irgendwelche Ideen, wie ich das erreichen kann, dies würde sehr geschätzt werden! Ich bin mit XSLT 2.0, bin aber offen für Lösungen, die anhand von XSLT 1.0-wenn es sein muss. Vielen Dank im Voraus.

Gibt es einen Grund, dass Sie mit for-each anstelle von separaten Vorlagen. Ich kann sehen, dass mindestens eine anständige Lösung wenn Sie die Vorlagen korrekt.
Ich bin derzeit nur über eine einzige Vorlage - ich bin offen für eine Lösung mit mehreren, da bin ich noch herausfinden, wie dies zu erreichen. Ich bin ziemlich neu in XSLT so nicht verstanden das Konzept von mehreren Vorlagen noch.
OK. Diese Art der Sache ist viel einfacher, mit mehrere templates (XSLT-im Allgemeinen - es lohnt sich, ein gutes Verständnis für das Konzept).
Danke, ich werde auf jeden Fall erkunden! Jetzt die Antwort von @michael.hor257k hat mir auch ein Ausgangspunkt für eine Lösung.

InformationsquelleAutor danw | 2014-07-15

Sollten Sie versuchen, ändern Sie Ihre Eingabe:

<root>
  <element1>
    <child>
      <aaa>1a</aaa>
      <bbb>2a</bbb>
    </child>
  </element1>
  <element2/>
  <element3>3a</element3>
  <element3>3b</element3>
  <element3>3c</element3>
</root>

dann sehen, was Sie erhalten mit:

<xsl:template match="/">
    <test>
        <xsl:for-each select="root/element3">
        <xsl:variable name="parent-position" select="position()" />
        <xsl:variable name="parent-value" select="." />
            <xsl:for-each select="../element1/child/*">
                <item value="{.}" parent-value="{$parent-value}" parent-position="{$parent-position}" position="{position()}"/>
            </xsl:for-each>
        </xsl:for-each>    
    </test>
</xsl:template>

InformationsquelleAutor michael.hor257k

Habe ich einige zusätzliche id-Attribute, um Ihre Eingabe, so dass Sie sehen können welcher Knoten wird immer verarbeitet, wenn also meine Eingabe sah aus wie:

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <element1 id="e1-1">
        <child>
            <aaa id="e1-a"></aaa>
            <bbb id="e1-b"></bbb>
        </child>
    </element1>
    <element2 id="e2-1"/>
    <element3 id="e3-1"/>
    <element3 id="e3-2"/>
    <element3 id="e3-3"/>
</root>

Diesem stylesheet hat, was ich denke, Sie versuchen zu tun - es verarbeitet jede element3 und alle Abläufe der ../element1/child/* Knoten für jeden element3:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

    <xsl:output indent="yes"/>
    <xsl:template match="root">
        <tests>
            <xsl:apply-templates select="element3"/>
        </tests>
    </xsl:template>

    <xsl:template match="element3">
        <xsl:apply-templates select="../element1/child/*">
            <xsl:with-param name="parent-pos" select="position() - 1"/>
            <xsl:with-param name="parent-id" select="@id"/>
        </xsl:apply-templates>
    </xsl:template>

    <xsl:template match="element1/child/*">
        <xsl:param name="parent-pos"/>
        <xsl:param name="parent-id"/>
        <xsl:variable name="current-pos" select="position()"/>

        <test parent-id="{$parent-id}" current-id="{@id}" parent-pos="{$parent-pos}" current-pos="{$current-pos}"/>

    </xsl:template>

</xsl:stylesheet>

Ist das Ergebnis:

<tests>
   <test parent-id="e3-1" current-id="e1-a" parent-pos="0" current-pos="1"/>
   <test parent-id="e3-1" current-id="e1-b" parent-pos="0" current-pos="2"/>
   <test parent-id="e3-2" current-id="e1-a" parent-pos="1" current-pos="1"/>
   <test parent-id="e3-2" current-id="e1-b" parent-pos="1" current-pos="2"/>
   <test parent-id="e3-3" current-id="e1-a" parent-pos="2" current-pos="1"/>
   <test parent-id="e3-3" current-id="e1-b" parent-pos="2" current-pos="2"/>
</tests>

Hoffe, das hilft

InformationsquelleAutor Nic Gibson

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.