Wie zum extrahieren von Daten von SQL Server nach Excel mithilfe von vba?

Sub aa()

Dim conn As ADODB.Connection

    Dim rs As ADODB.Recordset
    Dim sConnString As String

    ' Create the connection string.
    sConnString = "Provider=SQLOLEDB;Data Source=INSTANCE\SQLEXPRESS;" & _
                  "Initial Catalog=Raja;" & _
                  "Integrated Security=SSPI;"

    ' Create the Connection and Recordset objects.
    Set conn = New ADODB.Connection
    Set rs = New ADODB.Recordset

    ' Open the connection and execute.
    conn.Open sConnString
    Set rs = conn.Execute("SELECT * FROM raja.dbo.saran")

    ' Check we have data.
    If Not rs.EOF Then
        ' Transfer result.
        Sheets(1).Range("A1").CopyFromRecordset rs
    ' Close the recordset
        rs.Close
    Else
        MsgBox "Error: No records returned.", vbCritical
    End If

    ' Clean up
    If CBool(conn.State And adStateOpen) Then conn.Close
    Set conn = Nothing
    Set rs = Nothing
End Sub

Finden Sie oben code, aber der obige code nicht funktioniert.bitte, wie dieses Problem zu beheben.

  • wenn Sie einen anderen code geben Sie bitte andernfalls, wenn alle Referenz-Datei oder eine Referenz video teilen.
  • Welche Fehler sind Sie immer und auf welcher Linie?
  • VB.NET ≠ VBScript ≠ VBA. Bitte nicht spam Kennzeichnen, nur weil Sie die ersten beiden Buchstaben gemeinsam. Dies ist nur mit VBA.
  • Bitte Lesen Sie stellen und nehmen Sie die tour und nicht zu vergessen eine Frage zu stellen . Dies ist nicht ein Dienst Debuggen.
  • meine Vermutung .... der sql-server ist offline
  • ich schaute gerade auf Ihren anderen Beitrag. Sie nicht Fragen, jede Frage gibt es überhaupt und Sie machte keine Anstalten, das problem zu beschreiben, das Sie haben. Sie werden das gleiche tun hier. ich glaube nicht, dass hier irgendjemand verschwenden Ihre Zeit versuchen zu erraten, was Sie denken. also, bitte, geben Sie entweder einige nützliche Informationen, damit wir dir helfen können, oder löschen Sie Ihren Beitrag.

InformationsquelleAutor Saran | 2017-09-25
  1. 1

    Es gibt so viele Möglichkeiten, dies zu tun!!

    Sub ADOExcelSQLServer()
     ' Carl SQL Server Connection
     '
     ' FOR THIS CODE TO WORK
     ' In VBE you need to go Tools References and check Microsoft Active X Data Objects 2.x library
     '

    Dim Cn As ADODB.Connection
    Dim Server_Name As String
    Dim Database_Name As String
    Dim User_ID As String
    Dim Password As String
    Dim SQLStr As String
    Dim rs As ADODB.Recordset
    Set rs = New ADODB.Recordset

    Server_Name = "NAME" ' Enter your server name here
    Database_Name = "AdventureWorksLT2012" ' Enter your database name here
    User_ID = "" ' enter your user ID here
    Password = "" ' Enter your password here
    SQLStr = "SELECT * FROM [SalesLT].[Customer]" ' Enter your SQL here

    Set Cn = New ADODB.Connection
    Cn.Open "Driver={SQL Server};Server=" & Server_Name & ";Database=" & Database_Name & _
    ";Uid=" & User_ID & ";Pwd=" & Password & ";"

    rs.Open SQLStr, Cn, adOpenStatic
     ' Dump to spreadsheet
    With Worksheets("sheet1").Range("a1:z500") ' Enter your sheet name and range here
        .ClearContents
        .CopyFromRecordset rs
    End With
     '            Tidy up
    rs.Close
    Set rs = Nothing
    Cn.Close
    Set Cn = Nothing
End Sub

    ODER . . . 

    Sub ADOExcelSQLServer()

    Dim Cn As ADODB.Connection
    Dim Server_Name As String
    Dim Database_Name As String
    Dim User_ID As String
    Dim Password As String
    Dim SQLStr As String
    Dim rs As ADODB.Recordset
    Set rs = New ADODB.Recordset

    Server_Name = "Server_Name" ' Enter your server name here
    Database_Name = "Northwind" ' Enter your  database name here
    User_ID = "" ' enter your user ID here
    Password = "" ' Enter your password here
    SQLStr = "SELECT * FROM Orders" ' Enter your SQL here

    Set Cn = New ADODB.Connection
    Cn.Open "Driver={SQL Server};Server=" & Server_Name & ";Database=" & Database_Name & _
    ";Uid=" & User_ID & ";Pwd=" & Password & ";"

    rs.Open SQLStr, Cn, adOpenStatic

    With Worksheets("Sheet1").Range("A2:Z500")
        .ClearContents
        .CopyFromRecordset rs
    End With

    rs.Close
    Set rs = Nothing
    Cn.Close
    Set Cn = Nothing
End Sub

    Oder . . . 

    Sub TestMacro()

' Create a connection object.
Dim cnPubs As ADODB.Connection
Set cnPubs = New ADODB.Connection

' Provide the connection string.
Dim strConn As String

'Use the SQL Server OLE DB Provider.
strConn = "PROVIDER=SQLOLEDB;"

'Connect to the Pubs database on the local server.
strConn = strConn & "DATA SOURCE=(local);INITIAL CATALOG=NORTHWIND.MDF;"

'Use an integrated login.
strConn = strConn & " INTEGRATED SECURITY=sspi;"

'Now open the connection.
cnPubs.Open strConn

' Create a recordset object.
Dim rsPubs As ADODB.Recordset
Set rsPubs = New ADODB.Recordset

With rsPubs
    ' Assign the Connection object.
    .ActiveConnection = cnPubs
    ' Extract the required records.
    .Open "SELECT * FROM Categories"
    ' Copy the records into cell A1 on Sheet1.
    Sheet1.Range("A1").CopyFromRecordset rsPubs

    ' Tidy up
    .Close
End With

cnPubs.Close
Set rsPubs = Nothing
Set cnPubs = Nothing

End Sub

    Schauen Sie sich auch die untenstehenden links.

    https://www.excel-sql-server.com/excel-import-to-sql-server-using-distributed-queries.htm#Introduction

    https://www.excel-sql-server.com/excel-sql-server-import-export-using-vba.htm#Introduction

    • Das war genau das, was ich suchte, vielen Dank
    • irgendwelche pro 's oder con' s zu jeder Ihrer Ansätze? Als könnte ich einen über die anderen - was sind die Use Cases? Oder sind Sie völlig austauschbar?
    • Es ist nur ein anderes Mittel zu demselben Zweck. Ein sub kann schneller laufen als der andere, aber eine kleine-ish-Daten eingestellt, ich glaube nicht, dass Sie werden bemerken, die performance-Gewinne oder Verluste. Wenn die verschiedenen code-Beispiele führen über einen großen Datensatz, können Sie bemerken Unterschiede. Im Grunde sind dies nur verschiedene, sondern meist gleich, Ansätze zur Lösung des gleichen Problems.
    InformationsquelleAutor ryguy72
Schreibe einen Kommentar