Wie Streifen aus url-Variablen

Ich habe eine url.LoginID, und ich möchte, um es zu entfernen aus der Adressleiste, wenn der Benutzer klickt auf den link, um sich einzuloggen. Es hat ein Lesezeichen, es kann nicht ein Formular Absenden.

Q: Wie kann ich die entfernen ?LoginID vom Index.cfm?LoginID=XYZ&AssignmentID=123

Es ist wahrscheinlich etwas entlang der Linien von:

<cflocation url="#cgi.SCRIPT_NAME#?#cgi.QUERY_STRING#" addtoken="no">

InformationsquelleAutor Phillip Senn | 2011-01-15

coldfusion

20

Sieht aus wie Sie sind auf dem richtigen Weg.

Wenn loginID ist die einzige Sache, die in den query-string können Sie einfach cflocation an die Zielseite ohne den query-string.

Wenn es andere Daten in der Abfrage-string, dann können Sie etwas wie das hier tun:
```
<cfset q = reReplaceNoCase(cgi.query_string, "LOGINID=[^&]+&?", "")>
<cflocation url="#cgi.SCRIPT_NAME#?#q#">
```
Dies ist im wesentlichen entfernt loginid und alles, bis entweder der en der string oder die nächste URL-variable.
- +1 für die ordentliche regex - ich wusste, es war ein eleganter Weg, es zu tun 🙂
- +1 für klüger regex als meine version, die ist nicht so zuverlässig.
- +1. Auch geändert reReplace() -> reReplaceNoCase()
- Guter Fang, @orangepips. Ich dachte, dass alle struct-Tasten sind groß, und vergessen den query-string kann nicht sein.
- Vergessen Sie nicht addtoken="no"
- +1 für die elegante und einfache Lösung. Ich war auf der Suche für einfach, code zu verwalten, als die Schleife und listappend routine, die ich mache. Ich fand keine einfachere Lösungen, bis ich fügte hinzu, stackoverflow, um meine google-Suche und fand diese Seite als die Nummer eins Ergebnis. Genial!
InformationsquelleAutor Ben Doom

Als sonst, es gibt bereits eine UDF, die jemand geschrieben hat, stehen auf CFLIB: queryStringDeleteVar

Können Sie dann tun, wie so

<cflocation 
    url="#cgi.SCRIPT_NAME#?#queryStringDeleteVar("LoginID",cgi.QUERY_STRING)#" 
    addtoken="no"
>

CGI.QUERY_STRING ist eigentlich der Standardwert für das zweite argument, also wird das genauso gut funktionieren

<cflocation 
    url="#cgi.SCRIPT_NAME#?#queryStringDeleteVar("LoginID")#" 
    addtoken="no"
>

Hier ist der code für queryStringDeleteVar:

<cfscript>
/**
 * Deletes a var from a query string.
 * Idea for multiple args from Michael Stephenson ([email protected])
 * 
 * @param variable      A variable, or a list of variables, to delete from the query string. 
 * @param qs      Query string to modify. Defaults to CGI.QUERY_STRING. 
 * @return Returns a string. 
 * @author Nathan Dintenfass ([email protected]@changemedia.com) 
 * @version 1.1, February 24, 2002 
 */
function queryStringDeleteVar(variable){
    //var to hold the final string
    var string = "";
    //vars for use in the loop, so we don't have to evaluate lists and arrays more than once
    var ii = 1;
    var thisVar = "";
    var thisIndex = "";
    var array = "";
    //if there is a second argument, use that as the query string, otherwise default to cgi.query_string
    var qs = cgi.query_string;
    if(arrayLen(arguments) GT 1)
        qs = arguments[2];
    //put the query string into an array for easier looping
    array = listToArray(qs,"&");        
    //now, loop over the array and rebuild the string
    for(ii = 1; ii lte arrayLen(array); ii = ii + 1){
        thisIndex = array[ii];
        thisVar = listFirst(thisIndex,"=");
        //if this is the var, edit it to the value, otherwise, just append
        if(not listFind(variable,thisVar))
            string = listAppend(string,thisIndex,"&");
    }
    //return the string
    return string;
}
</cfscript>

InformationsquelleAutor ale

Gibt es eine Reihe von Möglichkeiten, dies zu tun, hier ist eine Möglichkeit, mit Hilfe einer Liste-Schleife zum Lesen über die vorhandenen Parameter und überprüfen Sie die, die Sie wollen, zu ignorieren:

<cfset newParams = "" />

<cfloop list="#cgi.query_string#" delimiters="&" index="i">
    <cfif listFirst(i, "=") neq "loginID">
        <cfset newParams = listAppend(newParams, i, "&") />
    </cfif>
</cfloop>


<cflocation url="#cgi.script_name#?#newParams#" addtoken="no">

Hoffe, das hilft!

InformationsquelleAutor Ciaran Archer

2

Angenommen, Sie wollen nicht wirklich, um die zu entfernen ? zu halten, die URL gültig ist, so einfache regex arbeiten soll:
```
QUERY_STRING = ReReplaceNoCase(cgi.QUERY_STRING, "LoginID=.+\&", "");
```
BTW, ich bin mir nicht sicher, warum halten Sie LoginID in der URL, es kann unsicher sein Ansatz. Die Verwendung von Sitzungen, klingt wie eine bessere Idee.

Edit: Ben ' s regex ist besser, weil meine version ist so einfach, das "Essen" alle key=value Paare vor der letzten.

InformationsquelleAutor Sergii
1

Einfügen berühmte Zawinski zwei problem regex zitieren und anders lösen:
```
<cfset copy = duplicate(url)>
<cfset structDelete(copy, "loginid")>
<cfset entries = []>
<cfloop collection="#copy#" item="key">
    <cfset arrayAppend(entries, "#key#=#copy[key]#")>
</cfloop>
<cfoutput>#arrayToList(entries, "&")#</cfoutput>
```
- Gibt es einen Grund, warum man mit arrayAppend() und arrayToList() anstatt listAppend()?
- In Bezug auf Speicherverbrauch, array-Verkettung führt besser als Zeichenkette (d.h. Liste). Dieser link auf das string-literal-pool in java für ein wenig mehr Erklärung: xyzws.com/Javafaq/what-is-string-literal-pool/3
InformationsquelleAutor orangepips

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.