Groovy Einfache JSON-array-generator

Brauche ich zum erstellen eines einfachen JSON-array in JSON aber in der Schleife überschreibt er den ersten Wert während jeder iteration.

def jsonBuilder = new groovy.json.JsonBuilder()
contact.each {
            jsonBuilder.contact(
                    FirstName:  it.getFirstName(),
                    LastName:  it.getLastName(),
                    Title: it.getTitle(),       
            )
    }

Es gibt nur die einfache JSON und überschreibt den Wert jeder iteration und behält nur das Letzte. Was ist die syntax für die Konstruktion eines JSON-Array in groovy?

InformationsquelleAutor user2093576 | 2015-01-29

  1. 13

    Trick ist collect aus der Liste der Kontakte. Vorausgesetzt, die Struktur der contract Liste ist als unten, Folgen dem Weg jsonBuilder unten verwendet wird.

    def contact = [ 
    [ getFirstName : { 'A' }, getLastName : { 'B' }, getTitle : { 'C' } ], 
    [ getFirstName : { 'D' }, getLastName : { 'E' }, getTitle : { 'F' } ], 
    [ getFirstName : { 'G' }, getLastName : { 'H' }, getTitle : { 'I' } ]     
]

def jsonBuilder = new groovy.json.JsonBuilder()

jsonBuilder {
    contacts contact.collect { 
        [ 
            FirstName: it.getFirstName(), 
            LastName: it.getLastName(), 
            Title: it.getTitle() 
        ] 
    }
}

println jsonBuilder.toPrettyString()


//Prints
{
    "contacts": [
        {
            "FirstName": "A",
            "LastName": "B",
            "Title": "C"
        },
        {
            "FirstName": "D",
            "LastName": "E",
            "Title": "F"
        },
        {
            "FirstName": "G",
            "LastName": "H",
            "Title": "I"
        }
    ]
}

    Wenn Sie auf der Suche für ein JSONArray, anstatt ein JSONObject als Letzte Stuktur, dann verwenden:

    jsonBuilder(
    contact.collect { 
        [ 
            FirstName: it.getFirstName(), 
            LastName: it.getLastName(), 
            Title: it.getTitle() 
        ]
    }
)

//OP
[
    {
        "FirstName": "A",
        "LastName": "B",
        "Title": "C"
    },
    {
        "FirstName": "D",
        "LastName": "E",
        "Title": "F"
    },
    {
        "FirstName": "G",
        "LastName": "H",
        "Title": "I"
    }
]

    Ist es nicht sinnvoll, wenn aber Struktur benötigt, wie unten

    [
    {
        "contact": {
            "FirstName": "A",
            "LastName": "B",
            "Title": "C"
        }
    },
    {
        "contact": {
            "FirstName": "D",
            "LastName": "E",
            "Title": "F"
        }
    },
    {
        "contact": {
            "FirstName": "G",
            "LastName": "H",
            "Title": "I"
        }
    }
]

    dann verwenden

    jsonBuilder(
    contact.collect { 
        [ 
            contact : [ 
                FirstName: it.getFirstName(), 
                LastName: it.getLastName(), 
                Title: it.getTitle() 
            ] 
        ]
    }
)
    Dank pal, aber für jetzt bin ich mit import net.sf.json.JSONObject import net.sf.json.JSONArray JSONObject obj = new JSONObject(); JSONArray Liste = new JSONArray(); Und dieser löst den Zweck ..

    InformationsquelleAutor dmahapatro

  2. 2

    Mit JsonBuilder funktioniert nicht wirklich gut mit .each; ich habe collect für diese Art der Sache. Unten ist ein Beispiel für diese Arbeit sollte für Ihren Fall:

    static class Contact {
    String firstName
    String lastName
    String title
}

Contact c1 = new Contact(firstName: "Tom", "lastName": "Potter", title: "Mr")
Contact c2 = new Contact(firstName: "Ryan", "lastName": "Olson", title: "Mr")

List<Contact> contactList = [c1,c2]
def jsonBuilder = new groovy.json.JsonBuilder()

jsonBuilder {
   contacts(contacts.collect{[firstName: it.firstName, lastName: it.lastName, title: it.title]})
}
println jsonBuilder.toPrettyString()

    Das Ergebnis dies ist:

    {
    "contacts": [
        {
            "firstName": "Tom"
        },
        {
            "firstName": "Ryan"
        }
    ]
}

    InformationsquelleAutor Durandal

  3. 1

    Nicht direkt die Frage beantwortet (es war über JsonBuilder), aber wenn das Ziel ist, erhalten ein JSON-Ausgabe eine Zeichenfolge, die es getan werden kann in der folgenden Weise (Teil des code entliehen @dmahapatro Antwort), mit JsonOutput:

    import groovy.json.JsonOutput

def contacts = [ 
    [ getFirstName : { 'A' }, getLastName : { 'B' }, getTitle : { 'C' } ], 
    [ getFirstName : { 'D' }, getLastName : { 'E' }, getTitle : { 'F' } ], 
    [ getFirstName : { 'G' }, getLastName : { 'H' }, getTitle : { 'I' } ]     
]

def list = ['contacts': contacts.collect { [FirstName: it.getFirstName(), LastName: it.getLastName(), Title: it.getTitle()] } ]

print JsonOutput.prettyPrint(JsonOutput.toJson(list))

    InformationsquelleAutor Opal

Schreibe einen Kommentar