Erstellung von groovy-Klassen

Ich versuche zu lernen, wie das erstellen von einfachen groovy-Klassen, die nicht Domänen-Klassen. Ich möchte einen Satz von Klassen (und deren Objekte) in meiner software, aber Sie haben nicht die Absicht, Speicherung in einer Datenbank. Speziell habe ich eine Frage über, wie man erstellen Sie eine Klasse, die hat eine Eigenschaft, die eine Liste von einer zweiten Klasse. wie diese:

class oParent{
    def fName
    def lName
    def listOfChildren
}
class oChild{
    def propertyOne
    def propertyTwo
}

So, in diesem Beispiel, kann ich ein Objekt erstellen, das von jedem so:

def p = new oParent();
def cOne = new oChild();
def cTwo = new oChild();

p.fName ="SomeName"
p.lName ="some Last Name"

cOne.propertyOne = "a"
cOne.propertyTwo = "b"

cTwo.propertyOne = "c"
cTwo.propertyTwo = "d"

So, wie füge ich jedem der die Kinder Objekte (Kegel und cTwo) auf das parent-Objekt p). Einmal Hinzugefügt, wie würde ich dann durchqueren Sie die übergeordnete Klasse die Kinder von Eigentum und, zum Beispiel, drucken Sie alle propertyTwo Eigenschaften für alle Kinder der Klassen?

  • einen bestimmten Grund für den down-vote?
  • Vielleicht wegen der verrückten Klasse und Instanz-Namen. Art der kleinlichen Grund, downvote, aber man weiß ja nie.
InformationsquelleAutor jason | 2012-09-29
  1. 5

    Hier eine kommentierte version des Codes mit einige Vorschläge für änderungen:

    //1) Class names start with a Capital Letter
class Parent {

  //2) If you know the type of something, use it rather than def
  String fName
  String lName

  //3) better name and type
  List<Child> children = []

  //4) A utility method for adding a child (as it is a standard operation)
  void addChild( Child c ) {
    children << c
  }

  //5) A helper method so we can do `parent << child` as a shortcut
  Parent leftShift( Child c ) {
    addChild( c )
    this
  }

  //6) Nice String representation of the object
  String toString() {
    "$fName, $lName $children"
  }
}

//See 1)
class Child{

  //See 2)
  String propertyOne
  String propertyTwo

  //See 6)
  String toString() {
    "($propertyOne $propertyTwo)"
  }
}

//Create the object and set its props in a single statement
Parent p = new Parent( fName: 'SomeName', lName:'some Last Name' )

//Same for the child objects
Child cOne = new Child( propertyOne: 'a', propertyTwo: 'b' )
Child cTwo = new Child( propertyOne: 'c', propertyTwo: 'd' )

//Add cOne and cTwo to p using the leftShift helper in (5) above
p << cOne << cTwo

//prints "SomeName, some Last Name [(a b), (c d)]"
println p

    Dann können Sie dies tun:

    println p.children.propertyTwo //prints "[b, d]"

    Oder so:

    p.children.propertyTwo.each { println it } //prints b and d on separate lines

    Oder, in der Tat ist diese:

    p.children.each { println it.propertyTwo } //As above
    InformationsquelleAutor tim_yates
  2. 1

    gut, es stellte sich heraus, ziemlich einfach, es sei denn, ich mache es falsch. hier ist, wie ich es gemacht habe:

    class oParent{
   def fName
   def lName
   def listOfChildren = []
}

class oChild{
   def propertyOne
   def propertyTwo
}

def p = new oParent();
def cOne = new oChild();
def cTwo = new oChild();

p.fName ="SomeName"
p.lName ="some Last Name"

cOne.propertyOne = "a"
cOne.propertyTwo = "b"

cTwo.propertyOne = "c"
cTwo.propertyTwo = "d"

p.listOfChildren.add(cOne)
p.listOfChildren.add(cTwo)

    Ich kann die Iteration so:

    p.listOfChildren.each{ foo->
    log.debug(foo.propertyOne)
}
    • Sind Sie richtig. Es ist eher typisch für name it Kinder eher als listOfChildren, aber die Idee ist die gleiche.
    • Es wäre auch eher typisch, um oParent (die in der Regel genannt werden 'Eltern'), ein addChild-Methode statt den Zugriff auf die Eltern-Liste direkt.
    InformationsquelleAutor jason
Schreibe einen Kommentar