XSLT: Wie bekomme index der position bestimmter nodes in alle childs kombiniert

Betrachten Sie das folgende XML:

<root>
    <a>
        <pos>
            <c val="abc"></c>
            <c val="def"></c>
            <c val="ghi"></c>
            <c val="jkl"></c>
            <c val="mno"></c>
        </pos>
        <b>
            <c></c>
        </b>
        <b>
            <c></c>
            <d>here</d>
        </b>
        <b>
            <e>and</e>
            <c></c>
            <d>for</d>
        </b>
        <b>
            <c></c>
            <c></c>
            <d>also</d>
        </b>
    </a>
    <a>
        <pos>
            <c val="pqr"></c>
            <c val="stu"></c>
            <c val="vwx"></c>
            <c val="yz"></c>
        </pos>
        <b>
            <c></c>
            <d>what</d>
        </b>
        <b>
            <c></c>
        </b>
        <b>
            <d>how</d>
        </b>
        <b>
            <c></c>
            <d>where</d>
            <c></c>
        </b>
    </a>
</root>

Nun in meine Ausgabe, wenn ich auch eine <c></c> innerhalb einer b ich benötigen, um den entsprechenden Wert des val Attribut eines <c></c> von der <pos></pos> Knoten. Vom entsprechenden Wert, den ich meine, der index der Knoten c innen pos sollte der gleiche sein wie der index der c in allen b Knoten kombiniert.

Die gewünschte Ausgabe:

<start>
    <level>
        abc
    </level>
    <level>
        def
        here
    </level>
    <level>
        and
        ghi
        for
    </level>
    <level>
        jkl
        mno
        also
    </level>
<start>


<start>
    <level>
        pqr
        what
    </level>
    <level>
        stu
    </level>
    <level>
        how
    </level>
    <level>
        vwx
        where
        yz
    </level>
 </start>

Versuchte ich es mit der folgenden XSL:

<xsl:template match="root">
    <star>
        <xsl:apply-templates select="a"/>
    </start>
</xsl:template>
<xsl:template match="a">
    <xsl:apply-templates select="b"/>
</xsl:template>
<xsl:template match="b">
    <level>
      <xsl:for-each select="*">
          <xsl:choose>
            <xsl:when test="name() = 'd'">
                <xsl:value-of select="."/>
            </xsl:when>
            <xsl:when test="name() = 'e'">
                <xsl:value-of select="."/>
            </xsl:when>
            <xsl:when test="name() = 'c'">
                <xsl:variable name="posCount">
                    <!-- I don't know what to do here -->
                </xsl:valiable>
                <xsl:for-each select="ancestor::a[1]/pos">
                    <xsl:for-each select="c[position() = $posCount]">
                          <xsl:value-of select="@val"/>
                    </xsl:for-each>
                </xsl:for-each>

            </xsl:when>
          </xsl:choose>
      </xsl:for-each>
    </level>
</xsl:template>

Was ich tun muss, ist irgendwie die position, die Anzahl der einzelnen c im inneren alle bs kombiniert und dann den Wert von val Attribut entsprechend positioniert c von innen pos.

Wie kann ich Vorgehen, um es zu tun?

Hinweis: ich bin mit XSLT 1.0

Thnx im vorraus!!!!!

InformationsquelleAutor Surender Thakran | 2014-03-01

Die index-Nummer, die Sie suchen, können erreicht werden ganz einfach mit Hilfe des xsl:number element. Zum Beispiel:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="root">
    <root>
        <xsl:apply-templates select="a"/>
    </root>
</xsl:template>

<xsl:template match="a">
    <start>
        <xsl:apply-templates select="b"/>
    </start>
</xsl:template>

<xsl:template match="b">
    <level>
        <xsl:text>&#10;</xsl:text>
        <xsl:apply-templates select="*"/>
    </level>
</xsl:template>

<xsl:template match="d|e">
    <xsl:value-of select="."/>
    <xsl:text>&#10;</xsl:text>
</xsl:template>

<xsl:template match="b/c">
<xsl:variable name="i">
    <xsl:number count="b/c" from="a" level="any" />
</xsl:variable>
    <xsl:value-of select="ancestor::a/pos/c[number($i)]/@val"/>
    <xsl:text>&#10;</xsl:text>
</xsl:template>

</xsl:stylesheet>

Hinweise:

1. Ich habe eine root element, um die Ausgabe zu machen, eine gültige XML;

2. Es wäre am besten eine Schlüssel zu bekommen, wird der entsprechende Wert aus pos/c.

In xsl:number sollte ich nicht schreiben from="ancestor::a[1]" statt?
Nein, warum? Ist es nicht so, wie ich es schrieb?
Ja, es hat perfekt funktioniert. Ich habe nur versucht zu verstehen, wie es funktionierte? Hat die from Attribut implizit leitet sich der erste Vorfahr a?
Lesen Sie mehr über es hier: w3.org/TR/xslt#number

InformationsquelleAutor michael.hor257k

Ich denke, dies zu tun:

<xsl:stylesheet  version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>



<xsl:template match="/">
    <levels>
        <xsl:apply-templates select="//b[c]"/>
    </levels>
</xsl:template>

<xsl:template match="b">
    <level>
        <xsl:apply-templates />
    </level>
</xsl:template>

<xsl:template match="c">
    <xsl:variable name="pos" select="count(preceding::b/c) + count(preceding-sibling::c) + 1"/>
    <xsl:value-of select="//pos/c[$pos]/@val"/>
</xsl:template>

</xsl:stylesheet>

während count(preceding-sibling::c) richtig ist, count(preceding::b/c) wird mir Anzahl der b/c - pair-Mädchen in der ganzen xml-anstatt im aktuellen a Knoten. Es können mehrere a Knoten in der root aber ich will position index ein c nur in seiner aktuellen a Knoten.

InformationsquelleAutor Lingamurthy CS

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.