Wie zum Lesen von text aus einem bereits geöffneten Webseite mit VBA

Ich habe ein makro gemacht, den text zu Lesen, der von einer gespeicherten html-Seite/Datei. Nun benötige ich, um es vorab durch die Lektüre einer bereits geöffneten Webseite. wäre wirklich dankbar für die Hilfe,

Müssen, ersetzen Sie die Zeile

URL = "file:///C:/test.html"

mit etwas, das Lesen einer offenen Webseite. Ich kann stellen Sie sicher, dass es nur eine Registerkarte geöffnet ist. Ich benutze den neuesten IE

Dim URL As String
Dim Data As String

URL = "file:///C:/test.html"

Dim ie As Object
Dim ieDoc As Object

Set ie = CreateObject("InternetExplorer.Application")
ie.navigate URL

Do Until (ie.readyState = 4 And Not ie.Busy)
    DoEvents
Loop

Set ieDoc = ie.Document

Data = ieDoc.body.innerText
  • Ist es nicht eine option, um tatsächlich geben Sie die URL zum abrufen der Daten aus?
  • Was meinst du mit already open webpage?
  • schon öffnen Webseite = gibt es eine Webseite, die sich öffnen, in den IE - = - Webseite wurde im browser geöffnet, bevor das makro ausgelöst wurde
  • ich bin nicht die Freiheit der Aufruf eine zweite Instanz der Webseite,...ich brauche, zu verwenden, die eine, die ist schon offen
  • Dann ist es mehr als die URL-code, den Sie ändern müssen. Der vorhandene code angezeigt werden, öffnen Sie eine neue Instanz des IE für die lokale html-Datei. Ich bin mir nicht sicher, ob es überhaupt möglich ist zu Lesen-Aktivität aus einem bestehenden browser-Sitzung von VBA.
  • ich bin damit einverstanden. muss ich mehr ändern. weiter, wenn wir nicht Lesen können, aus der vorhandenen Instanz des Browsers, kann ich nicht speichern öffnen Sie die Webseite, und Lesen Sie dann die html-Datei dem Weg habe ich den aktuellen code?

InformationsquelleAutor dsauce | 2014-01-28
  1. 0

    Wenn Sie wissen, den Titel oder die url von der bereits geöffnete Webseite, die du suchst, ist dann dieser code, lassen Sie es

    ' Determine if a specific instance of IE is already open.
    Set objShell = CreateObject("Shell.Application")
    IE_count = objShell.Windows.Count
    For x = 0 To (IE_count - 1)
        On Error Resume Next    ' sometimes more web pages are counted than are open
        my_url = objShell.Windows(x).Document.Location
        my_title = objShell.Windows(x).Document.Title

        'You can use my_title of my_url, whichever you want
        If my_title Like "Put your webpage title here" & "*" Then   'identify the existing web page
            Set ie = objShell.Windows(x)
            Exit For
        Else
        End If
    Next
    InformationsquelleAutor ron
  2. 0

    Diesen code verwenden, um die derzeit Laufenden internet-explorer (Arbeit mindestens mit IE9):

    Dim ie As Object
Dim objShell As Object
Dim objWindow As Object
Dim objItem As Object

Set objShell = CreateObject("Shell.Application")
Set objWindow = objShell.Windows()
For Each objItem In objWindow
    If LCase(objItem.FullName Like "*iexplore*") Then
        Set ie = objItem
    End If
Next objItem

MsgBox ie.Document.body.innertext
    InformationsquelleAutor CommonGuy
  3. 0
    ' Add reference to 
' - Microsoft Internet Controls (SHDocVw)
' - Microsoft Shell Controls and Automation (Shell32)
' Find all running instances of IE and get web page Url
' Source: http://msdn.microsoft.com/en-us/library/windows/desktop/bb773974(v=vs.85).aspx
' Useful link: http://msdn.microsoft.com/en-us/library/windows/desktop/bb776890(v=vs.85).aspx

Sub main()
    Dim browsers
    Set browsers = GetBrowsers

    Dim browser
    Dim url
    For Each browser In browsers
        url = browser.document.Location.href
        Debug.Print CStr(url)
    Next browser
End Sub

Public Function GetBrowsers() As Collection

    Dim browsers As New Collection
    Dim shellApp As Shell32.Shell
    Dim wnds As SHDocVw.ShellWindows

    Set shellApp = New Shell
    Set wnds = shellApp.Windows

    Dim i As Integer
    Dim ie As SHDocVw.WebBrowser
    Dim name

    For i = 1 To wnds.Count
        Set ie = wnds(i)
        If ie Is Nothing Then GoTo continue
        If UCase(ie.FullName) Like "*IEXPLORE.EXE" Then
            browsers.Add ie
        End If
continue:
    Next i

    Set GetBrowsers = browsers
    Set shellApp = Nothing
End Function
    InformationsquelleAutor dee
Schreibe einen Kommentar