Wie pausiere ich VBS-Skript, während die Ordner gelöscht?

Schreibe ich ein VBScript für SyncBack (backup utility), in denen ich bin das löschen von alten Versionen einer Sicherung.

    '' # if current version is greater than the total allowed number of versions,
    '' # delete the oldest folder
    If versionNumber > totalVersions Then
        delDirNum = versionNumber - totalVersions
        If delDirNum > 0 Then
            DelFoldername = containerFileOrFolder & "\" & delDirNum & "_"
               '' " # Ignore this line SO Prettify doesn't do VB very well. 
            If fso.FolderExists(DelFoldername) = True Then
                WScript.Echo "Deleting: <" & DelFoldername & ">"
                Set oFolder = objFileSystem.GetFolder(DelFoldername)
                oFolder.Delete()
                WScript.Sleep 2000
                If fso.FolderExists(DelFoldername) = False Then
                    WScript.Echo "Deleted <" & DelFoldername & "> successfully"
                Else
                    WScript.Echo "Could not delete <" & DelFoldername & ">"
                End If
            End If
        End If
    End If

Jedoch, gelegentlich wird der Ordner (enthält die alten backup), die ich versuche zu löschen, dauert länger als die 2 Sekunden mit WScript.Schlaf-2000 zu entfernen und ich Frage mich, ob es einen Weg, um das Skript warten, bis der Ordner gelöscht wurde, bevor es druckt "Gelöscht <Ordnername> erfolgreich".

Idealerweise würde ich gerne so etwas wie:

While oFolder.IsDeleting() Then
    WScript.Echo "Still deleting..."
    WScript.Sleep 2000
Loop

Aber ich bin gut bewusst, dass das wahrscheinlich nicht der Fall sein wird.

Was ist der Typ von objFileSystem?
FileSystemObject: msdn.microsoft.com/en-us/library/z9ty6h50(VS.85).aspx

InformationsquelleAutor Jon | 2009-11-20

vbscript

1

Schleife Schlaf mit Zählwerk Hinweis: übernimmt CScript host, der die "immer Noch Löschen" - Nachricht ein wenig mehr palettable. Die Verzögerung ist die im Beispiel 30 Sekunden.
```
Dim loopCount : loopCount = 0
WScript.StdOut.Write "Deleting ."
Do While fso.FolderExists(DelFoldername) And loopCount < 30
   WScript.Sleep 1000
   WScript.StdOut.Write "."
   loopCount = loopCount + 1
Loop
WScript.StdOut.Write vbCrLf
If fso.FolderExists(DelFolderName) Then
   '' # Do stuff due to failure.
End If
```
- Gibt es wirklich keinen anderen Weg, dies zu tun, andere als zu erraten, die maximale Zeit, die es dauern würde, um einen Ordner zu löschen und verwenden, die als die Grenze?
- Sie waren besorgt über das warten auf unbestimmte Zeit, also muss es eine Grenze. So wird die Frage "Wie bestimme ich, was ist die maximale Menge an Zeit zu warten, bis ich sicher sein kann, dass Sie den Ordner löschen, endgültig gescheitert?". Dies ist eine Unmögliche Frage zu beantworten, aber wir können einige gemeinsame Sinn-und ändern Sie es auf "was ist die maximale günstige Höhe der Zeit...". Mein Rat, verwenden Sie 300 Sekunden, und dann abwarten und sehen, wie viele Male, dass sich herausstellt, deckt Sie nicht, mein Geld ist auf Keine.
- Mein Anliegen war, über das warten auf unbestimmte Zeit in dem Fall, dass der Ordner nicht gelöscht werden konnte. @Tester101 die Aufnahme von "On Error..." ist hilfreich, da die, die dafür sorgen sollten, zu warten, ist nicht unendlich in dem Fall, dass ein Fehler tritt auf beim löschen des Ordner und seinen Inhalt. Abgesehen davon, dass ich wahrscheinlich haben, um eine Grenze, wie du vorgeschlagen hast.
- Ich denke, es ist ein Unterschied in der Herangehensweise, um administrative Skripte als typische Entwickler der Praxis. Ich möchte vermeiden On Error Resume Next wie die Pest steckte es Weg und eine Zeile code geschützt, indem es in eine kleine Funktion, sicherlich nicht herrschen über irgendein übrige code. In einem solchen Fall gäbe es keine Angst, dass ein Fehler eine unendliche Schleife verursachen, denn ein Fehler würde das tun, was Ihr wohl zu tun.
- Ich habe eine Warnung an meine post. Ich hoffe, es wird machen Sie fühlen sich wohler mit meiner Verwendung von " On Error Resume Next.
InformationsquelleAutor AnthonyWJones
3
```
While fso.FolderExists(DelFoldername)
   WScript.Echo "Still deleting"
   WScript.Sleep 1000
Wend
```
- Das ist, was ich vorhabe, aber was, wenn das script kann nicht den Ordner löschen? Endlosschleife?
- Wenn Sie On Error Resume wird es, wenn nicht, wird der Fehler automatisch abgebrochen wird.
InformationsquelleAutor C. Ross
2

Konnten Sie das löschen in seine eigene Funktion, und fügen Sie ein timeout. also wenn der Ordner nicht gelöscht werden in einer angemessenen Höhe der Zeit, liefert die Funktion löschen, ohne die Ordner. So etwas wie dieses:
```
Function DeleteFolder(Folder, Timeout)
'Folder is the full file path of the folder
'Timeout is the amount of time to wait for the folder to be deleted (in seconds).
    On Error Resume Next
    Set fso = CreateObject("Scripting.FileSystemObject")
    If fso.FolderExists(Folder) Then
        fso.DeleteFolder Folder, True
        start = Now()
        do while fso.FolderExists(Folder) AND DateDiff("s",start,Now()) < Timeout
            wscript.sleep 1000
        Loop
    End If
    If fso.FolderExists(Folder) Then
        DeleteFolder = False
    Else 
        DeleteFolder = True
    End If
End Function 
```
Dann rufen Sie die Funktion wie folgt
```
If DeleteFolder("C:\New Folder", 5) Then
    Wscript.Echo "Folder Deleted"
Else
    Wscript.Echo "Folder could NOT be deleted" 
End If
```
WARNUNG: die Verwendung von On Error Resume Next ist nicht zu empfehlen.

Dieser Befehl bewirkt, dass alle Fehler ignoriert werden, und sollten nur verwendet werden, unter Aufsicht von Erwachsenen.

Nebenwirkungen können einschließen: Merkwürdige Fehler in andere Teile des Skriptes, unerwarteten Skript-Aktion, Kopfschmerzen, Schwindel, Verwirrung, Wut, oder einen plötzlichen Drang zu fluchen. In seltenen Fällen ist dieser Befehl wurde bekannt, dass Blutungen aus Augen und Ohren. Mit diesem Befehl führen kann, um die Haare und den Verlust des Arbeitsplatzes.
- Warum würden Sie verwenden On Error Resume Next ?
- Weil ich kümmern sich nicht über Fehler in dieser Funktion, ich habe nur darauf wenn der Ordner gelöscht wurde oder nicht. Sollte das Skript Abbrechen, wenn es auf einen Fehler stößt? Aus der Betrachtung der OP-code-ich würde sagen, dass Sie nicht möchten, dass das Skript zu stoppen, Sie wollen einfach nur wissen, ob der Ordner gelöscht wurde oder nicht.
- Gibt es wirklich keinen anderen Weg, dies zu tun, andere als zu erraten, die maximale Zeit, die es dauern würde, um einen Ordner zu löschen und verwenden, die als die Grenze?
- Sind Sie sicher, dass, wenn etwaige Fehler passiert, gibt die Funktion den entsprechenden Wert True oder False in allen Lebenslagen?
- Ich kann mir nicht vorstellen, dass es eine Möglichkeit zu wissen, wie lange Sie einen Ordner zum löschen, andere löschen, eine Reihe von Ordnern von der gleichen Größe mit der gleichen Datei-Typen von der gleichen Größe und Zeit. Dann könnten Sie im Durchschnitt und verwenden, als das timeout, kurz, ich kann nicht denken, ein Weg, zu wissen, wie lange der Vorgang dauern soll.
- Ich bin mir nicht sicher, ob ich verstehe, warum du fragst. Kann ich sicher sein, dass diese Funktion funktioniert in jeder situation ein? Nein. Aber ich bin mir ziemlich sicher, dass nach dem timeout verstreicht, wenn der Ordner noch existiert, wird false zurückgegeben. Ich denke, ich könnte setup und testen Sie jede mögliche situation, aber wer hat die Zeit? Ich würde denken, dass fast niemand weiß, ob es code funktioniert in jeder situation.
- Ich fühle mich jetzt viel besser. 😉
InformationsquelleAutor Tester101
0

Warum nicht einfach überprüfen, um zu sehen, wenn der Ordner noch vorhanden ist, und beenden, sobald es Weg ist?

' Tun
'Wenn Ordner nicht vorhanden ist, beenden Sie Tun
'Schleife

InformationsquelleAutor johny why

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.