XSLT, herauszufinden, ob das Letzte Kind Knoten ist ein besonderes element

Wählen Sie einfach den letzten Knoten des <foo> element und verwenden Sie dann self Achse zu lösen, die Knoten geben.

/foo/node()[position()=last()]/self::bar

Dieser XPath-Ausdruck gibt eine leere Menge (das entspricht false), wenn der Letzte Knoten ist nicht ein element. Wenn Sie möchten, um speziell zu bekommen Wert true oder false, wickeln Sie diesen Ausdruck in der XPath-Funktion boolean(). Verwenden self::* statt self::bar übereinstimmung mit jedem element als letzten Knoten.

Eingabe-XML-Dokuments:

<root>
    <foo>some text <bar/> and maybe some more</foo>
    <foo>some text <bar/> and a last <bar/></foo>
</root>

XSLT-Dokument Beispiel:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="text"/>

<xsl:template match="foo">
    <xsl:choose>
        <xsl:when test="node()[position()=last()]/self::bar">
            <xsl:text>bar element at the end&#10;</xsl:text>
        </xsl:when>
        <xsl:otherwise>
            <xsl:text>text at the end&#10;</xsl:text>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Ausgabe des stylesheet:

text at the end
bar element at the end

Update: Diese Antwort Adressen der Anforderung angegeben in der original-Frage in der überschrift, "finden Sie heraus, wenn das Letzte Kind-Knoten ein Textknoten ist." Aber die Frage Körper schlägt einen anderen Anspruch, und es scheint, dass die letztere Bedingung war die eine bestimmt von der OP.

Den beiden vorherigen Antworten explizit testen, ob das Letzte Kind ist ein bar element, anstatt direkt testen, ob es ein Textknoten ist. Dies ist richtig, wenn foo enthält nur "gemischte text-nodes und bar-Elemente" und nie hat null Kinder.

Aber Sie möchten vielleicht testen Sie direkt, ob das Letzte Kind ist ein text-Knoten:

1. Für die Lesbarkeit von stylesheet-Logik
2. Falls das element andere Kinder neben Elementen und text: z.B. Kommentare oder processing instructions
3. Falls das element keine Kinder hat

Vielleicht kennen Sie den letzteren beiden wird nie auftreten, in Ihrem Fall (aber bei deiner Frage würde ich vermuten, dass die #3 könnte). Oder vielleicht denken Sie so, aber nicht sicher sind, oder vielleicht haben Sie noch nicht nachgedacht. In jedem Fall ist es sicherer, testen Sie direkt, was Sie wirklich wollen zu wissen:

     test="node()[last()]/self::text()"

Somit, aufbauend auf @Dimitre Beispiel-code und Eingabe, wird die folgende XML-Eingabe:

<root>
   <foo>some text <bar/> and maybe some more</foo>
   <foo>some text <bar/> and a pi: <?foopi param=yes?></foo>
   <foo>some text <bar/> and a comment: <!-- baz --></foo>
   <foo>some text and an element: <bar /></foo>
   <foo noChildren="true" />
</root>

Mit dieser XSLT-Vorlage:

   <xsl:template match="foo">
      <xsl:choose>
         <xsl:when test="node()[last()]/self::text()">
            <xsl:text>text at the end;&#10;</xsl:text>
         </xsl:when>
         <xsl:when test="node()[last()]/self::*">
            <xsl:text>element at the end;&#10;</xsl:text>
         </xsl:when>
         <xsl:otherwise>
            <xsl:text>neither text nor element child at the end;&#10;</xsl:text>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>

ergibt:

   text at the end;
   neither text nor element child at the end;
   neither text nor element child at the end;
   element at the end;
   neither text nor element child at the end;