XSLT-für jeden Buchstaben in einem string

Schreibe ich eine XSLT-transformation (für XSL-FO) und die Notwendigkeit, etwas zu wiederholen, für jeden Buchstaben in einen string-Wert, zum Beispiel:

Wenn der string gespeichert ist, in MyData/MyValue string (z.B. MyData.MyValue = "etwas") ich benötige eine for-each-Beispiel:

<xsl:for-each select="MyData/MyValue"> <!-- What goes here to iterate through letters? -->
  <someTags>
    <xsl:value-of select="Letter" /> <!-- What goes here to output current letter? -->
  </someTags>
</xsl:for-each>

Irgendwelche Ideen?

Ich denke, dass die XSLT-version Anzeige relevant ist.
ja, du hast absolut Recht, ich mache es in .net framework, es ist also v1
Eigentlich ist dies eine doppelte: XSLT 1.0 : Iterieren über Zeichen in einem string
die Frage ist eine doppelte, nicht die Antworten :). Ich denke, @veljkoz annehmen sollte, dass er Sie verwenden werden, endlich.
Wow, sehr freundliche xslt-community hier SO 🙂 Danke an alle die so viel, jede Antwort geholfen, aber das ist die, die ich verwenden werde, so ich habe das als Antwort... aber alle du hast +1 von mir 😉 nochmal danke! Und danke für die Verlinkung auf die gleiche Frage verschiedene Antworten hier, aber, nicht schlecht, mehr 🙂

InformationsquelleAutor veljkoz | 2011-07-13

könnte man eine call-template und Parameter übergeben, dann verwenden Sie die Rekursion aufrufen, um die Vorlage, bis es keine verbleibenden Zeichen.

Beispiel Hinzugefügt unten.

auf diese xml -

<?xml version="1.0" encoding="utf-8"?>
<data>
        <node>something</node>
</data>

- und das xslt -

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="data/node">
            <xsl:call-template name="for-each-character">                    
                    <xsl:with-param name="data" select="."/>
            </xsl:call-template>
    </xsl:template>

        <xsl:template name="for-each-character">                
                <xsl:param name="data"/>
                <xsl:if test="string-length($data) &gt; 0">
                        <someTags>                            
                                <xsl:value-of select="substring($data,1,1)"/>
                        </someTags>
                        <xsl:call-template name="for-each-character">
                                <xsl:with-param name="data" select="substring($data,2)"/>
                        </xsl:call-template>
                </xsl:if>
        </xsl:template>
</xsl:stylesheet>

dann werden Sie in der Lage zu manipulieren, in der if-Anweisung noch weitere Sachen!

InformationsquelleAutor Treemonkey

7

Können Sie versuchen, diese Schmutz-hässlicher hack, der schon bewiesen hat, funktioniert immer wieder:
```
<xsl:for-each select="//*[position() &lt;= string-length(MyData/MyValue)]">
  <someTags>
    <xsl:value-of select="substring(MyData/MyValue, position(), 1)"/>
  </someTags>
</xsl:for-each>
```
Dies funktioniert, wenn //* mit mehr Knoten als die Anzahl der Zeichen im string... natürlich würde dies auch verdienen die ungerade Zeile-Kommentar für den Armen Kerl lese dein code hinterher... 😉

Hinweis: ich weiß, es sind XSLT-Puristen da draußen. Aber wenn Sie brauchen, um den job zu erledigen und kümmern sich nicht viel über den hyper-Ausführlichkeit von XSLT -, dann manchmal diese tricks sind genial! IMO

Beachten Sie auch: ich hob eine performance-Frage ist hier, um zu sehen, ob die iteration oder Rekursion führt besser: XSLT-iteration oder Rekursion Leistung
- -1 da die Antwort ist nicht universal, und kann zu Verwirrung führen und behindern die Novizen lernen!
- Es gibt die ersten Puristisch 🙂 BTW: ich finde rekursive Lösungen viel mehr verwirrend...
- Ich verstehe nicht, den Einwand. Ich mochte diese Lösung.
- Es gibt gute Gründe zu widersprechen. Es ist nicht wirklich eine schöne Lösung, es ist ein hack. Es funktioniert die meiste Zeit, aber es ist nicht garantiert, schnell und zuverlässig. Ich denke, für diese Frage, es ist gut genug. Aber im Allgemeinen, Lesen Sie hier: stackoverflow.com/questions/6681191/... und hier: stackoverflow.com/questions/506348/.... Ich Wünsche XSLT echte Unterstützung für Schleifen, aber naja...
InformationsquelleAutor Lukas Eder

Ich bin mir nicht sicher über die Machbarkeit der iteration. Sie können Rekursion obsviously, wie gezeigt, in anderen Antworten. Dies ist mein Vorschlag (nicht viel anders als die anderen, neben der Tatsache, ich bin mit template match Muster und nicht benannte Vorlagen):

    <xsl:template match="MyData/MyValue">
        <xsl:param name="sub" select="."/>
        <xsl:variable name="subsub" select="substring($sub,1,1)"/>
        <xsl:if test="boolean($subsub)"> 
            <someTags>
                <xsl:value-of select="$subsub"/>
            </someTags>
            <xsl:apply-templates select="self::node()">
                <xsl:with-param name="sub" select="substring($sub,2)"/>
            </xsl:apply-templates>
        </xsl:if>
    </xsl:template>

InformationsquelleAutor Emiliano Poggi

Können Sie die Rekursion:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>


    <xsl:template match="/">

        <xsl:call-template name="get-letters">
            <xsl:with-param name="input">something</xsl:with-param>
        </xsl:call-template>

    </xsl:template>

    <xsl:template name="get-letters">
        <xsl:param name="input"/>
        <xsl:if test="string-length($input)">
            <xsl:value-of select="substring($input, 1, 1)"/>
            <xsl:text>&#xA0;</xsl:text>
            <xsl:call-template name="get-letters">
                <xsl:with-param name="input" select="substring($input, 2)"/>
            </xsl:call-template>
        </xsl:if>


    </xsl:template>
</xsl:stylesheet>

Ausgabe:
s o m e t h i n g

InformationsquelleAutor Kirill Polishchuk

Gute Frage, +1.

Dies ist, was die Vorlage/Funktion str-map von FXSL ist für:

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net/" xmlns:testmap="testmap"
 exclude-result-prefixes="xsl f testmap">
   <xsl:import href="str-dvc-map.xsl"/>

   <!-- to be applied on any xml source -->

   <testmap:testmap/>

   <xsl:output method="text"/>

   <xsl:template match="/">
     <xsl:variable name="vFunTripple" select="document('')/*/testmap:*[1]"/>

     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vFunTripple"/>
       <xsl:with-param name="pStr" select="'something'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="trippleChar" match="testmap:*" mode="f:FXSL">
      <xsl:param name="arg1"/>

      <xsl:value-of select="concat($arg1,$arg1,$arg1)"/>
    </xsl:template>
</xsl:stylesheet>

wenn diese transformation wird angewendet auf beliebigen XML-Dokument (nicht verwendet), die das erwartete Ergebnis produziert wird:

sssooommmeeettthhhiiinnnggg

InformationsquelleAutor Dimitre Novatchev

2

Mehrere XSLT 1.0-Lösungen wurden gepostet (denn das ist, was das ursprüngliche Plakat benötigt). Für den Vergleich, aber, hier ist, wie dieses getan werden könnte, in XSLT 2.0 mit xsl:analyze-string:
```
<xsl:analyze-string select="MyData/MyValue" regex="."> 
  <xsl:matching-substring>
    <someTags>
      <xsl:value-of select="."/> 
    </someTags>
  </xsl:matching-substring>
</xsl:analyze-string>
```
InformationsquelleAutor Jukka Matilainen

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.