Excel-VBA-makro zum generieren einer Liste von möglichen Kombinationen

Können Sie die folgenden verwenden, um cross-join von zwei verschiedenen Bereichen. Es behandelt Bereiche jeder Größe und schreiben Sie die crossjoined Kombinationen auf eine target-Platte, die Sie angeben.

In dem folgenden Beispiel, ich habe zwei benannte Bereiche: newValues und fixedValues. Diese beiden Bereiche werden auf Sheet1. Ich habe dann in einer Schleife durch die Bereiche und schreiben Sie alle Kombinationen Sheet2.

Sub CrossJoinMyRanges()
    Dim ws As Worksheet
    Dim newValues As Range
    Dim cell As Range

    Set ws = ThisWorkbook.Sheets("Sheet1")
    Set newValues = ws.Range("newValues")

    ' loop through the new values
    For Each cell In newValues
        Call ReplaceMe(cell.Value, ws)
    Next cell
End Sub

Sub ReplaceMe(replacement As String, ws As Worksheet)
    Dim fixedValues As Range
    Dim cell As Range

    Set fixedValues = ws.Range("fixedValues")

    ' outer loop through fixedValues
    For Each cell In fixedValues
        Call PrintReplacedValues(cell.Row, replacement)
    Next cell
End Sub

Sub PrintReplacedValues(rowNumber As Long, replacement As String)
    Dim wb As Workbook
    Dim src As Worksheet
    Dim tgt As Worksheet
    Dim fixedValues As Range
    Dim cell As Range
    Dim printMe As String
    Dim x As Long, y As Long

    Set wb = ThisWorkbook
    Set src = wb.Sheets("Sheet1")
    Set tgt = wb.Sheets("Sheet2")
    Set fixedValues = src.Range("fixedValues")
    y = 1
    x = tgt.Range("A" & tgt.Rows.Count).End(xlUp).Row + 1

    ' inner loop through fixed values
    For Each cell In fixedValues
        ' replace the fixed value with the replacement
        ' if the loops intersect
        If cell.Row = rowNumber Then
            printMe = replacement
        Else
        ' otherwise keep the fixed value
            printMe = cell
        End If
        ' write to the target sheet
        tgt.Cells(x, y).Value = printMe
        y = y + 1
    Next cell
End Sub

Es gibt ein paar ähnliche Fragen mit alternativen Lösungen, die Sie können auch, wenn mein Ansatz ist nicht, was Sie waren nach:

Excel vba zu erstellen, jede mögliche Kombination von einer Reihe

Wie bekomme ich das kartesische Produkt wie die Spalten in excel?