xsl:variable als xpath-Wert für andere xsl-tag

Habe ich Probleme mit xsl:variable. Ich will erstellen Sie eine variable mit einem Wert, der abhängig vom Wert eines anderen XML-Knoten-Attribut. Diese gute Arbeit. Aber wenn ich versuche, erstellen Sie eine variable mit einem string-Wert, der darstellt, XPath, es funktioniert einfach nicht, wenn ich versuche, es zu benutzen, da XPath in einem späteren XSL-tag.

<xsl:variable name="test">  
  <xsl:choose>
    <xsl:when test="node/@attribute=0">string/represent/xpath/1</xsl:when>
    <xsl:otherwise>string/represent/xpath/2</xsl:otherwise>
  </xsl:choose>       
</xsl:variable>                 
<xsl:for-each select="$test">
  [...]
</xsl:for-each>

Habe ich versucht:
Verwendung von xsl-variable in xsl-wenn
und
Probleme mit xsl:for-each-Auswahl mit xsl:variable. Aber mit keine Ergebnisse.

InformationsquelleAutor der Frage igor milla | 2011-01-13

  1. 10

    Wenn diese Pfad im Voraus bekannt sind, wie in diesem Fall, dann können Sie verwenden:

    <xsl:variable name="vCondition" select="node/@attribute = 0"/>
<xsl:variable name="test" select="actual/path[$vCondition] |
                                  other/actual/path[not($vCondition)]"/>

    InformationsquelleAutor der Antwort

  2. 10

    Dynamische Auswertung eines XPath-Ausdrucks ist in der Regel nicht unterstützt XSLT (sowohl 1.0 und 2.0), aber:

    Können wir implementieren eine eher Allgemeine dynamische XPath evaluator, wenn wir nur einschränken jedem Pfad zu einem element name:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:param name="inputId" select="'param/yyy/value'"/>

 <xsl:variable name="vXpathExpression"
  select="concat('root/meta/url_params/', $inputId)"/>

 <xsl:template match="/">
  <xsl:value-of select="$vXpathExpression"/>: <xsl:text/>

  <xsl:call-template name="getNodeValue">
    <xsl:with-param name="pExpression"
         select="$vXpathExpression"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="getNodeValue">
   <xsl:param name="pExpression"/>
   <xsl:param name="pCurrentNode" select="."/>

   <xsl:choose>
    <xsl:when test="not(contains($pExpression, '/'))">
      <xsl:value-of select="$pCurrentNode/*[name()=$pExpression]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="getNodeValue">
        <xsl:with-param name="pExpression"
          select="substring-after($pExpression, '/')"/>
        <xsl:with-param name="pCurrentNode" select=
        "$pCurrentNode/*[name()=substring-before($pExpression, '/')]"/>
      </xsl:call-template>
    </xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

    wenn diese transformation, angewandt auf das XML-Dokument:

    <root>
  <meta>
    <url_params>
      <param>
        <xxx>
          <value>5</value>
        </xxx>
      </param>
      <param>
        <yyy>
          <value>8</value>
        </yyy>
      </param>
    </url_params>
  </meta>
</root>

    die wollten, das richtige Ergebnis produziert wird:

    root/meta/url_params/param/yyy/value: 8

    InformationsquelleAutor der Antwort Dimitre Novatchev

  3. 0

    Dies ist nicht nativ möglich, die in XSLT 1.0, aber können Sie eine Erweiterungs-Bibliothek wie dyn:

    http://www.exslt.org/dyn/functions/evaluate/dyn.evaluate.html

    Den dyn:evaluate Funktion wertet einen string als XPath-Ausdruck.

    InformationsquelleAutor der Antwort Zkoh

Schreibe einen Kommentar