Wie Bearbeite ich BLOBs (mit JSON) in einem Oracle SQL-Developer?

Wenn Sie eine Abfrage ausführen, die in SQL Developer 3.1 (und wahrscheinlich auch frühere Versionen), gibt eine BLOB, können Sie auch einen Doppelklick auf dem jeweiligen BLOB, der Sie interessiert, wo werden Sie aufgefordert, entweder zu versuchen, das senden der Daten zu einem externen editor oder versuchen, die built-in-SQL-Developer display-Steuerung versuchen, die Daten zu interpretieren, als ein Bild oder als text. Ihre JSON-Daten wahrscheinlich korrekt angezeigt, wenn Sie wählen Sie die option "text".

Wenn Sie möchten, um die Daten zu ändern, jedoch sind Sie gehen zu müssen, um die Ausgabe eines UPDATE um tatsächlich die Daten. SQL Developer nicht über die Funktionalität, um direkt Bearbeiten Sie die LOB-Daten. Zum Beispiel

UPDATE table_name
   SET column_with_json_data = 
          utl_i18n.string_to_raw( '{"foo": {"id": "1", "value": "2"}}' )
 WHERE primary_key = <<some value>>

aktualisiert die angegebene Zeile mit der neuen JSON-Daten verschlüsselt mit dem Datenbank-Zeichensatz. Wenn Sie die Daten speichern möchten, die in einigen anderen Zeichensatz, string_to_raw nimmt einen optionalen zweiten parameter, der angibt, den Zeichensatz. Also, wenn Sie wollen, speichern Sie die Daten unter Verwendung des UTF-8-Zeichensatz, solltest du so etwas tun

UPDATE table_name
   SET column_with_json_data = 
          utl_i18n.string_to_raw( '{"foo": {"id": "1", "value": "2"}}', 'AL32UTF8' )
 WHERE primary_key = <<some value>>

Natürlich, da JSON-Daten ist Text, Sie wären weit besser dran, die Speicherung der Daten in einem CLOB -, die entworfen, zu speichern, character large objects. Dann SQL-Entwickler (und andere tools) könnte nur der text angezeigt, anstatt dass Sie wählen Sie das Ergebnis und nehmen Sie dann weitere Aktionen in text konvertieren. Und Sie würden nicht haben, die Daten zu konvertieren, um RAW zur Aktualisierung der Daten in der Datenbank.

Wenn die Daten zu lang für string_to_raw zu handhaben (welche, hängt vom Zeichensatz und der Daten, sondern wird jederzeit auftreten, die RAW Daten überschreitet 2000 Byte), können Sie speichern die Daten in einer CLOB und dann konvertieren, die in eine BLOB, die Sie verwenden, um die Tabelle zu aktualisieren. Das ist ein bisschen komplexer, aber es ist flexibler. In diesem Beispiel habe ich die Polsterung der JSON-Daten zu 3200 Zeichen, die mit einem '*'-- offensichtlich ist die test-Daten ist nicht mehr gültiges JSON, aber das ist nicht wichtig für die Zwecke dieser Frage.

declare
  l_blob        blob;
  l_clob        clob := rpad('{"foo": {"id": "1", "value": "2", "name": "bob"}}',3200,'*');
  l_amt         integer := dbms_lob.lobmaxsize;
  l_dest_offset integer := 1;
  l_src_offset  integer := 1;
  l_csid        integer := dbms_lob.default_csid;
  l_ctx         integer := dbms_lob.default_lang_ctx;
  l_warn        integer;
begin
  dbms_lob.createTemporary( l_blob, false );
  dbms_lob.convertToBlob( l_blob,
                          l_clob,
                          l_amt,
                          l_dest_offset,
                          l_src_offset,
                          l_csid,
                          l_ctx,
                          l_warn );

  -- You'll want to add a WHERE clause as well
  update json_data
     set data = l_blob;

  dbms_lob.freeTemporary( l_blob );
end;
/